LISTE IMAGES DANS BIBLIOTHEQUE

4D v16.3


LISTE IMAGES DANS BIBLIOTHEQUE ( refsImages ; nomsImages )

Paramètre	Type	Description
refsImages	Tableau entier long	Numéros de référence des images stockées dans la bibliothèque d'images
nomsImages	Tableau chaîne	Noms des images stockées dans la bibliothèque d'images

Description

La commande LISTE IMAGES DANS BIBLIOTHEQUE retourne les numéros de référence et le nom des images stockées dans la bibliothèque d’images de la base de données.

Après l’appel, vous récupérez les numéros de référence des images dans le tableau refsImages et leurs noms dans le tableau nomsImages. Les deux tableaux sont synchronisés : le nième élément de refsImages est le numéro de référence de l'image de la bibliothèque dont le nom est retourné dans le nième élément de nomsImages.

Si nécessaire, la commande crée et dimensionne automatiquement les tableaux refsImages et nomsImages.

La longueur maximale du nom d’une image de la bibliothèque est de 255 caractères.

Si la bibliothèque d’images est vide, les deux tableaux retournés seront vides.

Pour obtenir le nombre d’images contenues dans la bibliothèque, il vous suffit de tester la taille d’un des deux tableaux à l'aide de la fonction Taille tableau.

Exemple 1

Le code suivant retourne le contenu de la bibliothèque d'images dans les tableaux telRefImage et taNomImage :

LISTE IMAGES DANS BIBLIOTHEQUE(telRefImage;taNomImage)

Exemple 2

L’exemple suivant teste si la bibliothèque d’images est vide ou non :

 LISTE IMAGES DANS BIBLIOTHEQUE(telRefImage;taNomImage)

 Si(Taille tableau(telRefImage)=0)

    ALERTE("La bibliothèque d’images est vide.")

 Sinon

    ALERTE("La bibliothèque d’images contient "+Chaine(Taille tableau(tlRefImage))+" images.")

 Fin de si

Exemple 3

L'exemple suivant exporte la Bibliothèque d’Images vers un document stocké sur disque :

 LISTE IMAGES DANS BIBLIOTHEQUE($alRefImage;$asNomImage)

 $vlNbImages:=Taille tableau($alRefImage)

 Si($vlNbImages>0)

    REGLER SERIE(12;"")

    Si(OK=1)

       $vsTag:="4DV6PICTURELIBRARYEXPORT"

       ENVOYER VARIABLE($vsTag)

       ENVOYER VARIABLE($vlNbImages)

       gError:=0

       Boucle($vlImage;1;$vlNbImages)

          $vlRefImage:=$alRefImage{$vlImage}

          $vsNomImage:=$asNomImage{$vlImage}

          LIRE IMAGE DANS BIBLIOTHEQUE($alRefImage{$vlImage};$vgImage)

          Si(OK=1)

             ENVOYER VARIABLE($vlRefImage)

             ENVOYER VARIABLE($vsNomImage)

             ENVOYER VARIABLE($vgImage)

          Sinon

             $vlImage:=$vlImage+1

             gError:=-108

          Fin de si

       Fin de boucle

       REGLER SERIE(11)

       Si(gError#0)

          ALERTE("La bibliothèque d'images n'a pas pu être exportée, recommencez avec davantage de mémoire.")

          SUPPRIMER DOCUMENT(Document)

       Fin de si

    Fin de si

 Sinon

    ALERTE("La bibliothèque d'images est vide.")

 Fin de si

Voir aussi

ECRIRE IMAGE DANS BIBLIOTHEQUE
LIRE IMAGE DANS BIBLIOTHEQUE
SUPPRIMER IMAGE DANS BIBLIOTHEQUE