MAIL Convert from MIME

4D v18


MAIL Convert from MIME ( mime ) -> 戻り値

引数	型	説明
mime	BLOB, テキスト	MIME形式のEメール
戻り値	Object	Eメーrオブジェクト

説明

MAIL Convert from MIME コマンドは、MIME ドキュメントを有効なEメールオブジェクトへと変換します。

注: 4D が返すEメールオブジェクトはJMAP specification に準拠しています。

mime 引数には、変換する有効なMIME ドキュメントを渡します。これはどのメールサーバーまたはアプリケーションからでも提供可能です。mime 引数にはBLOBまたはテキストを渡すことができます。MIME がファイルから渡される場合、文字セットと改行コード変換に関する問題を避けるため、BLOB型の引数を使用することが推奨されます。

返される値

Email オブジェクト。このオブジェクトについての詳細な説明については、transporter.send( ) メソッドを参照してください。

例題 1

テキストドキュメントにMIME として保存されたメールのテンプレートを読み込み、メールを送信したい場合を考えます:

 C_BLOB($mime)

 C_OBJECT($mail;$status)

 

 $mime:=File("/PACKAGE/Mails/templateMail.txt").getContent())

 

 $mail:=MAIL Convert from MIME($mime)

 $mail.to:="smith@mail.com"

 $mail.subject:="Hello world"

 

 $server:=New object

 $server.host:="smtp.gmail.com"

 $server.port:=465

 $server.user:="test@gmail.com"

 $server.password:="XXXX"

 

 $transporter:=SMTP New transporter($server)

 $status:=$transporter.send($mail)

例題 2

この例題では、ピクチャーを含んでいる4D Write Pro ドキュメントを直接送信する場合を考えます:

 C_TEXT($mime)

 C_OBJECT($email;$server;$transporter;$status)

 

  // 4D Write Pro ドキュメントのMime 書き出し

 WP EXPORT VARIABLE(WParea;$mime;wk mime html)

 

  // 4D Write Pro Mime 変数をメールオブジェクトへと変換

 $email:=MAIL Convert from MIME($mime)

 

  // Eメールオブジェクトのヘッダーを入力

 $email.subject:="4D Write Pro HTML body"

 $email.from:="YourEmail@gmail.com"

 $email.to:="RecipientEmail@mail.com"

 

 $server:=New object

 $server.host:="smtp.gmail.com"

 $server.port:=465

 $server.user:="YourEmail@gmail.com"

 $server.password:="XXXX"

 

 $transporter:=SMTP New transporter($server)

 $status:=$transporter.send($email)

参照

attachment.getContent( )
SMTP_transporter.send( )