4D v12.4

SUPPRIMER RESSOURCE

Accueil

 
4D v12.4
SUPPRIMER RESSOURCE

 

SUPPRIMER RESSOURCE 


 

SUPPRIMER RESSOURCE ( resType ; resNum {; resFichier} ) 
Paramètre Type   Description
resType  Chaîne in Type de ressource (4 caractères)
resNum  Entier long in Numéro de ressource
resFichier  RefDoc in Numéro de référence de fichier de ressources ou fichier de ressources courant si ce paramètre est omis

La commande SUPPRIMER RESSOURCE supprime la ressource dont vous passez le type dans le paramètre resType et le numéro dans resNum.

Si vous passez un numéro de référence de fichier de ressources dans le paramètre resFichier, 4D recherche la ressource dans ce fichier uniquement. Si vous ne passez pas le paramètre resFichier, 4D recherche la ressource dans tous les fichiers de ressources ouverts.

Si la ressource n'existe pas, SUPPRIMER RESSOURCE ne fait rien et la variable OK prend la valeur 0 (zéro). Si la ressource est correctement identifiée et effacée, la variable système OK prend la valeur 1.

ATTENTION : Ne supprimez pas de ressources appartenant à 4D ou à un fichier du système. Cette opération peut provoquer l'apparition d'erreurs système.

L'exemple suivant supprime la ressource "STR#" d'ID=20000:

  ` Notez que cet exemple supprimera la première ressource "STR#" ID=20000 rencontrée
  ` parmi tous les fichiers de ressources actuellement ouverts :
 SUPPRIMER RESSOURCE("STR#";20000)

L'exemple suivant supprime la ressource "STR#" d'ID=20000 si celle-ci est présente dans un fichier particulier :

  ` Notez que cet exemple supprimera la ressource "STR#" d'ID=20000
  ` seulement si elle est présente dans le fichier de ressources désigné par $vhResFile :
 SUPPRIMER RESSOURCE("STR#";20000;$vhResFile)
  ` Notez également que si une ressource identique existe dans un fichier de ressources ouvert
  ` autre que le fichier spécifié par vhResFile, elle restera inchangée

La méthode projet SUPPRIMER RESSOURCES DE TYPE supprime du fichier de ressources spécifié par le premier paramètre toutes les ressources du type spécifié par le second paramètre :

  ` Méthode projet SUPPRIMER RESSOURCES DE TYPE
  ` SUPPRIMER RESSOURCES DE TYPE ( Heure ; Alpha )
  ` SUPPRIMER RESSOURCES DE TYPE ( resFichier ; resType )
 
 C_HEURE($1)
 C_ALPHA(4;$2)
 
 LISTE RESSOURCES($2;$aiResID;$asResNom;$1)
 Si(OK=1)
    Boucle($vlElem;1;Taille tableau($aiResID))
       SUPPRIMER RESSOURCE($2;$aiResID{$vlElem};$1)
    Fin de boucle
 Fin de si

Une fois que cette méthode projet existe dans votre base, vous pouvez écrire :

  ` Supprimer toutes les ressources de type "PREF" du fichier de ressources $vhResFile
 SUPPRIMER RESSOURCES DE TYPE($vhResFile;"PREF")

La méthode projet SUPPRIMER RESSOURCE PAR NOM supprime une ressource (d'un type spécifique) dont vous connaissez le nom :

  ` Méthode projet SUPPRIMER RESSOURCE PAR NOM
  ` SUPPRIMER RESSOURCE PAR NOM ( Heure ; Alpha ; Alpha )
  ` SUPPRIMER RESSOURCE PAR NOM ( resFichier ; resType ; resNom )
 
 C_HEURE($1)
 C_ALPHA(4;$2)
 C_ALPHA(255;$3)
 
 LISTE RESSOURCES($2;$aiResID;$asResName;$1)
 Si(OK=1)
    $vlElem:=Chercher dans tableau($asResName;$3)
    Si($vlElem>0)
       SUPPRIMER RESSOURCE($2;$aiResID{$vlElem};$1)
    Fin de boucle
 Fin de si

Une fois que cette méthode projet existe dans votre base, vous pouvez écrire :

  ` Supprimer du fichier de ressources $vhResFile la ressource "PREF" dont le nom
  ` est “Réglages standard” :
 SUPPRIMER RESSOURCE PAR NOM($vhResFile;"PREF";"Réglages standard")

La variable OK prend la valeur 0 si la ressource n'existe pas ; si la ressource a été supprimée, OK prend la valeur 1.

 
PROPRIÉTÉS 

Produit : 4D
Thème : Ressources
Numéro : 501
Nom intl. : DELETE RESOURCE

Cette commande modifie la variable système OK

 
HISTORIQUE 

Créé : 4D v6

 
VOIR AUSSI  

ECRIRE PROPRIETES RESSOURCE
LISTE RESSOURCES