4D Doc Center : DELETE RESOURCE

4D v12.4

DELETE RESOURCE


DELETE RESOURCE ( ResTyp ; ResID {; RefDatei} )

Parameter	Typ	Beschreibung
ResTyp	String	Ressourcentyp mit 4 Zeichen
ResID	Lange Ganzzahl	Kennummer der Ressource
RefDatei	DokRef	Referenznummer der Ressourcendatei, ohne Angabe aktuelle Ressourcendatei

Beschreibung

Der Befehl DELETE RESOURCE löscht die Ressource vom Typ ResTyp mit der Nummer ResID.

Übergeben Sie in ResDatei eine gültige Referenznummer für die Ressourcendatei, wird die Ressource nur in dieser Datei gesucht. Übergeben Sie ResDatei nicht, wird die Ressource in der aktuellen geöffneten Ressourcendatei gesucht.

Warnung: Löschen Sie KEINE Ressourcen, die zu 4D oder anderen Systemdateien gehören. Das kann zu unerwünschten Systemfehlern führen.

Beispiel 1

Folgendes Beispiel löscht die Ressource "STR#" ID=20000:

  ` Beachten Sie, dass dieses Beispiel die erste gefundene Ressource

  ` "STR#" ID=20000 in jeder aktuell geöffneten Ressourcendatei löscht:

 DELETE RESOURCE("STR#";20000)

Beispiel 2

Folgendes Beispiel löscht die Ressource "STR#" ID=20000, wenn sie in einer spezifischen Ressourcendatei gefunden wird:

  ` Beachten Sie, daß dieses Beispiel die Ressource "STR#" ID=20000 nur löscht,

  ` wenn sie in der Ressourcendatei $vhResFile vorhanden ist:

 DELETE RESOURCE("STR#";20000;$vhResFile)

  ` Gibt es diese Ressource auch in einer anderen aktuell geöffneten

  ` Ressourcendatei, wird sie nicht gelöscht

Beispiel 3

Die Projektmethode DELETE RESOURCES OF TYPE löscht alle Ressourcen vom angegebenen Typ (zweiter Parameter) aus der angegebenen Ressourcendatei (erster Parameter):

  ` Projektmethode DELETE RESOURCES OF TYPE

  ` DELETE RESOURCES OF TYPE ( Zeit ; String )

  ` DELETE RESOURCES OF TYPE ( ResDatei ; ResTyp )

 

 C_TIME($1)

 C_STRING(4;$2)

 

 RESOURCE LIST($2;$aiResID;$asResName;$1)

 If(OK=1)

    For($vlElem;1;Size of array($aiResID))

       DELETE RESOURCE($2;$aiResID{$vlElem};$1)

    End for

 End if

Ist diese Projektmethode in die Datenbank integriert, können Sie schreiben:

  ` Lösche alle Ressourcen vom Typ "PREF" aus der Ressourcendatei $vhResFile

 DELETE RESOURCES OF TYPE($vhResFile;"PREF")

Beispiel 4

Die Projektmethode DELETE RESOURCE BY NAME löscht eine Ressource (eines spezifischen Typs) deren Name bekannt ist:

  ` Projektmethode DELETE RESOURCE BY NAME

  ` DELETE RESOURCE BY NAME ( Zeit ; String ; String )

  ` DELETE RESOURCE BY NAME ( ResDatei ; Restyp ; ResName )

 

 C_TIME($1)

 C_STRING(4;$2)

 C_STRING(255;$3)

 

 RESOURCE LIST($2;$aiResID;$asResName;$1)

 If(OK=1)

    $vlElem:=Find in array($asResName;$3)

    If($vlElem>0)

       DELETE RESOURCE($2;$aiResID{$vlElem};$1)

    End for

 End if

Ist diese Projektmethode in die Datenbank integriert, können Sie schreiben:

  `Lösche aus der Ressourcendatei $vhResFile die Ressource "PREF" mit dem Namen “Standardeinstellungen”:

 DELETE RESOURCE BY NAME($vhResFile;"PREF";"Standardeinstellungen")

Systemvariablen und Mengen

Wurde die Ressource gelöscht, wird die OK Variable auf 1 gesetzt, sonst auf 0 (Null).