WP Table get rows

4D v18

WP Table get rows


WP Table get rows ( targetObj ) \| ( tableRef ; startRow {; numRows} ) -> 戻り値

引数	型	説明
targetObj	Object	レンジまたは要素または4D Write Pro ドキュメント
tableRef	Object	テーブル参照オブジェクト
startRow	倍長整数	最初の行の位置
numRows	倍長整数	取得したい行数
戻り値	Object	選択された行を含む新しいテーブルレンジ

説明

WP Table get rows コマンドは、targetObj または(startRow および numRows 引数で定義された)tableRef で指定した表から、行のセレクションを格納した新しいレンジオブジェクトを返します。

以下のいづれかを渡します:

targetObj 引数の場合、渡せるもの:
- レンジ
- 要素(行/段落/本文/ヘッダー/フッター/インラインピクチャー/セクション/サブセクション)
- 4D Write Pro ドキュメント

targetObj 引数が、表、または行のセレクションを取得可能なテキストレンジと交差しない場合、コマンドはNull を返します。

または

tableRef - 行のセレクションを取得したい表の参照
startRow - 返す表の最初の行を指定
(オプション) numRows - 返す行の数を指定。numRows 引数が省略された場合、startRow 引数で指定した行1つだけが返されます。

startRow 引数と numRows 引数を足した数がtableRef 引数で指定した表にある行の数より多い場合、またはstartRow 引数そのものがtableRef 引数で指定した表にある行の数より多い場合、返されるレンジには取得可能な行が全て格納されます。

例題 1

テーブルの最初の2行に対して特定の背景色を設定し、3行目の境界線を変更したい場合を考えます:

 C_OBJECT($wpTable;$wpRange;$wpRow1;$wpRow2;$wpRow3;$wpRow4;$wpRow5;$rows;$rows2)

 $wpRange:=WP Create range(WParea;wk start text;wk end text)

 

 $wpTable:=WP Insert table($wpRange;wk append)

 $wpRow1:=WP Table append row($wpTable;"Paul";"Smith";25)

 $wpRow2:=WP Table append row($wpTable;"John";"Richmond";40)

 $wpRow3:=WP Table append row($wpTable;"Mary";"Trenton";18)

 $wpRow4:=WP Table append row($wpTable;"Christopher";"Lee";53)

 $wpRow5:=WP Table append row($wpTable;"Henry";"Cartier";42)

 

 $rows:=WP Table get rows($wpTable;1;2)

 WP SET ATTRIBUTES($rows;wk background color;0x00E0F0FF)

 $rows2:=WP Table get rows($wpTable;3)

 WP SET ATTRIBUTES($rows2;wk border style;wk solid)

 WP SET ATTRIBUTES($rows2;wk border width;4)

例題 2

10行目の行から最後の行までのレンジを取得したい場合を考えます:

WP Table get rows(tableRef;10;MAXLONG)

例題 3

ユーザーが選択した行を取得した場合を考えます:

 C_OBJECT($userSelection;$rows)

 

 $userSelection:=WP Selection range(myWPArea)

 

 $rows:=WP Table get rows($userSelection)

参照

WP Insert table
WP Table append row
WP Table get cells
WP Table get columns