4D Doc Center : SMTP

4D Internet Commands v14

SMTP_QuickSend


SMTP_QuickSend ( hostName ; msgFrom ; msgTo ; subject ; message {; sessionParam}{; port}{; userName ; password} ) -> 戻り値

引数	型	説明
hostName	文字	ホスト名またはIPアドレス
msgFrom	テキスト	送信元MailAddress または AddressList
msgTo	テキスト	送信先MailAddress または AddressList
subject	テキスト	件名(デフォルトではUTF-8)
message	テキスト	メッセージ本文(デフォルトではUTF-8)
sessionParam	倍長整数	0または省略 = SSLを使用しない、1 = SSLを使用、2 = SSLを決して使用しない(スイッチオーバーを許可しない)、4 = SSLを使用せずにHTMLテキストを送信、5 = SSLを使用してHTMLを送信
port	倍長整数	使用するポート番号
userName	テキスト	認証に使用するユーザー名
password	テキスト	認証に使用するパスワード
戻り値	整数	エラーコード

説明

SMTP_QuickSend コマンドは、一つのコマンドでメールの構築と送信を可能にします。メッセージに対する詳細なコントロールが必要な場合、またはメッセージが複雑な性質をしているときには、 SMTP_New コマンドをはじめとするSMTP関連のコマンドを使用します。

hostName はSMTPサーバのホスト名またはIPアドレスで、配送するメッセージを中継するサーバです。

msgFrom は、メールの送信人を表す一つ以上の完全なMailAddress または AddressListです。Fromヘッダに書かれたすべてのアドレスはメッセージの受信者から閲覧可能です。

msgTo は、一つ以上の完全なAddressListを含みます。msgTo ヘッダに記載されたAddressListにそれぞれメッセージが送信されます。それぞれの受信者は、他の受信者のアドレスを見ることができます。

subject にはメールの件名を渡します。

注: デフォルトでは、メッセージの件名と本文はUTF-8でエンコードされています。これにより、送信された文字はほぼ全てのe-メールクライアントで正常に解釈されます。特定の文字コードを使用したい場合は、SMTP_SetPrefs と SMTP_Charset コマンドを参照して下さい。

messageはメールメッセージのボディテキストを渡します。過去の経緯からメッセージサイズは32 KBに制限されます。

オプションのsessionParam引数を使用すると、メッセージフォーマット(標準テキストまたはHTML)や接続に使用するSSLプロトコルのアクティベーションモードを設定できます:

0を渡すかこの引数を省略すると、メッセージはテキストとしてフォーマットされ、送信は標準の非保護モードで行われます。認証後にサーバーからSSL/TLSへの更新を要求された場合、スイッチは自動で行われます (explicitモードのSSL/TLS)。
1を渡すと、メッセージはテキストとしてフォーマットされ、送信はSSLで行われます (同期モード)、
2を渡すと、メッセージはテキストとしてフォーマットされ、送信は標準の非保護モードで行われます。SSL/TLSへの更新は行われません。
4を渡すと、メッセージはHTMLとしてフォーマットされ、標準モードで送信されます。
5を渡すと、メッセージはHTMLとしてフォーマットされ、送信はSSL/TLSで行われます。

任意の port 引数はサーバーに接続する際に使用するSMTPポート番号を指定します。もっともよく使用される値は以下の通りです:

25 = 標準の非保護SMTPポート(引数が省略された際のデフォルトのポート)
465 = SMTPS (SSL/TLS) ポート
587 = 標準の(保護された) SMTP ポート。MS Exchane サーバーに接続する際にはこのポートを指定して下さい(explicit モード)。

任意のuserName と password 引数はメールサーバーにて送信者を認証するために使用されます。これらの引数は一緒に渡す必要があります。この際には、サーバーでサポートされている最も安全な認証モードが(SMTP_Auth コマンドのデフォルトのモードとともに)使用されます。

例題 1

以下はこのコマンドの使用例です:

 $Host:="www.4d.com"

 $ToAddress:="adupont@4d.fr"

 $FromAddress:="jsmith@4d.com"

 $Subject:="Sales Report"

 $Message:="Can you send me the sales report for January 2000? Thanks."

 $Error:=SMTP_QuickSend($Host;$FromAddress;$ToAddress;$Subject;$Message;1)

 If($Error#0)

    ALERT("Error: SMTP_QuickSend"+Char(13)+IT_ErrorText($Error))

 End If

例題 2

MS Exchange serverにセキュアモードでメールを送信する例題:

 $ServerName:="exchange.4d.com"

 $MsgTo:="adupont@gmail.com"

 $MsgFrom:="a.user@4d.com"

 $Subject:="Test message"

 $Message:="This is a test for sending a message in secure mode. Please do not reply."

 $Error:=SMTP_QuickSend($ServerName;$MsgFrom;$MsgTo;$Subject;$Message;0;587;"a.user";"@!password@!")

例題 3

メッセージをHTMLフォーマットで、SSL/TLS モードを使用して送ります:

 $Host:="smtp.gmail.com"

 $ToAddress:="john@4d.com"

 $FromAddress:="harry@gmail.com"

 $Subject:="Message HTML"

 $Message:="Let’s meet at <b>Joe’s Coffee Shop</b>!"

 $Param:=5 //HTML フォーマットで SSL モード

 $Port:=465 //gmail の SSLポート

 $User:="harry@gmail.com"

 $Password:="xyz&@!&@"

 $Error:=SMTP_QuickSend($Host;$FromAddress;$ToAddress;$Subject;$Message;$Param;$Port;$User;$Password)