WR SET PICTURE IN PAGE INFO

4D Write v16


WR SET PICTURE IN PAGE INFO ( area ; pictureNumber ; page ; behind ; firstPage ; horizPos ; verticalPos ; width ; height )

引数	型	説明
area	倍長整数	4D Writeエリア
pictureNumber	倍長整数	ピクチャ番号
page	倍長整数	ピクチャの場所
behind	整数	0 =ピクチャはテキストの上 1 =ピクチャはテキストの後
firstPage	整数	*廃止、使用しないでください*
horizPos	倍長整数	ページ内の水平位置
verticalPos	倍長整数	ページ内の垂直位置
width	倍長整数	現在のピクチャの幅
height	倍長整数	現在のピクチャの高さ

説明

WR SET PICTURE IN PAGE INFOコマンドは、pictureNumberで指定された番号のピクチャの属性を変更できます。

警告: このコマンドは、テキストフロー内に挿入されたピクチャには使用できません。

pageでピクチャをどのページに表示するかを指定できます。そのためにはpageにページ番号を渡します。このページ番号は環境設定ダイアログで設定されているページ番号付けを考慮する必要があります。

pageが-11の場合、奇数ページと偶数ページでヘッダが異なる場合、ピクチャはページの右側に表示されます。
pageが-12の場合、奇数ページと偶数ページでヘッダが異なる場合、ピクチャはページの左側に表示されます。
pageが-4の場合、設定は変更されません。

behind: この引数にはWR Parametersテーマの以下の定数を渡すことができます。:

定数	型	値	コメント
wr above text	倍長整数	0	ピクチャをテキストの上に挿入する
wr behind text	倍長整数	1	ピクチャはテキストの後ろに挿入される。この場合、テキストと背景の属性に注意を払う必要があります。"なし"を選択するとテキストの後ろのピクチャを表示することができます。

firstPage: この引数は互換性のためにのみ保持されています。バージョン2004以降は使用せず、-1を渡してください。

horizPosとverticalPosで、物理的ページの左上隅を基点として、ピクチャの左上隅の水平および垂直座標を指定できます。horizPosの値は0からページの全幅までの間で設定できます。この場合、プリンタのマージンは考慮されず、ピクチャはページ中の印刷可能領域の外に配置されることもあります。

Note: ユーザーモードでピクチャをペーストする場合、プリンタのマージンは考慮されます。

widthとheightはピクチャの新しいサイズを指定できます。値はドキュメントのカレントデフォルト単位で指定します。

Note: behind, firstPage, horizPos, verticalPos, width そして height引数に-1を渡すと、コマンド実行時に設定されていた値は変更されません。

例題

同じピクチャを異なるドキュメントに挿入します:

 C_REAL($PosHoriz;$PosVert;$PictWidth;$PictHeight;$OrigWidth;$OrigHeight;$TxtMgTop;$HeadMgBottom)

 WR SET DOC PROPERTY(Area;wr view mode;0)

 $PosHoriz:=WR Get doc property(Area;wr text left margin)

 $PosVert:=WR Get doc property(Area;wr header top margin)

 ALL RECORDS([Interface])

  `ピクチャを挿入

 WR INSERT PICTURE(Area;[Interface]Logo;-1;$PosHoriz;$PosVert;1;0) `ピクチャはLogoフィールドに格納されている

 WR SELECT PICTURE IN PAGE(Area;1) `ピクチャを選択

  `ピクチャ属性を取得

 MyPict:=WR Get selected picture(Area;$NumPict)

 WR GET PICTURE IN PAGE INFO(Area;$NumPict;$Page;$Behind;$PageOne;$PosHoriz;$PosVert;$PictWidth;$PictHeight;$OrigWidth;$OrigHeight)

  `ピクチャサイズを50%縮小

 $PictHeight:=$PictHeight*1/2

 $PictWidth:=$PictWidth*1/2

 WR SET PICTURE IN PAGE INFO(Area;$NumPict;$Page;$Behind;$PageOne;$PosHoriz;$PosVert;$PictWidth;$PictHeight)

  `ヘッダにロゴを挿入できるかチェック

 $TxtMgTop:=WR Get doc property(Area;wr text top margin)

 $HeadMgBottom:=WR Get doc property(Area;wr header bottom margin)

 WR SET DOC PROPERTY(Area;wr text top margin;$PosVert+$PictHeight+$TxtMgTop+$HeadMgBottom)

 WR SET DOC PROPERTY(Area;wr header bottom margin;$PosVert+$PictHeight)

参照

WR GET PICTURE IN PAGE INFO