WR SET PICTURE IN PAGE INFO

4D Write v16


WR SET PICTURE IN PAGE INFO ( zone ; numImage ; page ; derrière ; pageUne ; posHoriz ; posVert ; largeur ; hauteur )

Paramètre	Type	Description
zone	Entier long	Zone 4D Write
numImage	Entier long	Numéro de l'image
page	Entier long	Endroit où l'image sera placée
derrière	Entier	0=Image sur le texte 1=Image sous le texte
pageUne	Entier	*Obsolète, à ne plus utiliser*
posHoriz	Entier long	Position horizontale dans la page
posVert	Entier long	Position verticale dans la page
largeur	Entier long	Largeur actuelle de l'image
hauteur	Entier long	Hauteur actuelle de l'image

Description

La commande WR FIXER INFO IMAGE DANS PAGE permet de modifier les informations de l'image dont le numéro a été passé en paramètre.

Attention : Cette commande ne s'applique pas aux images se trouvant dans le texte.

page permet de définir dans quelle page l'image doit être affichée. Pour cela, passez le numéro de la page. Il tient compte du début de numérotation.

Si page est égal à -11, l’image sera visible dans les pages droites si les en-têtes pairs et impairs sont différents, et sinon dans toutes les pages.
Si page est égal à -12, l’image sera visible dans les pages gauches si les en-têtes pairs et impairs sont différents.
Si page est égal à -4, la valeur n’est pas modifiée.

derrière : Vous pouvez passer dans le paramètre derrière l'une des constantes suivantes, placées dans le thème WR Paramètres :

Constante	Type	Valeur	Comment
wr sous le texte	Entier long	1	L'image sera sous le texte. Le texte comportera alors un fond transparent sauf si une couleur de fond lui avait au préalable été affectée.
wr sur le texte	Entier long	0	L'image sera sur le texte.

pageUne : Ce paramètre correspond à un ancien fonctionnement de la commande, il est conservé pour des raisons de compatibilité uniquement et ne doit plus être utilisé à compter de la version 2004. Passez -1 pour l'ignorer.

posHoriz et posVert permettent de fixer les coordonnées du point supérieur gauche de l'image par rapport à l'angle supérieur gauche du papier. Les valeurs sont exprimées dans l'unité courante. posHoriz peut être compris entre 0 et la largeur de la page. Dans ce cas, il n'est pas tenu compte des marges mortes et l'image peut se retrouver en dehors du document.

Note : Lorsque vous collez une image dans la page en mode Utilisation, elle est placée à l'intérieur des marges mortes.

largeur et hauteur permettent de fixer les nouvelles dimensions de l'image s'il y a une déformation éventuelle de celle-ci. Les valeurs sont exprimées dans l'unité courante.

Note : Si vous passez -1 dans les paramètres derrière, pageUne, posHoriz, posVert, largeur et hauteur, la valeur du paramètre concerné n’est pas modifiée.

Exemple

Vous désirez placer en fond d'en-tête une image d'habillage pour tous vos documents :

 C_REAL($PosHoriz;$PosVert;$LargImage;$HautImage;$LargOrig;$HauteurOrig;$TxtMgHaut;$EntMgBas)

 WR SET DOC PROPERTY(LaZone;wr view mode;0)

 $PosHoriz:=WR Get doc property(LaZone;wr text left margin)

 $PosVert:=WR Get doc property(LaZone;wr header top margin)

 ALL RECORDS([Interface])

  `Insertion de l'image

 WR INSERT PICTURE(LaZone;[Interface]Logo;-1;$PosHoriz;$PosVert;1;0) `L’image provient du champ Logo

 WR SELECT PICTURE IN PAGE(LaZone;1) `Sélection de l'image

  `Lecture des propriétés de l'image

 MonImage:=WR Get selected picture(LaZone;$NumImage)

 WR GET PICTURE IN PAGE INFO(LaZone;$NumImage;$Page;$Derriere;$PageUne;$PosHoriz;$PosVert;$LargImage;$HautImage;$LargOrig;$HautOrig)

  `Réduction de l'image de 50 %

 $HautImage:=$HautImage*1/2

 $LargImage:=$LargImage*1/2

 WR SET PICTURE IN PAGE INFO(LaZone;$NumImage;$Page;$Derriere;$PageUne;$PosHoriz;$PosVert;$LargImage;$HautImage)

  `Vérification que l'en-tête recouvre le logo

 $TxtMgHaut:=WR Get doc property(LaZone;wr text top margin)

 $EntMgBas:=WR Get doc property(LaZone;wr header bottom margin)

  `On descend le haut du texte pour retailler l'en-tête

 WR SET DOC PROPERTY(LaZone;wr text top margin;$PosVert+$HautImage+$TxtMgHaut+$EntMgBas)

  `On retaille la hauteur de l'en-tête

 WR SET DOC PROPERTY(LaZone;wr header bottom margin;$PosVert+$HautImage)

Voir aussi

WR GET PICTURE IN PAGE INFO