RESOURCE TYPE LIST

Home

4D v16.3

RESOURCE TYPE LIST


RESOURCE TYPE LIST ( ResTypen {; ResDatei} )

Parameter	Typ	Beschreibung
ResTypen	Array String	Liste der verfügbaren Ressourcentypen
ResDatei	DokRef	Referenznummer der Ressourcendatei Ohne Angabe alle geöffneten Ressourcendateien

Beschreibung

Der Befehl RESOURCE TYPE LIST füllt das Array ResTypen mit den Ressourcentypen, die in den Ressourcen der aktuell geöffneten Ressourcendateien vorhanden sind.

Übergeben Sie in dem optionalen Parameter ResDatei eine gültige Referenznummer für die Ressourcendatei, erscheinen nur die Ressourcen aus dieser Datei. Übergeben Sie diesen Parameter nicht, erscheinen alle Ressourcen aus den derzeit geöffneten Ressourcendateien.

Sie können für das Array ResTypen vor dem Aufrufen von RESOURCE TYPE LIST den Typ String oder Text festlegen. Legen Sie nichts fest, erstellt der Befehl ResTypen als Array vom Typ Text.

Nach dem Aufruf können Sie über die Funktion Size of array die Anzahl der gefundenen Ressourcentypen im Array ResTypen prüfen.

Beispiel 1

Folgendes Beispiel füllt das Array atResType mit den Ressourcentypen, die in allen derzeit geöffneten Ressourcendateien vorhanden sind:

RESOURCE TYPE LIST(atResType)

Beispiel 2

Folgendes Beispiel teilt mit, ob die 4D Strukturdatei auf Macintosh alte 4D Plug-Ins enthält, die für den Einsatz der Datenbank unter Windows aktualisiert werden müssen:

 $vhResFile:=Open resource file(Structure file)

 RESOURCE TYPE LIST(atResType;$vhResFile)

 If(Find in array(atResType;"4DEX")>0)

    ALERT("Diese Datenbank enthält überholte Mac OS 4D Plug-Ins."+(Char(13)*2)+

    "Für den Einsatz unter Windows bitte aktualisieren.")

 End if

Hinweis: Alte Plug-Ins sind nicht nur in der Strukturdatei enthalten. Die Datenbank kann auch eine Datei Proc.Ext enthalten.

Beispiel 3

Folgende Projektmethode gibt die Anzahl der Ressourcen zurück, die in einer Ressourcendatei enthalten sind:

  ` Projektmethode Count resources

  ` Count resources ( Zeit ) -> Lange Ganzzahl

  ` Count resources ( DokRef ) -> Anzahl der Ressourcen

 

 C_LONGINT($0)

 C_TIME($1)

 

 $0:=0

 RESOURCE TYPE LIST($atResType;$1)

 For($vlElem;1;Size of array($atResType))

    RESOURCE LIST($atResType{$vlElem};$alResID;$atResName;$1)

    $0:=$0+Size of array($alResID)

 End for

Ist diese Projektmethode in eine Datenbank integriert, können Sie schreiben:

 $vhResFile:=Open resource file("")

 If(OK=1)

    ALERT("Die Datei “"+Dokument+"” enthält "+String(Count resources($vhResFile))

    +" Ressource(n).")

    CLOSE RESOURCE FILE($vhResFile)

 End if

Siehe auch

RESOURCE LIST