PV FIELD TO CELLS

4D View v16

PV FIELD TO CELLS


PV FIELD TO CELLS ( zone ; direction ; colonne ; ligne ; conversion ; primaire ; numTable ; numChamp )

Paramètre	Type	Description
zone	Entier long	Zone 4D View
direction	Entier	0 = Ligne; 1 = Colonne
colonne	Entier long	Numéro de colonne de la cellule de départ
ligne	Entier long	Numéro de ligne de la cellule de départ
conversion	Entier	0 = Valeurs non retypées; 1 = Valeurs retypées texte
primaire	Entier	Numéro de la table primaire
numTable	Entier	Numéro de table
numChamp	Entier	Numéro de champ

Description

La commande PV CHAMP VERS CELLULES insère dans zone les valeurs de champ correspondant à la sélection courante de la table primaire. L’insertion s'effectue à partir de la cellule définie par les coordonnées colonne et ligne, dans la direction définie par le paramètre direction.

Note : L’usage du paramètre direction est différent de celui du paramètre direction des commandes PV ALLER A CELLULE SUIVANTE et PV LIRE CELL LIBRE SUIVANTE, pour lesquelles la direction peut être dans n'importe quel sens. En ce qui concerne la commande PV CHAMP VERS CELLULES, la direction est soit vers la droite (0 = ligne), soit vers le bas (1 = colonne).

Le cinquième paramètre, conversion, permet de retyper le contenu de la cellule de destination en texte. Le type de la valeur source doit être compatible avec cette opération : si vous demandez le retypage d’un blob ou d’une image en texte, conversion sera ignoré.

La commande peut s’appliquer à une table liée à la table primaire par un lien. Ce dernier doit être de type automatique et aller de la table définie par numPrimaire vers la table définie par numTable comportant le champ numChamp à afficher. Dans la structure traditionnelle des factures et des lignes de factures, il permet par exemple de récupérer le contenu d’un champ de la table des lignes, mais également de la table des factures par rapport à une sélection de la table des lignes de factures (table primaire).

À la différence des commandes du type PV FIXER CHAMP CELLULE, qui maintiennent un lien dynamique avec la base de données, les modifications de valeurs effectuées dans la zone 4D View après leur récupération au moyen de PV CHAMP VERS CELLULES ne sont pas répercutées dans le contenu des enregistrements.

Exemple

Dans l’exemple de la commande PV CELLULES VERS TABLEAU, nous mettons à jour la table des contacts suite à leur saisie dans une zone 4D View incluse dans le formulaire entrée des clients. Dans le cas présent, l'affichage ces valeurs sera effectué sur demande, à partir de la cellule courante.

Un lien automatique de la table primaire des contacts vers la table des titres professionnels (Directeur, Secrétaire, Développeur) permet de récupérer, dans le champ ad hoc de cette dernière, le libellé du titre de chaque contact à partir de son code de titre stocké sous forme d’entier (champ de départ du lien). Affichons dans deux colonnes (sens vertical) le nom du contact et son titre à partir de la cellule courante, qui recevra donc le premier nom.

 C_LONGINT($Primaire) //N° de la table primaire

 C_LONGINT($Table) //N° de table

 C_LONGINT($Champ) //N° de champ

 C_LONGINT($Colonne;$Ligne) //Coordonnées de la cellule de départ

 

 $Primaire:=Table(->[Contacts]) //N° de la table primaire : les contacts (pour les deux colonnes)

 RELATE MANY([Clients]code) //Récupération de la sélection des contacts correspondants

 PV GET CURRENT CELL(Zone;$Colonne;$Ligne)

 

  //Mise à jour de la zone 4D View pour les noms

 $Table:=Table(->[Contacts]) //N° de la table des contacts

 $Champ:=Field(->[Contacts]NomDuContact) //N° de champ dont le contenu est à récupérer

  //La conversion n'est pas nécessaire, nous récupérons de l'alphanumérique

 PV FIELD TO CELLS(Zone;1;$Colonne;$Ligne;0;$Primaire;$Table;$Champ)

 

  //Mise à jour de la zone 4D View pour les titres

 $Table:=Table(->[Titres]) //N° de la table des titres types (liée)

 $Champ:=Field(->[Titres]Libellé) //N° de champ dont le contenu est à récupérer

 PV FIELD TO CELLS(Zone;1;$Colonne+1;$Ligne;0;$Primaire;$Table;$Champ)

Voir aussi

PV ARRAY TO CELLS
PV FIELDS LIST TO CELLS
PV SET CELL FIELD