MAIL Convert to MIME

4D v18


MAIL Convert to MIME ( mail {; options} ) -> 戻り値

引数	型	説明
mail	Object	Email オブジェクト
options	Object	文字セットとエンコーディングのメールオプション
戻り値	テキスト	MIMEへと変換されたEmailオブジェクト

説明

MAIL Convert to MIME コマンドはEメールオブジェクトをMIME テキストへと変換します。このコマンドは、Eメールオブジェクトを送信する前に整形する目的でSMTP_transporter.send( ) コマンドによって内部的に呼び出されます。また、オブジェクトのMIME フォーマットを解析するためにも使用されます。

eMail 引数には、変換するEメールのコンテンツとストラクチャーの詳細を渡します。この情報にはEメールアドレス(送信者と受信者)、メッセージそのもの、メッセージの表示タイプなどが含まれます。
オブジェクトについてのより詳細な情報については、SMTP_transporter.send( ) のメソッドの詳細を参照してください。

注: 4D は、JMAP specification に従ってEメールオブジェクトの整形を行います。

options 引数を使用すると、eMail 引数のメールに対して特定の文字セットとエンコーディング設定を設定することができます。以下のプロパティが利用可能です:

プロパティ

型

詳細

headerCharset

テキスト

eメールの以下の部分に使用される文字セットとエンコーディング: 主題、添付ファイル名、eメール名属性。取りうる値:

定数	値	コメント
mail mode ISO2022JP	US-ASCII_ISO-2022-JP_UTF8_QP	headerCharset: 可能ならUS-ASCII 、次に可能ならJapanese (ISO-2022-JP) & Quoted-printable 、それも不可なら UTF-8 & Quoted-printable bodyCharset: 可能ならUS-ASCII、次に可能ならJapanese (ISO-2022-JP) & 7-bit、それも不可なら UTF-8 & Quoted-printable
mail mode ISO88591	ISO-8859-1	headerCharset: ISO-8859-1 & Quoted-printable bodyCharset: ISO-8859-1 & 8-bit
mail mode UTF8	US-ASCII_UTF8_QP	headerCharset & bodyCharset: 可能ならUS-ASCII、それが不可ならUTF-8 & Quoted-printable (デフォルト値)

bodyCharset

テキスト

eメールのhtmlおよびテキスト本文コンテンツに使用される文字セットとエンコーディング。取りうる値: headerCharset と同じ(上記参照)

options 引数が省略されていた場合、ヘッダーおよび本文においてはmail mode UTF8 設定が使用されます。

例題

 C_OBJECT($mail)

 C_TEXT($mime)

 $mail:=New object

 

  // メールを作成

 $mail.from:="tsales@massmarket.com"

 $mail.subject:="Terrific Sale! This week only!"

 $mail.textBody:="Text format email"

 $mail.htmlBody:="<html><body>HTML format email</body></html>"

 $mail.to:=New collection

 $mail.to.push(New object("email";"noreply@4d.com"))

 $mail.to.push(New object("email";"test@4d.com"))

 

  // メールオブジェクトをMIMEへと変換

 $mime:=MAIL Convert to MIME($mail)

 

  // $mime の中身:

  // MIME-Version: 1.0

  // Date: Thu, 11 Oct 2018 15:42:25 GMT

  // Message-ID: <7CA5D25B2B5E0047A36F2E8CB30362E2>

  // Sender: tsales@massmarket.com

  // From: tsales@massmarket.com

  // To: noreply@4d.com

  // To: test@4d.com

  // Content-Type: multipart/alternative; boundary="E0AE5773D5E95245BBBD80DD0687E218"

  // Subject: Terrific Sale! This week only!

  //

  // --E0AE5773D5E95245BBBD80DD0687E218

  // Content-Type: text/plain; charset="UTF-8"

  // Content-Transfer-Encoding: quoted-printable

  //

  // Text format email

  // --E0AE5773D5E95245BBBD80DD0687E218

  // Content-Type: text/html; charset="UTF-8"

  // Content-Transfer-Encoding: quoted-printable

  //

  // <html><body>HTML format email</body></html>

  // --E0AE5773D5E95245BBBD80DD0687E218--

参照

SMTP New transporter
SMTP_transporter.send( )