SMTP_Attachment

4D Internet Commands v16

SMTP_Attachment


SMTP_Attachment ( smtp_ID ; nomFichier ; typeEncodage ; supprimerOption {; idAttachment {; contentType}} ) -> Résultat

Paramètre	Type	Description
smtp_ID	Entier long	Référence de message
nomFichier	Texte	Nom du fichier à joindre
typeEncodage	Entier	0 = Pas d'encodage (n'envoie que la DataFork) ±1 = BinHex ±2 = Base64 (n'envoie que la DataFork) ±3 = AppleSingle ±4 = AppleDouble ±5 = AppleSingle ET Base64 ±6 = AppleDouble ET Base64 ±7 = UUEncode
supprimerOption	Entier	0 = Ajouter à la liste existante, 1 = Remplacer toutes les pièces jointes par nomFichier, 2 = Ne supprimer que cette pièce jointe
idAttachment	Texte	Identifiant de fichier joint (messages en HTML uniquement)
contentType	Texte	Valeur de type de contenu à définir
Résultat	Entier	Code d'erreur

Description

La commande SMTP_Attachment vous permet de joindre des fichiers de type binaire ou texte à votre message dans le format MIME. Cette commande peut être appelée plusieurs fois pour joindre plusieurs documents à un message. Si vous passez une valeur positive dans le paramètre typeEncodage, l'encodage sera effectué au moment de l'envoi du message.

smtp_ID contient l'identifiant d'un message créé avec la commande SMTP_New.

Le paramètre nomFichier désigne le fichier que vous voulez joindre au message. Cette valeur peut être spécifiée de trois manières :

""	= Affiche la boîte de dialogue standard d'ouverture de documents.
"nomFichier"	= Recherche le nom du fichier dans le répertoire de la structure de la base de données.
"Chemin:nomFichier"	= Chemin d'accès complet (nom du fichier compris).

Le paramètre typeEncodage indique le type d'encodage à appliquer au fichier avant de l'intégrer au message. S'il s'agit d'un fichier binaire, vous devez utiliser un type d'encodage approprié (BinHex, AppleSingle). L'encodage le plus courant est BinHex.

Si la valeur de typeEncodage est positive, la commande encode automatiquement le fichier au moment de l'envoi du message à l'aide de la commande SMTP_Send.
Si le fichier est volumineux, l'exécution de la commande SMTP_Send peut durer quelques instants. Il est possible de gagner du temps lorsqu'un même fichier est envoyé plusieurs fois : l'astuce consiste à encoder le fichier une seule fois avec la commande IT_Encode, puis de le joindre au message en passant une valeur négative dans typeEncodage. Lorsque le paramètre typeEncodage reçoit une valeur négative, aucun encodage supplémentaire n'est effectué, mais le type d'encodage est décrit dans l'en-tête du message du fichier joint, de manière à ce que le logiciel de messagerie du destinataire puisse l'interpréter correctement.

Note : Vous ne devez pas passer d'élément de tableau dans le paramètre typeEncodage.

Le paramètre supprimerOption indique comment traiter le fichier joint.

Si vous passez 0 (zéro), le fichier joint est ajouté à la liste courante des fichiers joints.
Si vous passez 1, nomFichier remplace tous les fichiers éventuellement déjà joints au message. Dans ce cas, si nomFichier est une chaîne vide, tous les fichiers joints sont supprimés.
Si vous passez 2, le fichier désigné par nomFichier est supprimé de la liste des fichiers joints.

Le paramètre idAttachement vous permet d’associer le fichier joint à une référence définie dans le corps du message via la balise HTML <img src=\"cid:ID\">. Ce principe permet d’afficher le contenu du fichier, par exemple une image, à l’intérieur du message sur le client de messagerie.
Ce fonctionnement est pris en charge uniquement avec les messages formatés en HTML. A noter également que le rendu final pourra varier en fonction du client de messagerie.

Le paramètre optionnel contentType vous permet de définir explicitement le type de contenu du fichier joint. Par défaut, si ce paramètre est omis ou contient une chaîne vide, 4DIC définit automatiquement le type de contenu du fichier joint sur la base de son extension. Les règles suivantes sont appliquées :

Extension	Type de contenu
jpg, jpeg	image/jpeg
png	image/png
gif	image/gif
pdf	application/pdf
doc	application/msword
xls	application/vnd.ms-excel
ppt	application/vnd.ms-powerpoint
zip	application/zip
gz	application/gzip
json	application/json
js	application/javascript
ps	application/postscript
xml	application/xml
htm, html	text/html
mp3	audio/mpeg
other	application/octet-stream

Dans contentType, vous pouvez passer une chaîne spécifiant le type de contenu pour le fichier (type MIME), par exemple "video/mpeg". Cette valeur de content-type sera alors utilisée pour le fichier joint, quelle que soit son extension.

Note : Passez une chaîne vide ("") dans le paramètre idAttachment si vous ne souhaitez pas l'utiliser.

Exemple 1

Envoi d’un message en HTML avec une image incluse :

 $erreur:=SMTP_New($smtp_id)

 $erreur:=SMTP_Host($smtp_id;"smtp.gmail.com")

 $erreur:=SMTP_From($smtp_id;"henry@gmail.com")

 $erreur:=SMTP_ReplyTo($smtp_id;"replies@gmail.com")

 $erreur:=SMTP_Subject($smtp_id;"Test HTML  &  image incluse")

 $erreur:=SMTP_To($smtp_id;"jean@4d.com";1)

 $erreur:=SMTP_Body($smtp_id;"<html><B><I>Hello world in bold!</I></B> <img src=\"cid:myID123\">(normal text)</html>";4)

 $erreur:=SMTP_Attachment($smtp_id;"c:\\temp\\tulips.jpg";2;0;"myID123")

 $erreur:=SMTP_Auth($smtp_id;"henry@gmail.com";"*******")

 $erreur:=SMTP_Send($smtp_id;1)

 $erreur:=SMTP_Clear($smtp_id)

Exemple 2

Vous souhaitez déclarer vos fichiers de configuration (settings) en tant que fichiers XML :

 $path:=Dossier 4D(Dossier base)+"Settings.mySettings"

 $err:=SMTP_Attachment($smtp_id;$path;2;0;"myID123";"application/xml")

Voir aussi

IT_Encode
SMTP_New
SMTP_Send