OBJET FIXER COULEURS RVB

4D v16.3


OBJET FIXER COULEURS RVB ( {* ;} objet ; couleurAvantPlan ; couleurArrièrePlan {; couleurArrièrePlanAlt} )

Paramètre	Type	Description
*	Opérateur	Si spécifié, objet est un nom d'objet (chaîne) Si omis, objet est un champ ou une variable
objet	Objet de formulaire	Nom d'objet (si * est spécifié) ou Champ ou Variable (si * est omis)
couleurAvantPlan	Entier long	Valeur de la couleur RVB d'avant-plan
couleurArrièrePlan	Entier long	Valeur de la couleur RVB d'arrière-plan
couleurArrièrePlanAlt	Entier long	Valeur de la couleur RVB d'arrière-plan alternée

Description

La commande OBJET FIXER COULEURS RVB modifie les couleurs d'avant-plan et d'arrière-plan du ou des objet(s) défini(s) par le paramètre objet et le paramètre optionnel *. Lorsque la commande est appliquée à un objet de type List box, un paramètre supplémentaire permet de modifier la couleur alternée des lignes.

Si vous passez le paramètre optionnel *, vous spécifiez que le paramètre objet est le nom d'un objet (une chaîne de caractères). Si le paramètre * est omis, vous spécifiez que objet est un champ ou un objet. Dans ce cas, vous ne passez pas dans objet une chaîne de caractères mais la référence à un champ ou à une variable (champ ou variable objet uniquement). Pour plus d'informations sur les noms d'objets, reportez-vous à la section Objets de formulaires.

Le paramètre facultatif couleurArrièrePlanAlt permet de désigner une couleur alternative pour l’arrière-plan (c’est-à-dire le fond) des lignes paires. Ce paramètre n’est utile que lorsque l’objet désigné est de type List box ou colonne de list box. Lorsque ce paramètre est utilisé, la couleurArrièrePlan est utilisée pour le fond des lignes impaires uniquement. Utiliser des couleurs alternées améliore la lisibilité des tableaux.
Si objet désigne l’objet List box, les couleurs alternées sont utilisées dans la totalité de la list box. Si objet désigne une colonne de list box, seule la colonne utilisera les couleurs définies.

Vous passez des valeurs de couleurs RVB dans les paramètres couleurAvantPlan, couleurArrièrePlan et couleurArrièrePlanAlt. Ces valeurs sont des entiers longs de 4 octets dont le format (0x00RRGGBB) est décrit ci-dessous (les octets sont numérotés de 0 à 3 de la droite vers la gauche) :

Octet	Description
3	Doit être zéro pour une couleur RVB absolue
2	Composante rouge de la couleur (0..255)
1	Composante verte de la couleur (0..255)
0	Composante bleue de la couleur (0..255)

Le tableau ci-dessous présente des exemples de valeurs de couleurs RVB :

Valeur	Description
0x00000000	Noir
0x00FF0000	Rouge vif
0x0000FF00	Vert vif
0x000000FF	Bleu vif
0x007F7F7F	Gris
0x00FFFF00	Jaune vif
0x00FF7F7F	Rouge pastel
0x00FFFFFF	Blanc

Vous pouvez aussi spécifier une des couleurs “système” utilisées par défaut par 4D pour dessiner des objets ayant la propriété de couleur “automatique”. Les constantes prédéfinies suivantes sont proposées par 4D dans le thème "FIXER COULEUR RVB" :

Constante	Type	Valeur	Comment
Coul arrière plan	Entier long	-2
Coul claire	Entier long	-4
Coul de fond texte sélect	Entier long	-7
Coul fond élément sélect désact	Entier long	-11
Coul fond ligne menu sélect	Entier long	-9
Coul fond transparent	Entier long	-16	Cette constante peut être utilisée uniquement avec les paramètres couleurArrièrePlan et couleurArrièrePlanAlt.
Coul premier plan	Entier long	-1
Coul sombre	Entier long	-3
Coul texte ligne menu sélect	Entier long	-10
Coul texte sélect	Entier long	-8

Par exemple, vous pouvez obtenir les couleurs suivantes pour les objets de type champ ou variable saisissable sur des systèmes standard :

ATTENTION : Ces couleurs automatiques dépendent du système et du type d'objet auquel elles sont affectées. En fonction de la version de l'OS ou si vous personnalisez vos couleurs système, les couleurs automatiques de 4D seront modifiées en conséquence. Utilisez les valeurs de couleurs automatiques pour assigner à des objets les couleurs système, et non pour leur assigner les mêmes couleurs que celles de l'exemple ci-dessus.

Exemple 1

Voici un formulaire contenant deux variables non saisissables, vsColorValue et vsColor ainsi que trois thermomètres, thRouge, thVert et thBleu :

Les méthodes associées à ces objets sont les suivantes :

  ` Méthode objet de la variable non saisissable vsColorValue

 Au cas ou

    :(Evenement formulaire=Sur chargement)

       vsColorValue:="0x00000000"

 Fin de cas

 

  ` Méthode objet de la variable non saisissable vsColor

 Au cas ou

    :(Evenement formulaire=Sur chargement)

       vsColor:=""

       OBJET FIXER COULEURS RVB(vsColor;0x00FFFFFF;0x0000)

 Fin de cas

 

  ` Méthode objet du thermomètre thRouge

 CLIC SUR THERMOMETRE COULEUR

 

  ` Méthode objet du thermomètre thVert

 CLIC SUR THERMOMETRE COULEUR

 

  ` Méthode objet du thermomètre thBleu

 CLIC SUR THERMOMETRE COULEUR

La méthode projet appelée par les trois thermomètres est la suivante :

  ` Méthode projet CLIC SUR THERMOMETRE COULEUR

 OBJET FIXER COULEURS RVB(vsColor;0x00FFFFFF;(thRouge << 16)+(thVert << 8)+thBleu)

 vsColorValue:=Chaine((thRouge << 16)+(thVert << 8)+thBleu;"&x")

 Si(thRouge=0)

    vsColorValue:=Sous chaine(vsColorValue;1;2)+"0000"+Sous chaine(vsColorValue;3)

 Fin de si

Notez l'utilisation des Opérateurs sur les bits pour le calcul des valeurs des couleurs à partir de celles des thermomètres.

En exécution, le formulaire a l'aspect suivant :

Exemple 2

Passage du fond en transparent avec couleur de police claire :

OBJET FIXER COULEURS RVB(*;"maVar";Coul claire;Coul fond transparent)

Voir aussi

OBJET FIXER COULEUR
OBJET LIRE COULEURS RVB
Opérateurs sur les bits
Selectionner couleur RVB