SVG_Filter

4D v16

SVG_Filter_Blur


SVG_Filter_Blur ( refFiltre ; déviation {; entrée {; nom}} ) -> Résultat

Paramètre	Type	Description
refFiltre	Ref_SVG	Référence de filtre
déviation	Réel	Déviation standard pour l'opération de flou
entrée	Chaîne	Source de la primitive de filtre
nom	Chaîne	Cible de la primitive de filtre
Résultat	Ref_SVG	Référence de primitive

Description

La commande SVG_Filter_Blur définit un flou gaussien pour le filtre refFiltre et retourne sa référence. Si refFiltre n’est pas une référence de filtre, une erreur est générée.

Le paramètre déviation permet de définir la déviation standard pour l'opération de flou. Si le nombre est entier, la même déviation sera appliquée sur les axes X et Y. Si le nombre comporte une partie décimale, la partie entière représente la déviation à appliquer sur l'axe X et la partie décimale la déviation à appliquer sur l'axe Y.

Le paramètre optionnel entrée identifie la source graphique de la primitive de filtre. Vous pouvez passer :

soit "sourceGraphic", désignant le graphique comme source du filtre (défaut),
soit "sourceAlpha", désignant le canal alpha du graphique comme source du filtre.

Le paramètre optionnel nom est le nom éventuellement assigné au résultat de cette primitive de filtre.

Note : A compter de 4D v14 R5, cette commande fonctionne sous Windows avec Direct2D activé en mode logiciel (cf. constante Direct2D Logiciel dans la description de la commande SET DATABASE PARAMETER).

Exemple

Dans un formulaire, vous affichez deux images SVG identiques puis créez et affectez un filtre "blur" à l'image de droite :

 $root:=SVG_New(400;400;"filters test")  //définition de la première image (gauche)

 $rect:=SVG_New_rect($root;10;10;380;100;0;0;"darkblue";"white";1)

 SVG_SET_FILL_BRUSH($root;"orange")

 $textAreaRef:=SVG_New_textArea($root;"Hello World!";10;10;380;100;"arial";60;Plain;Align center)

 <>pict1:=SVG_Export_to_picture($root)  //affichage de la première image

 

 $root2:=SVG_New(400;400;"filters test") //définition de l'image de droite identique

 

   //création du filtre

 $filter1:=SVG_Define_filter($root2;"blur")

   // définition du filtre

 $vGraph:=True  //application sur la couche graphique - mettre à Faux pour la couche alpha

 If($vGraph)

    SVG_Filter_Blur($filter1;Deviation{Deviation};"sourceGraphic") 

 Else

    SVG_Filter_Blur($filter1;Deviation{Deviation};"sourceAlpha")

 End if

 

 $rect2:=SVG_New_rect($root2;10;10;380;100;0;0;"darkblue";"white";1) //définition de l'image de droite identique

 SVG_SET_FILL_BRUSH($root2;"orange")

 $textAreaRef2:=SVG_New_textArea($root2;"Hello World!";10;10;380;100;"arial";60;Plain;Align center)

 

 SVG_SET_FILTER($textAreaRef2;"blur") //application du filtre

 <>pict2:=SVG_Export_to_picture($root2) //affichage de la seconde image

Résultat (entrée = sourceGraphic) :

Résultat (entrée = sourceAlpha) :

Voir aussi

SVG_Filter_Blend
SVG_Filter_Offset