4D Doc Center : SMTP

4D Internet Commands v14

SMTP_Auth


SMTP_Auth ( smtp_ID ; nomeUsuario ; senha {; autModo} ) -> Resultado

Parâmetro	Tipo	Descrição
smtp_ID	Inteiro longo	Referencia da mensagem
nomeUsuario	cadeia	Nome do usuário para a autenticação SMTP
senha	cadeia	Senha para a autenticação SMTP
autModo	Inteiro	Modo de autenticação a utilizar: 0 ou se omite = Modo definido pelo servidor 1= PLAIN, 2 = LOGIN, 3 = CRAM-MD5
Resultado	Inteiro	Código de erro

Descrição

O comando SMTP_Auth permite o envio da mensagem referenciada por smtp_ID quando um mecanismo de autenticação é requerido pelo servidor SMTP. Este tipo de autenticação é requerida por alguns servidores SMTP com a finalidade de reduzir o risco de que as mensagens sejam falsificados ou que a identidade do remetente seja usurpada, particularmente com o finalidade de enviar spam.

Este comando pode ser utilizada se a autenticação é necessária ou não, já que somente é executada se nomeUsuario e senha não são cadeias vazias.

smtp_ID é a referencia inteiro longo de um e-mail criado com o comando SMTP_New.

nomeUsuario é o nome do usuário no servidor SMTP. O parâmetro nomeUsuario não deve conter o domínio. Por exemplo, para o endereço "jack@4d.com", o nomeUsuario é "Jack".

senha é a senha para nomeUsuario no servidor SMTP.

Nota: Se nomeUsuario e/ou senha são cadeias vazias, o comando SMTP_Auth não é executado.

O parâmetro opcional autModo permite "forçar" o modo de autenticação utilizado. Pode passar 0, 1, 2 ou 3 neste parâmetro:

Se passa 0 (zero), o modo de autenticação utilizado pelo comando SMTP_Auth será o modo mais seguro suportado pelo servidor (CRAM-MD5, LOGIN depois PLAIN),
Se passa 1, o método de autenticação localizado será PLAIN,
Se passa 2, o método de autenticação utilizado será LOGIN,
Se passa 3, o método de autenticação utilizado será CRAM-MD5.
Se omite autModo, por padrão se utiliza o valor 0. Se o método de autenticação solicitado por este parâmetro não é compatível com o servidor SMTP, é devolvido um erro.

Exemplo

Este exemplo permite enviar uma mensagem com ou sem autenticação, em função do conteúdo de campos especificados armazenados na base 4D:

C_INTEGER($vError)

 C_LONGINT($vSmtp_id)

 C_STRING(30;$vAuthUserName;$vAuthPassword)

 

 $vError:=SMTP_New($vSmtp_id)

 $vError:=SMTP_Host($vSmtp_id;"wkrp.com")

 $vError:=SMTP_From($vSmtp_id;"herb_tarlick@wkrp.com")

 $vError:=SMTP_Subject($vSmtp_id;"Are you there?")

 $vError:=SMTP_To($vSmtp_id;"Dupont@wkrp.com")

 $vError:=SMTP_Body($vSmtp_id;"Podemos nos reunir?")

 

  ` Os campos são introduzidos se o servidor utiliza um mecanismo

  ` de autenticação. Caso contrário, são devolvidas as cadeias vazias.

 $vAuthUserName:=[Account]AuthUser

 $vAuthPassword:=[Account]AuthPass

 

 $vError:=SMTP_Auth($vSmtp_id;$vAuthUserName;$vAuthPassword)

 $vError:=SMTP_Send($vSmtp_id)

 $vError:=SMTP_Clear($vSmtp_id)