MAIL Convert from MIME

Home

4D v18

Mail


MAIL Convert from MIME ( mime ) -> Funktionsergebnis

Parameter	Typ	Beschreibung
mime	BLOB, Text	E-Mail in MIME
Funktionsergebnis	Objekt	E-Mail Objekt

Beschreibung

Der Befehl MAIL Convert from MIME konvertiert ein MIME Dokument in ein gültiges E-Mail Objekt.

Hinweis: 4D richtet sich beim Formatieren des zurückgegebenen E-Mail Objekts nach der JMAP specification.

In mime übergeben Sie ein gültiges MIME Dokument zum Konvertieren. Es kann von einem beliebigen Mail Server bzw. beliebiger Anwendung kommen. Sie können ein BLOB oder einen Text übergeben. Stammt MIME aus einer Datei, empfehlen wir den Typ BLOB, um Probleme beim Konvertieren von Text-Encoding und Zeilenumbrüchen zu vermeiden.

Zurückgegebener Wert

Email Objekt. Weitere Informationen dazu finden Sie in der Methode transporter.send().

Beispiel 1

Eine Mail Vorlage, die als MIME gesichert ist, in ein Textdokument laden und ein E-Mail senden.

 C_BLOB($mime)

 C_OBJECT($mail;$server;$transporter;$status)

 

 $mime:=File("/PACKAGE/Mails/templateMail.txt").getContent())

 

 $mail:=MAIL Convert from MIME($mime)

 $mail.to:="smith@mail.com"

 $mail.subject:="Hello world"

 $server:=New object

 $server.host:="smtp.gmail.com"

 $server.port:=465

 $server.user:="test@gmail.com"

 $server.password:="XXXX"

 

 $transporter:=SMTP New transporter($server)

 $status:=$transporter.send($mail)

Beispiel 2

Ein 4D Write Pro Dokument mit Bildern direkt senden:

 C_TEXT($mime)

 C_OBJECT($email;$server;$transporter;$status)

 

  // Mime Export des 4D Write Pro Dokuments

 WP EXPORT VARIABLE(WParea;$mime;wk mime html)

 

  // 4D Write Pro Mime Variable in Mail Objekt konvertieren

 $email:=MAIL Convert from MIME($mime) // Ihre Mail Objekte Header füllen

 $email.subject:="4D Write Pro HTML body"

 $email.from:="YourEmail@gmail.com"

 $email.to:="RecipientEmail@mail.com"

 

 $server:=New object

 $server.host:="smtp.gmail.com"

 $server.port:=465

 $server.user:="YourEmail@gmail.com"

 $server.password:="XXXX"

 

 $transporter:=SMTP New transporter($server)

 $status:=$transporter.send($email)

Siehe auch

attachment.getContent( )
SMTP_transporter.send()