4D View v16
PV SET CELL CONTROL
- 4D View - Lenguaje
-
- PV Valor celda
-
- PV Valor de la celda, Introducción
- PV ADD DYNAMIC ARRAYS
- PV ADD DYNAMIC FIELDS
- PV ARRAY TO CELLS
- PV CELLS TO ARRAY
- PV CLEAR DYNAMIC COLUMNS
- PV FIELD TO CELLS
- PV FIELDS LIST TO CELLS
- PV Get cell boolean value
- PV GET CELL CONTROL
- PV GET CELL DATE TIME VALUE
- PV Get cell date value
- PV GET CELL FIELD
- PV Get cell formula
- PV Get cell num value
- PV Get cell picture value
- PV Get cell string value
- PV Get cell text value
- PV Get cell time value
- PV Get cell value type
- PV Get cell variable
- PV REPORT MANY
- PV REPORT ONE
- PV SET CELL BOOLEAN VALUE
- PV SET CELL CONTROL
- PV SET CELL DATE TIME VALUE
- PV SET CELL DATE VALUE
- PV SET CELL FIELD
- PV SET CELL FORMULA
- PV SET CELL NUM VALUE
- PV SET CELL PICTURE VALUE
- PV SET CELL STRING VALUE
- PV SET CELL TEXT VALUE
- PV SET CELL TIME VALUE
- PV SET CELL VARIABLE
- PV UPDATE DYNAMIC AREA
PV SET CELL CONTROL
| PV SET CELL CONTROL ( area ; columna ; linea ; tipo ; nomVar ; metodo ; titulo ) | ||||||||
| Parámetro | Tipo | Descripción | ||||||
| area | Entero largo |
|
Área 4D View | |||||
| columna | Entero largo |
|
Número de columna de la celda | |||||
| linea | Entero largo |
|
Número de línea de la celda | |||||
| tipo | Entero |
|
Tipo de control | |||||
| nomVar | Cadena |
|
Nombre de la variable de gestión del control | |||||
| metodo | Cadena |
|
Nombre del método de retrollamada | |||||
| titulo | Cadena |
|
Título del control | |||||
El comando PV SET CELL CONTROL coloca un "control" en la celda designada por linea y columna.
Un control es un objeto de tipo botón, casilla de selección, botón de radio, lista desplegable o un combo box dentro de una celda.
Si un control ya fue insertado en la celda, se elimina y se sustituye por el nuevo control, cualquiera que sea su tipo.
tipo indica el tipo de control (entre los cinco mencionados anteriormente) que figura en la celda. Para definir este parámetro, utilice las constantes del tema PV Controles.
nomVar es la variable asociada al control. Pase el nombre del array que contiene los valores a mostrar (para los controles de tipos lista desplegable y combo box).
metodo contiene el nombre del método de retrollamada relacionado con el control. Para más información sobre los métodos de retrollamada, consulte la sección PV Área, Introducción.
titulo contiene la etiqueta del botón, casilla de selección, etc.
Los siguientes métodos permiten visualizar los diferentes tipos de controles:
- Botón estándar en C3:
C_LONGINT(vStandardButton) `Botón estándar
PV SET CELL CONTROL(Area;3;3;pv control push button;"vStandardButton";"CallbackButton";"Button")
`Método CallbackButton
C_LONGINT($1) `Área 4D View
C_LONGINT($2) `Número de columna
C_LONGINT($3) `Número de línea
C_POINTER($4) `Puntero al objeto de llamada
ALERT("Control from method: "+Current method name)- Botones radio en E3, E4, E5:
C_LONGINT(vRadio1;vRadio2;vRadio3) `Botones radio
vRadio1:=1
vRadio2:=0
vRadio3:=0
PV SET CELL CONTROL(Area;5;3;pv control radio button;"vRadio1";"CallbackRadio";"Día")
PV SET CELL CONTROL(Area;5;4;pv control radio button;"vRadio2";"CallbackRadio";"Mes")
PV SET CELL CONTROL(Area;5;5;pv control radio button;"vRadio3";"CallbackRadio";"Año")
`Método CallbackRadio
C_LONGINT($1) `Área 4D View
C_LONGINT($2) `Número de columna
C_LONGINT($3) `Número de línea
C_POINTER($4) `Puntero al objeto de llamada
C_TEXT($Value)
Case of
:($4=(->vRadio1))
vRadio2:=0
vRadio3:=0
$Value:="Día"
:($4=(->vRadio2))
vRadio1:=0
vRadio3:=0
$Value:="Mes"
:($4=(->vRadio3))
vRadio1:=0
vRadio2:=0
$Value:="Año"
End case
PV SET CELL TEXT VALUE($1;($2+1);3;$Value)- Casillas de selección en E7, E8, E9:
C_LONGINT(vCheckBox1;vCheckBox2;vCheckBox3) `Casillas a seleccionar
vCheckBox1:=0
vCheckBox2:=0
vCheckBox3:=0
PV SET CELL CONTROL(Area;5;7;pv control check box;"vCheckBox1";"CallbackCheckBox";"Principiante")
PV SET CELL CONTROL(Area;5;8;pv control check box;"vCheckBox2";"CallbackCheckBox";"Intermedio")
PV SET CELL CONTROL(Area;5;9;pv control check box;"vCheckBox3";"CallbackCheckBox";"Experto")
`Método CallbackCheckBox
C_LONGINT($1) `Área 4D View
C_LONGINT($2) `Número de columna
C_LONGINT($3) `Número de línea
C_POINTER($4) `Puntero al objeto de llamada
C_TEXT($Value)
If(vCheckBox1=1)
$Value:="Principiante"
End if
If(vCheckBox2=1)
If($Value#"")
$Value:=$Value+" + "
End if
$Value:=$Value+"Intermedio"
End if
If(vCheckBox3=1)
If($Value#"")
$Value:=$Value+" + "
End if
$Value:=$Value+"Expert"
End if
PV SET CELL TEXT VALUE($1;($2+1);7;$Value)- Lista desplegable en C5:
ARRAY TEXT(DropdownListArray;5) `Para lista desplegable
DropdownListArray{1}:="Lunes"
DropdownListArray{2}:="Martes"
DropdownListArray{3}:="Miércoles"
DropdownListArray{4}:="Jueves"
DropdownListArray{5}:="Viernes"
DropdownListArray:=3 `Por defecto a miércoles
PV SET CELL CONTROL(Area;3;5;pv control drop down;"DropdownListArray";"CallbackDropList";"")
`Método CallbackDropList
C_LONGINT($1) `Área 4D View
C_LONGINT($2) `Número de columna
C_LONGINT($3) `Número de línea
C_POINTER($4) `Puntero al objeto de llamada
PV SET CELL TEXT VALUE($1;3;6;DropdownListArray{DropdownListArray})- Combo box en C7:
ARRAY TEXT(ComboArray;5) `Para lista del combo box
ComboArray{1}:="Lunes"
ComboArray{2}:="Martes"
ComboArray{3}:="Miércoles"
ComboArray{4}:="Jueves"
ComboArray{5}:="Viernes"
ComboArray:=5 `Por defecto para viernes
PV SET CELL CONTROL(Area;3;7;pv control combo box;"ComboArray";"CallbackCombo";"")
`Método: CallbackCombo
C_LONGINT($1) `Área 4D View
C_LONGINT($2) `Número de columna
C_LONGINT($3) `Número de línea
C_POINTER($4) `Puntero al objeto de llamada
PV SET CELL TEXT VALUE($1;3;8;ComboArray{0})
Producto: 4D View
Tema: PV Valor celda
Número
15916
Creado por: 4D View 6.8
4D View - Lenguaje ( 4D View v16)
