4D View v16
PV SET CELL CONTROL
- 4D View - Langage
-
- PV Valeur de cellule
-
- PV Valeur de cellule, Introduction
- PV ADD DYNAMIC ARRAYS
- PV ADD DYNAMIC FIELDS
- PV ARRAY TO CELLS
- PV CELLS TO ARRAY
- PV CLEAR DYNAMIC COLUMNS
- PV FIELD TO CELLS
- PV FIELDS LIST TO CELLS
- PV Get cell boolean value
- PV GET CELL CONTROL
- PV GET CELL DATE TIME VALUE
- PV Get cell date value
- PV GET CELL FIELD
- PV Get cell formula
- PV Get cell num value
- PV Get cell picture value
- PV Get cell string value
- PV Get cell text value
- PV Get cell time value
- PV Get cell value type
- PV Get cell variable
- PV REPORT MANY
- PV REPORT ONE
- PV SET CELL BOOLEAN VALUE
- PV SET CELL CONTROL
- PV SET CELL DATE TIME VALUE
- PV SET CELL DATE VALUE
- PV SET CELL FIELD
- PV SET CELL FORMULA
- PV SET CELL NUM VALUE
- PV SET CELL PICTURE VALUE
- PV SET CELL STRING VALUE
- PV SET CELL TEXT VALUE
- PV SET CELL TIME VALUE
- PV SET CELL VARIABLE
- PV UPDATE DYNAMIC AREA
PV SET CELL CONTROL
| PV SET CELL CONTROL ( zone ; colonne ; ligne ; type ; nomVar ; méthode ; titre ) | ||||||||
| Paramètre | Type | Description | ||||||
| zone | Entier long |
|
Zone 4D View | |||||
| colonne | Entier long |
|
Numéro de colonne de la cellule | |||||
| ligne | Entier long |
|
Numéro de ligne de la cellule | |||||
| type | Entier |
|
Type de contrôle | |||||
| nomVar | Chaîne |
|
Nom de la variable de gestion du contrôle | |||||
| méthode | Chaîne |
|
Nom de la méthode de rétro-appel | |||||
| titre | Chaîne |
|
Titre du contrôle | |||||
La commande PV FIXER CONTROLE CELLULE place un “contrôle” dans la cellule désignée par colonne et ligne.
Un contrôle est un objet de type bouton, case à cocher, bouton radio, liste déroulante ou combo box contenu dans une cellule. Si un contrôle existait déjà dans la cellule définie, il est remplacé par le nouveau, quel que soit son type.
type indique le type de contrôle (parmi les cinq ci-dessus) à placer dans la cellule. Pour définir ce paramètre, utilisez les constantes du thème PV Contrôles :
| Constante | Type | Valeur |
| pv control check box | Entier long | 3 |
| pv control combo box | Entier long | 5 |
| pv control drop down | Entier long | 4 |
| pv control none | Entier long | 0 |
| pv control push button | Entier long | 1 |
| pv control radio button | Entier long | 2 |
nomVar est le nom de la variable associée au contrôle. Pour les contrôles de types liste déroulante ou combo box, passez le nom du tableau contenant les valeurs à afficher.
méthode contient le nom de la méthode de rétro-appel liée au contrôle. Pour plus d’informations sur le concept de rétro-appel, reportez-vous à la section PV Zone, Introduction.
titre contient le libellé du bouton, de la case à cocher, etc.
Les méthodes suivantes permettent de visualiser les différents types de contrôles.
- Bouton standard en C3 :
C_LONGINT(vBoutonStandard) `Bouton standard
PV SET CELL CONTROL(Zone;3;3;pv control push button;"vBoutonStandard";"RétroAppelBouton";"Bouton")
`Méthode RétroAppelBouton
C_LONGINT($1) `Zone 4D View
C_LONGINT($2) `N° de colonne
C_LONGINT($3) `N° de ligne
C_POINTER($4) `Pointeur sur objet d'appel
ALERT("Contrôle depuis la méthode : "+Current method name)- Boutons radio en E3, E4, E5 :
C_LONGINT(vRadio1;vRadio2;vRadio3) `Boutons radio
vRadio1:=1
vRadio2:=0
vRadio3:=0
PV SET CELL CONTROL(Zone;5;3;pv control radio button;"vRadio1";"RétroAppelRadio";"Jour")
PV SET CELL CONTROL(Zone;5;4;pv control radio button;"vRadio2";"RétroAppelRadio";"Mois")
PV SET CELL CONTROL(Zone;5;5;pv control radio button;"vRadio3";"RétroAppelRadio";"Année")
`Méthode RétroAppelRadio
C_LONGINT($1) `Zone 4D View
C_LONGINT($2) `N° de colonne
C_LONGINT($3) `N° de ligne
C_POINTER($4) `Pointeur sur objet d'appel
C_TEXT($Valeur)
Case of
:($4=(->vRadio1))
vRadio2:=0
vRadio3:=0
$Valeur:="Jour"
:($4=(->vRadio2))
vRadio1:=0
vRadio3:=0
$Valeur:="Mois"
:($4=(->vRadio3))
vRadio1:=0
vRadio2:=0
$Valeur:="Année"
End case
PV SET CELL TEXT VALUE($1;($2+1);3;$Valeur)- Cases à cocher en E7, E8, E9 :
C_LONGINT(vCac1;vCac2;vCac3) `Cases à cocher
vCac1:=0
vCac2:=0
vCac3:=0
PV SET CELL CONTROL(Zone;5;7;pv control check box;"vCac1";"RétroAppelCac";"Initiation")
PV SET CELL CONTROL(Zone;5;8;pv control check box;"vCac2";"RétroAppelCac";"Fondamentaux")
PV SET CELL CONTROL(Zone;5;9;pv control check box;"vCac3";"RétroAppelCac";"Expert")
`Méthode RétroAppelCac
C_LONGINT($1) `Zone 4D View
C_LONGINT($2) `N° de colonne
C_LONGINT($3) `N° de ligne
C_POINTER($4) `Pointeur sur objet d'appel
C_TEXT($Valeur)
If(vCac1=1)
$Valeur:="Initiation"
End if
If(vCac2=1)
If($Valeur#"")
$Valeur:=$Valeur+" + "
End if
$Valeur:=$Valeur+"Fondamentaux"
End if
If(vCac3=1)
If($Valeur#"")
$Valeur:=$Valeur+" + "
End if
$Valeur:=$Valeur+"Expert"
End if
PV SET CELL TEXT VALUE($1;($2+1);7;$Valeur)- Liste déroulante en C5 :
ARRAY TEXT(TabListeDéroulante;5) `Pour liste déroulante
TabListeDéroulante{1}:="Lundi"
TabListeDéroulante{2}:="Mardi"
TabListeDéroulante{3}:="Mercredi"
TabListeDéroulante{4}:="Jeudi"
TabListeDéroulante{5}:="Vendredi"
TabListeDéroulante:=3 `Défaut à Mercredi
PV SET CELL CONTROL(Zone;3;5;pv control drop down;"TabListeDéroulante";"RétroAppelListeDéroulante";"")
`Méthode RétroAppelListeDéroulante
C_LONGINT($1) `Zone 4D View
C_LONGINT($2) `N° de colonne
C_LONGINT($3) `N° de ligne
C_POINTER($4) `Pointeur sur objet d'appel
PV SET CELL TEXT VALUE($1;3;6;TabListeDéroulante{TabListeDéroulante})- Combo box en C7 :
ARRAY TEXT(TabCombo;5) `Pour liste de la combo Box
TabCombo{1}:="Lundi"
TabCombo{2}:="Mardi"
TabCombo{3}:="Mercredi"
TabCombo{4}:="Jeudi"
TabCombo{5}:="Vendredi"
TabCombo:=5 `Défaut à Vendredi
PV SET CELL CONTROL(Zone;3;7;pv control combo box;"TabCombo";"RétroAppelCombo";"")
`Méthode : RétroAppelCombo
C_LONGINT($1) `Zone 4D View
C_LONGINT($2) `N° de colonne
C_LONGINT($3) `N° de ligne
C_POINTER($4) `Pointeur sur objet d'appel
PV SET CELL TEXT VALUE($1;3;8;TabCombo{0})
Produit : 4D View
Thème : PV Valeur de cellule
Numéro :
15916
Créé : 4D View 6.8
4D View - Langage ( 4D View v16)
