VP EXPORT DOCUMENT

4D v18

VP EXPORT DOCUMENT


VP EXPORT DOCUMENT ( vpAreaName ; filePath {; paramObj} )

引数	型	説明
vpAreaName	テキスト	4D View Pro エリアフォームオブジェクト名
filePath	テキスト	ドキュメントのパス名
paramObj	Object	書き出しのオプション

説明

VP EXPORT DOCUMENT コマンドは、vpAreaName で指定した 4D View Pro エリアに関連付けられている 4D View Pro オブジェクトを、filePath と paramObj 引数で指定されたとおりにディスク上のドキュメントに書き出します。

vpAreaName には 4D View Pro エリアの名前を渡します。存在しない名前を渡した場合にはエラーが返されます。

filePath には書き出すドキュメントのパスおよびファイル名を渡します。ドキュメント名のあとに拡張子(4D View Pro の ".4VP" 、Microsoft Excel の ".xlsx"、あるいはPDFの ".pdf")を含めることで、ドキュメントのフォーマットを指定することができます。ドキュメント名のみを指定した場合、ドキュメントは4Dのストラクチャーファイルと同じ階層に、デフォルトの".4VP" 拡張子で保存されます。

任意のparamObj 引数を使用すると、書き出される4D View Pro オブジェクトの複数のプロパティに加えて、書き出しが完了した際に呼び出されるコールバックメソッド名を定義することができます。

プロパティ

型

詳細

format

テキスト

渡した場合、書き出す際のファイル形式を指定します:".4VP" (デフォルト)または ".xlsx"あるいは".pdf"。format 引数には、4D View Pro Constants テーマの定数を渡すことができます。この場合、4D は必要に応じて適切な拡張子をファイル名に追加します。

以下のフォーマットがサポートされます:

定数	値	コメント
vk 4D View Pro format	.4VP	4D View Pro フォーマット(デフォルトのフォーマット)
vk MS Excel format	.xlsx	Microsoft Excel フォーマット
vk pdf format	.pdf	PDF フォーマット

指定されたフォーマットが引数に渡された拡張子と合致しない場合、指定された形式はfilePath 引数の後ろに追加されます。形式が指定されず、filePath 引数にも拡張子がなかった場合には、デフォルトのファイル形式が使用されます。

password

テキスト

Microsoft Excel のみ(任意) - MS Excel ドキュメントをプロテクトするために使用されるパスワード。

formula

オブジェクト

書き出しが完了した際に呼び出されるコールバックメソッド名。コールバックメソッドはFormula コマンドと使用する必要があります。詳細な情報は以下を参照して下さい。

valuesOnly

ブール

フォーミュラ(あれば)の値のみを書きだすかどうかを指定します。

includeFormatInfo

ブール

フォーマット情報を含めるにはTrue、それ以外の場合にはfalse(デフォルトはTrueです)。フォーマット情報は特定の場合(例: SVGへの書き出しなど)において有用です。一方で、このプロパティをFalse に設定することで書き出し時間を縮小することもできます。

sheetIndex

数値

PDF のみ(任意) - 書き出すシートのインデックス(0から始まります)。 -2=表示されている全てのシート(デフォルト)、-1=カレントのシートのみ

pdfOptions

オブジェクト

PDFのみ(任意) - pdf書き出しのオプション

プロパティ	型	詳細
creator	テキスト	変換されたドキュメントの変換元を作成したアプリケーション名。
title	テキスト	ドキュメント名。
author	テキスト	ドキュメントの作成者の名前
keywords	テキスト	ドキュメントに割り当てられているキーワード。
subject	テキスト	ドキュメントの題名

任意

コールバックメソッドの$3引数を通して利用可能な任意のカスタムの引数

Excel フォーマットについての注意: 4D View Pro ドキュメントをMicrosoft Excel 形式のファイルに書き出す場合、一部の設定が失われる可能性があります。例えば、4D メソッドとフォーミュラはExcel ではサポートされません。GrapeCity にあるこちらのリストを使用して他の設定を検証することができます。

PDF フォーマットについての注意: 4D View Pro ドキュメントをPDF 形式に書き出す場合、ドキュメントでしようされているフォントは自動的にPDF ファイルに埋め込まれます。ただしUnicode マップを持つOpenType フォント(.OTF または .TTF ファイル)のみが埋め込まれます。フォントに対して有効なフォントファイルが見つからない場合、デフォルトのフォントが代わりに使用されます。

書き出し操作が完了すると、VP EXPORT DOCUMENT は自動的に、paramObj オブジェクトのformula プロパティ内に設定されたメソッドをトリガーします(使用されていれば)。

コールバックメソッドを渡す

任意のparamObj 引数を使用する場合、VP EXPORT DOCUMENT コマンドではFormula コマンドを使用することで、書き出しが完了した時に実行される4Dメソッドを呼び出すことができます。コールバックメソッドは以下の値をローカル変数として受け取ります:

変数		型	詳細
$1		テキスト	4D View Pro オブジェクト名
$2		テキスト	書き出された4D View Pro オブジェクトのファイルパス
$3		オブジェクト	コマンドのparamObj 引数への参照
$4		オブジェクト	メソッドから返されるステータスメッセージのオブジェクト
	.success	ブール	書き出しに成功した場合にはTrue 、それ以外の場合にはFalse
	.errorCode	整数	エラーコード。4D あるいはJavaScript から返されます。
	.errorMessage	テキスト	エラーメッセージ。4D あるいはJavaScript から返されます。

例題 1

"VPArea"の中身をディスク上の 4D View Pro ドキュメントに書き出します:

 C_TEXT($docPath)

 

 $docPath:="C:\\Bases\\ViewProDocs\\MyExport.4VP"

 VP EXPORT DOCUMENT("VPArea";$docPath)

  // MyExport.4VP がディスク上に保存されます

例題 2

カレントのシートをPDFに書き出したい場合を考えます:

 C_OBJECT($params)

 $params:=New object

 $params.format:=vk pdf format

 $params.sheetIndex:=-1

 $params.pdfOptions:=New object("title";"Annual Report";"author";Current user)

 VP EXPORT DOCUMENT("VPArea";"report.pdf";$params)

例題 3

4D View Pro ドキュメントを".xlsx" フォーマットに書き出して、書き出しが完了したらそのドキュメントをMicrosoft Excel で開くメソッドを呼び出したい場合を考えます:

 $params:=New object

 $params.formula:=New formula(AfterExport)

 $params.format:=vp MS Excel format //".xlsx"

 $params.valuesOnly:=True

 

 VP EXPORT DOCUMENT("ViewProArea";"c:\\tmp\\convertedfile";$params)

AfterExport メソッド:

 C_TEXT($1;$2)

 C_OBJECT($3;$4)

 $areaName:=$1

 $filePath:=$2

 $params:=$3

 $status:=$4

 

 If($status.success=False)

    ALERT($status.errorMessage)

 Else

    LAUNCH EXTERNAL PROCESS("C:\\Program Files\\Microsoft Office\\Office15\\excel "+$filePath)

 End if

参照

VP Convert to picture
VP Export to object
VP IMPORT DOCUMENT
VP PRINT