MAIL Convert to MIME

4D v18

Mail


MAIL Convert to MIME ( eMail {; opções} ) -> Resultado

Parâmetro	Tipo	Descrição
eMail	Objeto	Objeto de email
opções	Objeto	Charset e opções de codificação de mail
Resultado	Texto	Objeto email convertido a MIME

Descrição

O comando MAIL Convert to MIME converte um objeto email em texto MIME. Este comando é chamado internamente por SMTP_transporter.send( ) para formatar o objeto email antes de enviá-lo. Pode ser utilizado para analisar o formato MIME do objeto.

Em eMail, passe o conteúdo e os detalhes da estrutura de email a converter. Isto inclui informação como os endereços de correio eletrônico (remetente e destinatario(s)), a mensagem em si e o tipo de visualização da mensagem.
Para saber mais sobre o objeto de correio eletrônico, consulte a descrição do método SMTP_transporter.send( ).

Nota: 4D segue a especificação JMAP para formatar o objeto email.

Em opções, pode estabelecer um conjunto de caracteres e configuração de codificação para eMail. As propriedades abaixo estão disponíveis:

Propriedade

Tipo

Descrição

headerCharset

Text

Charset e codificação usada para as partes a seguir do email: tema, nomes de arquivos de anexos, e atributos de nome de email. Valores possíveis:

Constante	Valor	Comentário
mail mode ISO2022JP	US-ASCII_ISO-2022-JP_UTF8_QP	headerCharset: US-ASCII se for possível, japonês (ISO-2022-JP) & Quoted-printable i se for possível, se não UTF-8 & Quoted-printable bodyCharset: US-ASCII se for possível, japonês (ISO-2022-JP) & 7 bits se for possível, do contrário UTF-8 & Quoted-printable
mail mode ISO88591	ISO-8859-1
mail mode UTF8	US-ASCII_UTF8_QP	headerCharset & bodyCharset: US-ASCII se for possível, do contrário UTF-8 & Quoted-printable (valor predeterminado)

bodyCharset

Text

Charset e codificação usada para o conteúdo de corpo de texto e html do email. Valores possíveis: mesmo que para headerCharset (ver acima)

Se o parâmetro opções for omitido, a configuração mail mode UTF8 é usada para cabeçalho e partes de corpo.

Exemplo

 C_OBJECT($mail)

 C_TEXT($mime)

 $mail:=New object

 

  // Criação de um mail

 $mail.from:="tsales@massmarket.com"

 $mail.subject:="Terrific Sale! This week only!"

 $mail.textBody:="Text format email"

 $mail.htmlBody:="<html><body>HTML format email</body></html>"

 $mail.to:=New collection

 $mail.to.push(New object("email";"noreply@4d.com"))

 $mail.to.push(New object("email";"test@4d.com"))

 

  // transformar o objeto mail em MIME

 $mime:=MAIL Convert to MIME($mail)

 

  // Conteúdos de $mime:

  // MIME-Version: 1.0

  // Date: Thu, 11 Oct 2018 15:42:25 GMT

  // Message-ID: <7CA5D25B2B5E0047A36F2E8CB30362E2>

  // Sender: tsales@massmarket.com

  // From: tsales@massmarket.com

  // To: noreply@4d.com

  // To: test@4d.com

  // Content-Type: multipart/alternative; boundary="E0AE5773D5E95245BBBD80DD0687E218"

  // Subject: Terrific Sale! This week only!

  //

  // --E0AE5773D5E95245BBBD80DD0687E218

  // Content-Type: text/plain; charset="UTF-8"

  // Content-Transfer-Encoding: quoted-printable

  //

  // Text format email

  // --E0AE5773D5E95245BBBD80DD0687E218

  // Content-Type: text/html; charset="UTF-8"

  // Content-Transfer-Encoding: quoted-printable

  //

  // <html><body>HTML format email</body></html>

  // --E0AE5773D5E95245BBBD80DD0687E218--

Ver também

SMTP New transporter
SMTP_transporter.send( )