ADD RECORD

Home

4D v16.3

ADD RECORD


ADD RECORD ( {Tabellenname}{;}{*} )

Parameter	Typ	Beschreibung
Tabellenname	Tabelle	Tabelle für die Dateneingabe, oder Standardtabelle ohne Angabe
*		Rollbalken ausblenden

Beschreibung

Der Befehl ADD RECORD ermöglicht dem Benutzer, für Tabellenname einen neuen Datensatz in der Datenbank hinzuzufügen. Tabellenname ist optional. Wird dieser Parameter nicht angegeben, wird der Datensatz in der Standardtabelle angelegt.

ADD RECORD erstellt einen neuen Datensatz, macht diesen zum aktuellen Datensatz für den aktuellen Prozess und zeigt ihn im aktuellen Eingabeformular an. Sobald der Benutzer den neuen Datensatz in der Anwendungsumgebung bestätigt, ist er der einzige Datensatz in der aktuellen Auswahl.

Hier sehen Sie ein typisches Eingabeformular:

Das Formular erscheint im obersten Fenster des Prozesses mit Rollbalken und Kästchen für Größeneinstellung. Der optionale Parameter * blendet Rollbalken und Kästchen für Größeneinstellung aus.

ADD RECORD zeigt das Formular an, bis der Benutzer den Datensatz bestätigt oder annulliert. Der Befehl wird für jeden neuen Datensatz einmal ausgeführt.
Der Datensatz wird gesichert, wenn der Benutzer auf die Schaltfläche Bestätigen bzw. die Eingabetaste im Zahlenblock klickt oder der Befehl ACCEPT ausgeführt wird.
Der Datensatz wird nicht gesichert, wenn der Benutzer auf die Schaltfläche Abbrechen bzw. die Tastenkombination strg + Punkt unter Windows, Befehl + Punkt auf Macintosh verwendet oder der Befehl CANCEL ausgeführt wird.

Hinweis: Für diesen Befehl muss Tabellenname nicht im Lese-/Schreibmodus sein. Er lässt sich auch verwenden, wenn die Tabelle im Nur-Lesen Modus ist (siehe Überblick zu Datensatz sperren).

Die Systemvariable OK hat den Wert 1, wenn der Datensatz bestätigt wurde; den Wert 0, wenn er annulliert wurde.

Hinweis: Selbst wenn Sie die Eingabe annullieren, bleibt der Datensatz im Arbeitsspeicher und lässt sich mit SAVE RECORD sichern, bevor ein neuer aktueller Datensatz aufgerufen wird.

Beispiel 1

Folgendes Beispiel ist eine gängige Schleife, um in einer Datenbank neue Datensätze hinzuzufügen:

 FORM SET INPUT([Customers];"Std Input")

  ` Setze Eingabeformular für Tabelle [Customers]

 Repeat ` Durchlaufe, bis der Benutzer abbricht

    ADD RECORD([Customers];*) ` Füge Datensatz in Tabelle [Customers] hinzu

 Until(OK=0) ` Bis der Benutzer abbricht

Beispiel 2

Folgendes Beispiel sucht in der Datenbank nach einem Kunden. Es gibt je nach Suchergebnis zwei Möglichkeiten. Wird kein Kunde gefunden, kann der Benutzer mit ADD RECORD einen neuen Kunden hinzufügen. Wird mindestens ein Kunde gefunden, erscheint der zuerst gefundene Datensatz. Der Benutzer kann ihn mit MODIFY RECORD ändern:

 READ WRITE([Customers])

 FORM SET INPUT([Customers];"Input") ` Setze Eingabeformular

 vlCustNum:=Num(Request("Gib Kundennr ein:")) ` Erhalte die Kundennummer

 If(OK=1)

    QUERY([Customers];[Customers]CustNo=vlCustNum) ` Suche nach dem Kunden

    If(Records in selection([Customers])=0) ` Wird kein Kunde gefunden…

       ADD RECORD([Customers]) ` Füge neuen Kunden hinzu

    Else

       If(Not(Locked([Customers])))

          MODIFY RECORD([Customers]) ` Ändere den Datensatz

          UNLOAD RECORD([Customers])

       Else

          ALERT("Datensatz wird gerade benutzt.")

       End if

    End if

 End if

Systemvariablen und Mengen

Bestätigen des Datensatzes setzt die Systemvariable OK auf 1, Abbrechen setzt die Systemvariable OK auf 0. Die Systemvariable OK wird nur gesetzt, wenn der Datensatz bestätigt oder annulliert wird.

Siehe auch

ACCEPT
CANCEL
CREATE RECORD
MODIFY RECORD
SAVE RECORD