MAIL Convert from MIME

4D v18

Mail


MAIL Convert from MIME ( mime ) -> Resultado

Parámetro	Tipo	Descripción
mime	BLOB, Texto	Email en MIME
Resultado	Objeto	Objeto email

Descripción

El comando MAIL Convert from MIME convierte un documento MIME en un objeto de correo electrónico válido.

Nota: 4D sigue la especificación JMAP para formatear el objeto de correo electrónico devuelto.

Pase en mime un documento MIME válido a convertir. Puede ser suministrado para todos los tipos de servidor o de aplicación. Puede pasar un parámetro mime BLOB o texto. Si el MIME proviene de un archivo, se recomienda utilizar un parámetro BLOB para evitar los problemas relacionados con las conversiones de caracteres y de saltos de línea.

Valor devuelto

Objeto Email. Para una descripción detallada de este objeto, consulte el método transporter.send( ).

Ejemplo 1

Usted desea cargar una plantilla de correo guardada como MIME en un documento de texto y enviar un correo electrónico:

 C_BLOB($mime)

 C_OBJECT($mail;$server;$transporter;$status)

 

 $mime:=File("/PACKAGE/Mails/templateMail.txt").getContent())

 

 $mail:=MAIL Convert from MIME($mime)

 $mail.to:="smith@mail.com"

 $mail.subject:="Hello world"

 

 $server:=New object

 $server.host:="smtp.gmail.com"

 $server.port:=465

 $server.user:="test@gmail.com"

 $server.password:="XXXX"

 

 $transporter:=SMTP New transporter($server)

 $status:=$transporter.send($mail)

Ejemplo 2

En este ejemplo, usted envía directamente un documento 4D Write Pro que contiene las imágenes:

 C_TEXT($mime)

 C_OBJECT($email;$server;$transporter;$status)

 

  // Export Mime del documento 4D Write Pro

 WP EXPORT VARIABLE(WParea;$mime;wk mime html)

 

  // convierte la variable Mime de 4D Write Pro en objeto mail

 $email:=MAIL Convert from MIME($mime)

 

  //Llena los encabezados de su objetos mail

 $email.subject:="4D Write Pro HTML body"

 $email.from:="YourEmail@gmail.com"

 $email.to:="RecipientEmail@mail.com"

 

 $server:=New object

 $server.host:="smtp.gmail.com"

 $server.port:=465

 $server.user:="YourEmail@gmail.com"

 $server.password:="XXXX"

 

 $transporter:=SMTP New transporter($server)

 $status:=$transporter.send($email)

Ver también

attachment.getContent( )
SMTP_transporter.send( )