PV FIELDS LIST TO CELLS

4D View v16


PV FIELDS LIST TO CELLS ( zone ; direction ; colonnes ; lignes ; conversions ; primaire ; tabTables ; tabChamps )

Paramètre	Type	Description
zone	Entier long	Zone 4D View
direction	Entier	0 = Ligne; 1 = Colonne
colonnes	Tableau entier long	Tableau des numéros de colonnes de départ
lignes	Tableau entier long	Tableau des numéros de lignes de départ
conversions	Tableau entier long	0 = Valeurs non retypées; 1 = Valeurs retypées texte
primaire	Entier long	Numéro de table primaire
tabTables	Tableau entier long	Tableau des numéros de tables
tabChamps	Tableau entier long	Tableau des numéros de champs

Description

La commande PV LISTE CHAMPS VERS CELLULES est semblable à la commande PV CHAMP VERS CELLULES, mais peut utiliser plusieurs champs.

Note : L’usage du paramètre sens est différent de celui du paramètre direction des commandes PV ALLER A CELLULE SUIVANTE et PV LIRE CELL LIBRE SUIVANTE, pour lesquelles la direction peut être dans n'importe quel sens. En ce qui concerne la commande PV LISTE CHAMPS VERS CELLULES, le sens est soit vers la droite (0 = ligne), soit vers le bas (1 = colonne).

Les paramètres colonnes et lignes et contiennent respectivement les numéros de colonnes et de lignes des cellules de départ.

Le tableau conversions passé en cinquième paramètre permet, pour chaque champ, de retyper le contenu des cellules de destination en texte. Le type de la valeur source doit être compatible avec l’opération : si vous demandez le retypage d’un blob ou d’une image en texte, conversions sera ignoré pour l’élément de tableau concerné.

Les tableaux tabTables et tabChamps contiennent les numéros des tables et des champs sources.

La commande peut s'appliquer à des tables liées à la table primaire par des liens. Ces derniers doivent être de type automatique et aller de la table primaire vers la table du champ à afficher, défini par les tableaux tabTables et tabChamps.

À la différence des commandes du type PV AJOUTER CHAMPS DYNAMIQUES, qui maintiennent un lien dynamique avec la base de données, les modifications de valeurs effectuées dans la zone 4D View après leur récupération au moyen de PV LISTE CHAMPS VERS CELLULES ne sont pas répercutées dans le contenu des enregistrements.

Exemple

Reprenons l'exemple décrit dans la commande PV CHAMP VERS CELLULES pour un enregistrement de la table des clients. Cette fois-ci, nous afficherons les valeurs pendant l’événement formulaire Sur chargement, c'est-à-dire lors du chargement de ce formulaire entrée en modification. Nous traiterons trois champs simultanément.

Un lien automatique de la table primaire des contacts vers la table des titres professionnels permet de récupérer, dans le champ ad hoc de cette dernière, le libellé du titre de chaque contact à partir de son code de titre stocké sous forme d’entier (champ de départ du lien). Nous afficherons respectivement les noms, prénoms et titres dans les colonnes C à E, à partir de la ligne 2.

 C_LONGINT($Primaire) //N° de la table primaire

 C_LONGINT($Indice) //Indice de boucle

 

 $Primaire:=Table(->[Contacts]) //N° de la table primaire : les contacts (pour toutes les colonnes)

 

 ARRAY LONGINT($TabColonnes;3) //N°s de colonnes des cellules de départ

 ARRAY LONGINT($TabLignes;3) //N°s de lignes des cellules de départ

 ARRAY INTEGER($TabConversions;3) //0 valeurs non retypées ou 1 pour retypage en texte

 ARRAY INTEGER($TabTables;3) //N°s de tables

 ARRAY INTEGER($TabChamps;3) //N°s de champs

 

 For($Indice;1;3)

    $TabColonnes{$Indice}:=$Indice+2 //Colonnes C à E

    $TabLignes{$Indice}:=2 //À partir de la deuxième ligne

    $TabConversions{$Indice}:=0 //Conservons les types des champs

 End for

 

  //Tables et champs à récupérer

 $TabTables{1}:=Table(->[Contacts]) //N° de la table des contacts

 $TabChamps{1}:=Field(->[Contacts]NomDuContact) //N° du champ Nom

 

 $TabTables{2}:=Table(->[Contacts]) //N° de la table des contacts

 $TabChamps{2}:=Field(->[Contacts]PrénomDuContact) //N° du champ Prénom

 

 $TabTables{3}:=Table(->[Titres]) //N° de la table des titres types (liée)

 $TabChamps{3}:=Field(->[Titres]Libellé) //N° du champ Libellé (Directeur, Secrétaire, Développeur)

 

  //Récupération de la sélection des contacts correspondants

 RELATE MANY([Clients]code)

 

  //Mise à jour des colonnes avec les champs Nom, Prénom et Titre

 PV FIELDS LIST TO CELLS(Zone;1;$TabColonnes;$TabLignes;$TabConversions;$Primaire;$TabTables;$TabChamps)

Voir aussi

PV ADD DYNAMIC FIELDS
PV ARRAY TO CELLS
PV FIELD TO CELLS