4D Doc Center : SMTP

4D Internet Commands v14

SMTP_Auth


SMTP_Auth ( smtp_ID ; userName ; password {; authMode} ) -> 戻り値

引数	型	説明
smtp_ID	倍長整数	メッセージ参照
userName	文字	SMTP認証で使用するユーザ名
password	文字	SMTP認証で使用するパスワード
authMode	整数	使用する認証モード: 0 または省略 = サーバが指定するモード, 1= PLAIN, 2 = LOGIN, 3 = CRAM-MD5
戻り値	整数	エラーコード

説明

SMTP_Auth コマンドは、認証を要求するSMTPサーバを使用してメールを送信する場合に使用します。スパムなどの目的でメッセージや送信者の偽装リスクを軽減するために、SMTPサーバはこのような認証を要求します。

このコマンドは userName および passwordが空でない場合にのみ実行されるため、認証が必要であるかないかにかかわらず使用できます。

smtp_ID はSMTP_New コマンドで作成されるメールメッセージ参照です。

userName はSMTPサーバに認証のために送信されるユーザ名です。

password はSMTPサーバに認証のために送信されるパスワードです。

Note: userName または password が空の文字列の場合、SMTP_Auth コマンドは実行されません。

オプションのauthMode 引数を使用して、使用する認証モードを強制することができます。

0を渡した場合、SMTP_Auth コマンドで使用される認証モードは、サーバがサポートするモードのうち最も安全性の高いモードとなります (CRAM-MD5, LOGIN そののち PLAIN)。
1を渡した場合、認証モードはPLAINが使用されます。
2を渡した場合、認証モードはLOGINが使用されます。
3を渡した場合、認証モードはCRAM-MD5が使用されます。

authModeが省略されると、デフォルトで0が使用されます。この引数で指定された認証モードがSMTPサーバでサポートされていない場合、エラーが返されます。

例題

この例題では、4Dデータベースに格納された特定のフィールドの内容に基づき、メッセージが認証ありまたはなしで送信されます:

 C_INTEGER($vError)

 C_LONGINT($vSmtp_id)

 C_STRING(30;$vAuthUserName;$vAuthPassword)

 

 $vError:=SMTP_New($vSmtp_id)

 $vError:=SMTP_Host($vSmtp_id;"wkrp.com")

 $vError:=SMTP_From($vSmtp_id;"herb_tarlick@wkrp.com")

 $vError:=SMTP_Subject($vSmtp_id;"Are you there?")

 $vError:=SMTP_To($vSmtp_id;"Dupont@wkrp.com")

 $vError:=SMTP_Body($vSmtp_id;"Can we have a meeting?")

 

  ` サーバが認証を必要とする場合、以下のフィールドに値が

  ` 入力される。必要でなければ空のまま

 $vAuthUserName:=[Account]AuthUser

 $vAuthPassword:=[Account]AuthPass

 

 $vError:=SMTP_Auth($vSmtp_id;$vAuthUserName;$vAuthPassword)

 $vError:=SMTP_Send($vSmtp_id)

 $vError:=SMTP_Clear($vSmtp_id)