4D v13

WR INSERT HYPERLINK

ホーム

 
4D Write v13
4D Write
WRデータベースオブジェクト
WR INSERT HYPERLINK

WR INSERT HYPERLINK 


 

WR INSERT HYPERLINK ( area ; linkType ; urlStyle ; linkLabel ; linkContent ; methodRef ) 
引数 型   説明
area  倍長整数 in 4D Write エリア
linkType  整数 in ハイパーリンクタイプ： 0= メソッド、 1=URL、2=4D Write ドキュメント
urlStyle  整数 in URL の外観: 1= デフォルトスタイル、 0= カスタムスタイル
linkLabel  テキスト in リンクの表示テキスト (表示/値モード)
linkContent  テキスト in ハイパーリンクの値
methodRef  倍長整数 in $3の値、メソッドの3番目の値 (リンクタイプがメソッドの場合)

説明   

WR INSERT HYPERLINKコマンドは、area内の現在のカーソル位置またはテキストの現在選択している範囲にハイパーリンク参照を挿入します。

linkType
linkType は、挿入するハイパーテキストリンクのタイプを指定します。4D Writeには、URL タイプリンク、ドキュメントタイプリンク、メソッドタイプリンクの3つのハイパーテキストリンクを使用できます。

  • メソッドタイプリンクは、参照をクリックすることによって4Dメソッドを実行します。メソッドに関数は使用できません。また引数を渡すこともできません。しかし、$1、$2、オプションの$3 を通じて2 つまたは3 つの値を受け渡すことができます:
    • $1 （倍長整数）4D Write エリア参照番号を含む
    • $2（テキスト）リンクラベルの文字列を含む
    • $3（倍長整数）任意の数値を含む。methodRef 引数によってリンクを関連付け4D Write のユーザモードで使用することができる。
      データベースをコンパイルする場合には、これらの引き数を使わなくても、$1と$2を倍長整数、$3をテキストとして宣言する必要があります。
      メソッドタイプリンクの場合linkTypeに0 を挿入します。
  • URL タイプリンクはlinkContent で指定したURL をデフォルトブラウザでオープンします。URL タイプリンクの場合は、linkTypeに1を挿入します。
  • ドキュメントタイプリンクは、リンクがクリックするとlinkContent に格納されたパスによって現在のドキュメントを他のドキュメントに置換します。もちろんドキュメントを開くためにはドキュメントのフォーマットが4D_Write によって認識可能なものでなければなりません。ドキュメントタイプリンクの場合はlinkTypeに2を挿入します。

linkType引数には"WR Parameters"テーマの以下のいずれかの定数を渡します:

定数 型 値 コメント
wr method type link 倍長整数 0 メソッドタイプのリンクを挿入。
wr URL type link 倍長整数 1 URLタイプのリンクを挿入
wr document type link 倍長整数 2 ドキュメントタイプのリンクを挿入

urlStyle:
urlStyle を使用して、挿入したハイパーテキストリンクの外観を設定できます。この引数には"WR Parameters"テーマの以下のいずれかの 定数を渡します:

定数 型 値 コメント
wr custom link appearance 倍長整数 0 カスタマイズされたアピアランスの利用を許可します。この場合リンクを選択し、WR SET TEXT PROPERTYコマンドを使用してスタイルを定義できます。
wr default link appearance 倍長整数 1 デフォルトのハイパーリンクアピアランス (青色および下線) を保持します。デフォルトのカラーはWR SET DOC PROPERTYコマンドを使用してプログラムで変更できます。

定数wr custom link appearanceを使用してかつリンクスタイルを指定しない場合、リンクはカレントテキストとして表示されます (表示がリンクになりません)。

linkLabel:
linkLabel は、（表示/値モードでの）リンクの表示テキストを設定します。

linkContent:
linkContent は、ハイパーテキストリンクの値を設定します。値の性質は、リンクタイプに依存します:

  • 4Dメソッドタイプリンクの場合、メソッド名を指定します。例 "Order_Clients"
  • URLタイプリンクの場合、完全URLを設定します。例 "http://www.4d-japan.com"
  • ドキュメントタイプリンクの場合、ドキュメントへのフルパスを設定します。例 "（"C:\MyFolder\MyDoc.4w7" Windows の場合）、（"HardDrive:MyFolder:MyDoc" MacOSの場合）"

methodRef:
methodRef は、リンクにメソッドタイプを指定したときに、呼び出すメソッドに受け渡す値を設定します。メソッドは、引数$3 （倍長整数）の中の格納された値を受け取ることができます。

4D Write エリアにWeb サイトのURL を挿入します:

 WR INSERT HYPERLINK(area;wr URL type link;wr default link appearance;"Visit that great site";"http:/www.MySite.com/")

4D_Write ドキュメントに、ドキュメントタイプリンクによるプラットフォームに依存しないハイパーテキストのナビゲーション機能をあたえます。次のメソッドは、ドキュメントのパスを動的に管理します。:

 $Doc:=Structure file
 Doc:=$Doc
 While(Position(":";$Doc)#0)
    $Doc:=Substring($Doc;1+Position(":";$Doc);Length($Doc))
    $Long:=Length($Doc)
 End while
 Doc:=Substring(Doc;1;Length(Doc)-$Long)
 PLATFORM PROPERTIES($Platf;$Syst;$Computer)
 If($Platf=Windows)
    $name:=Doc+"Documentation"+"/"+"01_Introduction.4W7"
 Else
    $name:=Doc+"Documentation"+":"+"01_Introduction.4W7"
 End if
 $title:="See Documentation"
 WR INSERT HYPERLINK(Writearea;wr document type link;wr default link appearance;$title;$name)

メソッドタイプリンクの使用例です。この例は、ユーザに対してドキュメントの特定の場所に名字と名前を入力を要求します。$3 に設定した値（メソッド名）によってメソッドを起動します。そのメソッドがユーザに名前の入力を要求し、リンクを入力された名前に置き換えます:

  `Hyperlink_Method
 C_LONGINT($1;$3)
 C_TEXT($2)
 Case of
    :($3=1)
       WR INSERT TEXT($1;Request("Enter your first name"))
    :($3=2)
       WR INSERT TEXT($1;Request("Enter your last name"))
 End case
 WR GET SELECTION($1;$deb;$end)
 WR SET SELECTION($1;$deb;$end+1)
 WR EXECUTE COMMAND($1;wr cmd clear)

4D Writeエリアにメソッドタイプのリンクを挿入する:

 $title:="Click to enter"
 $method:="Hyperlink_Method"
 WR INSERT TEXT(Area;"Last name: ")
 WR INSERT HYPERLINK(Area;wr method type link;wr default link appearance;$title;$method;1)
 WR INSERT TEXT(Area;Char(Carriage return)+"First name: ")
 WR INSERT HYPERLINK(Area;wr method type link;wr default link appearance;"Click to enter";"Hyperlink_Method";2)

 
プロパティ 

プロダクト: 4D
テーマ: WRデータベースオブジェクト
番号: 89430

 
目次

コマンドリスト (文字順)

 
履歴 

初出: 4D Write 6.7

 
参照 

WR GET HYPERLINK