MAIL Convertir depuis MIME

4D v18

Mail


MAIL Convertir depuis MIME ( mime ) -> Résultat

Paramètre	Type	Description
mime	BLOB, Texte	Mail en MIME
Résultat	Objet	Objet mail

Description

La commande MAIL Convertir depuis MIME convertit un document MIME en un objet mail valide.

Note: Dans 4D, le format de l'objet mail retourné suit la spécification JMAP.

Dans mime, passez un document MIME valide à convertir. Il peut être fourni par tous types de serveur ou d'application. Vous pouvez passer un BLOB ou texte un paramètre mime. Si le MIME provient d'un fichier, il est recommandé d'utiliser un paramètre BLOB pour éviter les problèmes liés aux conversions de charset et de retour à la ligne.

Valeur retournée

Objet mail. Pour une description plus détaillée de cet objet, veuillez vous reporter à la méthode transporteur.send( ).

Exemple 1

Vous souhaitez charger un template mail enregistré au format MIME dans un document texte et l'envoyer par e-mail :

 C_BLOB($mime)

 C_OBJET($mail;$status)

 

 $mime:=Fichier("/PACKAGE/Mails/templateMail.txt").getContent())

 

 $mail:=MAIL Convertir depuis MIME($mime)

 $mail.to:="smith@mail.com"

 $mail.subject:="Hello world"

 $server:=Creer objet

 $server.host:="smtp.gmail.com"

 $server.port:=465

 $server.user:="test@gmail.com"

 $server.password:="XXXX"

 

 $transporter:=SMTP Creer transporteur($server)

 $status:=$transporter.send($mail)

Exemple 2

Dans cet exemple, vous envoyez directement un document 4D Write Pro contenant des images :

 C_TEXTE($mime)

 C_OBJET($email;$server;$transporter;$status)

 

  // Export Mime du document 4D Write Pro

 WP EXPORT VARIABLE(WParea;$mime;wk mime html)

 

  // convertir la variable Mime de 4D Write Pro en objet e-mail

 $email:=MAIL Convertir depuis MIME($mime)</p><p> // Remplir les en-têtes de l'objet e-mail

 $email.subject:="4D Write Pro HTML body"

 $email.from:="YourEmail@mail.com"

 $email.to:="RecipientEmail@mail.com"

 

 $server:=Creer objet

 $server.host:="smtp.gmail.com"

 $server.port:=465

 $server.user:="YourEmail@gmail.com"

 $server.password:="XXXX"

 

 $transporter:=SMTP Creer transporteur($server)

 $status:=$transporter.send($email)

Voir aussi

piecejointe.getContent( )
SMTP_transporteur.send( )