TRACE

4D v16.3

TRACE


	TRACE

	このコマンドは引数を必要としません

説明

データベースの開発時に、TRACEコマンドを使用してメソッドをトレースすることができます。

TRACEコマンドは、カレントプロセス用の4Dのデバッガを起動します。デバッグウィンドウはコードの次の行が実行される前に表示されます。実行するコードを表示しながらメソッドの実行を続けることができます。コードの実行中に、 Alt+Shift+右クリック (Windows) 、またはControl+Option+Command+クリック (Macintosh) でもデバッガを起動することができます。

コンパイルされたデータベースでは、TRACEコマンドは無視されます。

4D Server: ストアドプロシージャのコンテキスト内で実行されたプロジェクトメソッドからTRACEコマンドをコールすると、デバッグウィンドウはサーバマシン上に表示されます。

Tip: On ActivateおよびOn Deactivateイベントが選択されたフォームを使用する場合、TRACEコマンドを使用しないでください。デバッグウィンドウが表示されるたびに、これらのイベントが起動されて、この2つのイベントとデバッグウィンドウとの間で永久ループになってしまいます。このような状況になった場合には、トレースなしボタンをShiftキーを押しながらクリックします。以降、そのプロセス内ではTRACEコマンドが無視されます。

例題

次のコードでは、プロセス変数BUILD_LANGに“US”あるいは“FR”という値であることを期待しています。それ以外の値である場合に、プロジェクトメソッドDEBUGを呼び出します:

  ` ...

 Case of

    :(BUILD_LANG="US")

       vsBHCmdName:=[Commands]CM US Name

    :(BUILD_LANG="FR")

       vsBHCmdName:=[Commands]CM FR Name

    Else

       DEBUG("Unexpected BUILD_LANG value")

 End case

DEBUG プロジェクトメソッドを次に示します:

  ` DEBUG Project Method

  ` DEBUG (Text)

  ` DEBUG (Optional Debug Information)

 

 C_TEXT($1)

 

 If(<>vbDebugOn) ` インタープロセス変数はOn Startupメソッドで設定される

    If(Is compiled mode)

       If(Count parameters>=1)

          ALERT($1+Char(13)+"Call Designer at x911")

       End if

    Else

       TRACE

    End if

 End if

参照

NO TRACE