SVG_Filter

4D v16

SVG_Filter_Blur


SVG_Filter_Blur ( refFiltro ; desviación {; entrada {; nombre}} ) -> Resultado

Parámetro	Tipo	Descripción
refFiltro	Ref_SVG	Referencia de filtro
desviación	Real	Desviación estándar para la operación de volver borroso
entrada	Cadena	Fuerza de la primitiva de filtro
nombre	Cadena	Objetivo de la primitiva de filtro
Resultado	Ref_SVG	Referencia de la primitiva

Descripción

El comando SVG_Filter_Blur define un desenfoque Gaussiano para el filtro refFiltro y devuelve su referencia. Si refFiltro no es una referencia de filtro, se genera un error.

El parámetro desviación permite definir la desviación estándar para la operación de desenfoque. Si el número es un número entero, la misma desviación se aplicará a los ejes X e Y. Si el número incluye una parte decimal, la parte entera representa la desviación que se aplicará al eje X y la parte decimal representa la desviación que se aplicará al eje Y.

El parámetro opcional entrada identifica la fuente gráfica de la primitiva de filtro. Puede pasar:

"sourceGraphic", indicando que el gráfico es la fuente del filtro (por defecto),
o "sourceAlpha", que indica que el canal alpha es la fuente del filtro.

El parámetro opcional nombre es el nombre asignado al resultado de esta primitiva de filtro.

Nota: a partir de 4D v14 R5, este comando funciona en Windows con Direct2D activado en modo software (ver la constante Direct2D disabled en la descripción del comando SET DATABASE PARAMETER).

Ejemplo

En un formulario, mostramos dos imágenes SVG idénticas luego creamos un filtro "blur" y lo asignamos a la imagen a la derecha:

 $root:=SVG_New(400;400;"filters test") //definición de primera imagen (izquierda)

 $rect:=SVG_New_rect($root;10;10;380;100;0;0;"darkblue";"white";1)

 SVG_SET_FILL_BRUSH($root;"orange")

 $textAreaRef:=SVG_New_textArea($root;"Hello World!";10;10;380;100;"arial";60;Normal;Align center)

 <>pict1:=SVG_Export_to_picture($root) //visualización de la primera imagen

 

 $root2:=SVG_New(400;400;"filters test") //definición de la imagen de la derecha idéntica

 

  //creación del filtro

 $filter1:=SVG_Define_filter($root2;"blur")

  // filter definition

 $vGraph:=True //aplicación en la capa gráfica - pase False para aplicar la capa alpha

 If($vGraph)

    SVG_Filter_Blur($filter1;Deviation{Deviation};"sourceGraphic")

 Else

    SVG_Filter_Blur($filter1;Deviation{Deviation};"sourceAlpha")

 End if

 

 $rect2:=SVG_New_rect($root2;10;10;380;100;0;0;"darkblue";"white";1) //definición de la imagen derecha idéntica

 SVG_SET_FILL_BRUSH($root2;"orange")

 $textAreaRef2:=SVG_New_textArea($root2;"Hello World!";10;10;380;100;"arial";60;Normal;Align center)

 

 SVG_SET_FILTER($textAreaRef2;"blur") //aplicación del filtro

 <>pict2:=SVG_Export_to_picture($root2) //visualización de la segunda imagen

Result (input = sourceGraphic):

Result (input = sourceAlpha):

Ver también

SVG_Filter_Blend
SVG_Filter_Offset