4D Doc Center : WR INSERT HYPERLINK

4D Write v13

WR INSERT HYPERLINK


WR INSERT HYPERLINK ( area ; tipoLink ; estiloURL ; etiquetaLink ; conteudoLink ; refMetodo )

Parâmetro	Tipo	Descrição
area	Inteiro longo	4D Write area
tipoLink	Inteiro	Hyperlink type: 0 = Method, 1 = URL, 2 = 4D Write Document
estiloURL	Inteiro	URL appearance: 1 = Default style, 0 = Custom style
etiquetaLink	Texto	Link’s visible text (View/Values mode)
conteudoLink	Texto	Hyperlink value
refMetodo	Inteiro longo	Value for $3, 3rd parameter of the method (if the link type is Method)

Descrição

O comando WR INSERT HYPERLINK insere dentro da área uma referencia de tipo "link hipertexto", na localização atual do cursor ou no lugar da seleção atual.

tipoLink

O parâmetro tipoLink define o tipo de link hipertexto a inserir. 4D Write permite três tipos de links hipertexto: os links de tipo método, os links de tipo URL e os links de tipo documento.

Um link de tipo método executa um método 4D quando faz um clique na referencia. O método não pode ser uma função e não é possível passar parâmetros. No entanto, pode receber dois ou três valores em $1, $2 e opcionalmente $3:

$1 (Inteiro longo) contém a referencia da área 4D Write,
$2 (Texto) contém a etiqueta do link,
$3 (Inteiro longo) contém um valor numérico arbitrário que pode ser associado com um link utilizando o parâmetro refMetodo ou através da interface de usuário da base.
Com o objetivo de compilar a base, é necessário declarar $1 e $3 como Inteiros longos e $2 como Texto, inclusive se não se utilizam.
Para adicionar um link de tipo de método, coloque 0 em tipoLink.

Um link de tipo URL abre o navegador por padrão e acessa a uma URL específica, definida no parâmetro conteudoLink. Para adicionarr um link de tipo URL, coloque 1 em tipoLink.
Um link de tipo document substitui, quando faz clique no link, o documento atual por outro documento cuja via foi definida no parâmetro conteudoLink. É claro, o formato do documento a abrir deve ser reconhecido por 4D Write. Para inserir um link de tipo Document, coloque 2 em tipoLink.

No parâmetro tipoLink, passe uma das seguintes constantes, que se encontram no tema "WR Parameters":

Constante	Tipo	Valor
wr method type link	Inteiro longo	0
wr URL type link	Inteiro longo	1
wr document type link	Inteiro longo	2

estiloURL:
O parâmetro estiloURL permite definir a aparência do link hipertexto inserido. Neste parâmetro, pode passar uma das seguintes constantes do tema "WR Parameters":

Constante	Tipo	Valor
wr custom link appearance	Inteiro longo	0
wr default link appearance	Inteiro longo	1

Se utilizar a constante wr custom link appearance e não definir o estilo do link, o link aparecerá como texto atual (não será materializado graficamente).

etiquetaLink:
O parâmetro etiquetLink define o texto visível do link (em modo Vista/Valores).

conteudoLink:
O parâmetro conteudoLink contém o valor hipertexto do link. A natureza deste valor depende do tipo de link:

Para um link de tipo método 4D, passe o nome do método (por exemplo "Order_Clients"),
Para um link de tipo URL, passe o URL completo (por exemplo “http://www.4D.com/”)
No caso de um link de tipo Document, passe a via completa do documento (por exemplo, "C:\MinhaPasta\MyDoc.4w7" em Windows o "DiscoDuro:MinhaPasta:MyDoc" em Mac OS).

refMetodo:
O parâmetro refMetodo permite, quando o link é de tipo método 4D, agregar um valor adicional ao método chamado. o método receberá este valor no parâmetro $3 (de tipo Inteiro longo).

Exemplo 1

Você quer inserir o URL de seu site web na área 4D Write:

WR INSERT HYPERLINK(area;wr URL type link;wr default link appearance;"Visite o site";"http:/www.MySite.com/")

Em seus documentos 4D Write, você propõe uma interface de navegação hipertexto baseada nos links de tipo document. O seguinte método gerencia dinamicamente as vias de acesso, sem importar a plataforma:

 $Doc:=Structure file

 Doc:=$Doc

 While(Position(":";$Doc)#0)

    $Doc:=Substring($Doc;1+Position(":";$Doc);Length($Doc))

    $Long:=Length($Doc)

 End while

 Doc:=Substring(Doc;1;Length(Doc)-$Long)

 PLATFORM PROPERTIES($Platf;$Syst;$Computer)

 If($Platf=Windows)

    $name:=Doc+"Documentation"+"/"+"01_Introduction.4W7"

 Else

    $name:=Doc+"Documentation"+":"+"01_Introduction.4W7"

 End if

 $title:="See Documentation"

 WR INSERT HYPERLINK(Writearea;wr document type link;wr default link appearance;$title;$name)

Exemplo 3

Este exemplo ilustra o emprego de links de tipo método. Em seu documento, você quer que o usuário possa introduzir a informação, por exemplo, seu nome e sobrenome, em uma localização específica. Para fazer isso, insira um link que chame ao método Hyperlink_Method. Este método pede ao usuário introduzir seu nome ou sobrenome, dependendo do valor passado em $3. Os dados introduzidos serão substituídos pelo link:

  `Hyperlink_Method

 C_LONGINT($1;$3)

 C_TEXT($2)

 Case of

    :($3=1)

       WR INSERT TEXT($1;Request("Escreva seu nome"))

    :($3=2)

       WR INSERT TEXT($1;Request("Escreva seu sobrenome"))

 End case

 WR GET SELECTION($1;$deb;$end)

 WR SET SELECTION($1;$deb;$end+1)

 WR EXECUTE COMMAND($1;wr cmd clear)

Para inserir o link de tipo de método na área 4D Write:

 $title:="Faça clique em introduzir"

 $method:="Hyperlink_Method"

 WR INSERT TEXT(Area;"Sobrenome: ")

 WR INSERT HYPERLINK(Area;wr method type link;wr default link appearance;$title;$method;1)

 WR INSERT TEXT(Area;Char(Carriage return)+"Nome: ")

 WR INSERT HYPERLINK(Area;wr method type link;wr default link appearance;"Faça clique para introduzir";"Hyperlink_Method";2)

4D v13

WR INSERT HYPERLINK

WR INSERT HYPERLINK

Descrição

Exemplo 1

Exemplo 2

Exemplo 3