MAIL Convert from MIME

4D v18

Mail


MAIL Convert from MIME ( mime ) -> Resultado

Parâmetro	Tipo	Descrição
mime	BLOB, Texto	Email em MIME
Resultado	Objeto	Objeto email

Descrição

O comando MAIL Convert from MIME converte um documento MIME para um objeto email válido.

Nota: 4D segue a especificação JMAP para formatar o objeto email retornado.

Passe em mime um documento MIME válido para converter. Pode ser fornecido por qualquer servidor de mail ou aplicação. Pode passar um parâmetro BLOB ou mime. Se o MIME vier de um arquivo, é recomendado usar um parâmetro BLOB para evitar problemas relacionadas a conversões de charset e quebras de linha.

Valor retornado

Objeto Email Para uma descrição detalhada deste objeto, veja o método transporter.send( ).

Exemplo 1

Se quiser carregar um modelo mail salvado como um documento texto MIME e enviar um email:

 C_BLOB($mime)

 C_OBJECT($mail;$server;$transporter;$status)

 

 $mime:=File("/PACKAGE/Mails/templateMail.txt").getContent())

 

 $mail:=MAIL Convert from MIME($mime)

 $mail.to:="smith@mail.com"

 $mail.subject:="Hello world"

 

 $server:=New object

 $server.host:="smtp.gmail.com"

 $server.port:=465

 $server.user:="test@gmail.com"

 $server.password:="XXXX"

 

 $transporter:=SMTP New transporter($server)

 $status:=$transporter.send($mail)

Exemplo 2

Neste exemplo, pode enviar diretamente um documento 4D Write Pro contendo imagens:

 C_TEXT($mime)

 C_OBJECT($email;$server;$transporter;$status)

 

  // Exportação Mime do documento 4D Write Pro

 WP EXPORT VARIABLE(WParea;$mime;wk mime html)

 

  // converter variável 4D Write Pro Mime no objeto mail

 $email:=MAIL Convert from MIME($mime)

 

  // Preencher os cabeçalhos de objeto mail

 $email.subject:="4D Write Pro HTML body"

 $email.from:="YourEmail@gmail.com"

 $email.to:="RecipientEmail@mail.com"

 

 $server:=New object

 $server.host:="smtp.gmail.com"

 $server.port:=465

 $server.user:="YourEmail@gmail.com"

 $server.password:="XXXX"

 

 $transporter:=SMTP New transporter($server)

 $status:=$transporter.send($email)

Ver também

attachment.getContent( )
SMTP_transporter.send( )