4D View v16

PV SET CELL CONTROL

ホーム

 
ホーム
4D View v16
4D View
PVセルの値
PV SET CELL CONTROL

PV SET CELL CONTROL 


 

PV SET CELL CONTROL ( area ; column ; row ; type ; varName ; method ; title ) 
引数 型   説明
area  倍長整数 in 4D View エリア
column  倍長整数 in セルの列番号
row  倍長整数 in セルの行番号
type  整数 in 制御タイプ
varName  文字 in 制御管理変数の名前
method  文字 in コールバックメソッド名
title  文字 in 制御のタイトル

説明   

PV SET CELL CONTROLコマンドは、column とrowで指定されたセルに“制御”を設定します。制御とは、セルに納められるボタンやチェックボックス、ラジオボタン、ドロップダウンリスト、コンボボックスタイプのオブジェクトのことです。セルに制御が既に組み込まれている場合には、タイプに関わらずそれが削除され、新しい制御で置き換えられます。

type は、セルに納められる制御タイプ（上記5 つのタイプの1 つ）を示します。この引数を設定するには、PV Controlテーマ内の定数を使用します。

varName は、表示する値（ドロップダウンリストやコンボボックスの制御タイプ用）を格納した変数です。

method には、設定する制御に関連付けるコールバックメソッドの名前を指定します。コールバックメソッドに関する詳細はエリアコマンドについてを参照してください。

title には、ボタンやチェックボックス等のラベルを指定します。

例題  

以下の各メソッドにより、さまざまなタイプの制御を具体的に示します:

  • C3 セルに標準ボタン:
 C_LONGINT(vStandardButton)   `標準ボタン
 PV SET CELL CONTROL(Area;3;3;pv control push button;"vStandardButton";"CallbackButton";"Button")
 
  `CallbackButton method
 C_LONGINT($1)   `4D View エリア
 C_LONGINT($2)   `カラム番号
 C_LONGINT($3)   `行番号
 C_POINTER($4)   `オブジェクトを呼び出すポインター
 ALERT("Control from method: "+Current method name)
  • E3、E4、E5 セルにラジオボタン:
 C_LONGINT(vRadio1;vRadio2;vRadio3)   `ラジオボタン
 vRadio1:=1
 vRadio2:=0
 vRadio3:=0
 PV SET CELL CONTROL(Area;5;3;pv control radio button;"vRadio1";"CallbackRadio";"Day")
 PV SET CELL CONTROL(Area;5;4;pv control radio button;"vRadio2";"CallbackRadio";"Month")
 PV SET CELL CONTROL(Area;5;5;pv control radio button;"vRadio3";"CallbackRadio";"Year")
 
  `CallbackRadio メソッド
 C_LONGINT($1)   `4D View エリア
 C_LONGINT($2)   `カラム番号
 C_LONGINT($3)   `行番号
 C_POINTER($4)   `オブジェクトを呼び出すポインター
 C_TEXT($Value)
 Case of
    :($4=(->vRadio1))
       vRadio2:=0
       vRadio3:=0
       $Value:="Day"
    :($4=(->vRadio2))
       vRadio1:=0
       vRadio3:=0
       $Value:="Month"
    :($4=(->vRadio3))
       vRadio1:=0
       vRadio2:=0
       $Value:="Year"
 End case
 PV SET CELL TEXT VALUE($1;($2+1);3;$Value)
  • E7, E8, E9にチェックボックス:
 C_LONGINT(vCheckBox1;vCheckBox2;vCheckBox3)   `チェックするボックス
 vCheckBox1:=0
 vCheckBox2:=0
 vCheckBox3:=0
 PV SET CELL CONTROL(Area;5;7;pv control check box;"vCheckBox1";"CallbackCheckBox";"Beginner")
 PV SET CELL CONTROL(Area;5;8;pv control check box;"vCheckBox2";"CallbackCheckBox";"Intermediate")
 PV SET CELL CONTROL(Area;5;9;pv control check box;"vCheckBox3";"CallbackCheckBox";"Expert")
 
  `CallbackCheckBox メソッド
 C_LONGINT($1)   `4D View エリア
 C_LONGINT($2)   `カラム番号
 C_LONGINT($3)   `行番号
 C_POINTER($4)   `オブジェクトを呼び出すポインター
 C_TEXT($Value)
 If(vCheckBox1=1)
    $Value:="Beginner"
 End if
 If(vCheckBox2=1)
    If($Value#"")
       $Value:=$Value+" + "
    End if
    $Value:=$Value+"Intermediate"
 End if
 If(vCheckBox3=1)
    If($Value#"")
       $Value:=$Value+" + "
    End if
    $Value:=$Value+"Expert"
 End if
 PV SET CELL TEXT VALUE($1;($2+1);7;$Value)
  • C5にドロップダウンリスト:
 ARRAY TEXT(DropdownListArray;5)   `ドロップダウンリスト用
 DropdownListArray{1}:="Monday"
 DropdownListArray{2}:="Tuesday"
 DropdownListArray{3}:="Wednesday"
 DropdownListArray{4}:="Thursday"
 DropdownListArray{5}:="Friday"
 DropdownListArray:=3 `デフォルトを水曜日に設定
 PV SET CELL CONTROL(Area;3;5;pv control drop down;"DropdownListArray";"CallbackDropList";"")
 
  `CallbackDropList メソッド
 C_LONGINT($1)   `4D View エリア
 C_LONGINT($2)   `カラム番号
 C_LONGINT($3)   `行番号
 C_POINTER($4)   `オブジェクトを呼び出すポインター
 PV SET CELL TEXT VALUE($1;3;6;DropdownListArray{DropdownListArray})
  • C7にコンボボックス:
 ARRAY TEXT(ComboArray;5)   `コンボボックスリスト
 ComboArray{1}:="Monday"
 ComboArray{2}:="Tuesday"
 ComboArray{3}:="Wednesday"
 ComboArray{4}:="Thursday"
 ComboArray{5}:="Friday"
 ComboArray:=5 `デフォルトを金曜日に設定
 PV SET CELL CONTROL(Area;3;7;pv control combo box;"ComboArray";"CallbackCombo";"")
 
  `Method: CallbackCombo
 C_LONGINT($1)   `4D View エリア
 C_LONGINT($2)   `カラム番号
 C_LONGINT($3)   `行番号
 C_POINTER($4)   `オブジェクトを呼び出すポインター
 PV SET CELL TEXT VALUE($1;3;8;ComboArray{0})



参照 

PV GET CELL CONTROL
PV Get cell value type

前ページ
次ページ

 
プロパティ 

プロダクト: 4D View
テーマ: PVセルの値
番号: 15916

 
履歴 

初出: 4D View 6.8

 
ARTICLE USAGE

4D View ( 4D View v16)