SMTP_Attachment

4D Internet Commands v16

SMTP_Attachment


SMTP_Attachment ( smtp_ID ; nomArchivo ; tipoCod ; eliminarOpcion {; idAdjunto {; contentType}} ) -> resultado

Parámetro	Tipo	Descripción
smtp_ID	Entero largo	Referencia del mensaje
nomArchivo	Texto	Nombre del archivo a adjuntar
tipoCod	Entero	0 = No codificar (sólo envía el DataFork) ±1 = BinHex ±2 = Base64; (sólo envía el DataFork) ±3 = AppleSingle ±4 = AppleDouble ±5 = AppleSingle Y Base64 ±6 = AppleDouble Y Base64 ±7 = UUEncode
eliminarOpcion	Entero	0 = Añadir a la lista existente, 1 = Reemplazar todos los adjuntos por nomArchivo, 2 = Eliminar sólo este adjunto
idAdjunto	Texto	ID del archivo adjunto(mensajes HTML únicamente)
contentType	Texto	Valor del tipo de contenido a definir
resultado	Entero	Código de error

Descripción

El comando SMTP_Attachment permite añadir archivos binarios o de texto a su mensaje en formato MIME. Este comando puede llamarse varias veces para adjuntar varios documentos a un mensaje. Si pasa un valor mayor que cero en el parámetro tipoCod, este comando realizará la codificación en el momento del envío del mensaje.

smtp_ID es la referencia entero largo de un mensaje electrónico creado con el comando SMTP_New.

nomArchivo contiene el nombre del archivo a adjuntar al mensaje. Este valor se puede especificar de tres maneras diferentes:

""	= Muestra la caja de diálogo estándar de apertura de documentos.
"nomArchivo"	= Busca el nombre del archivo en el mismo directorio que la estructura de la base de datos.
"Ruta:nomArchivo"	= Ruta de acceso completa incluyendo el nombre de archivo.

tipoCod es un valor entero que indica qué tipo de codificación aplicar al archivo antes de integrarlo al mensaje. Si adjunta un archivo binario, debe utilizar un método de codificación adecuado (BinHex, AppleSingle). El método de codificación más común es BinHex.

Si pasa valores positivos en tipoCod el comando codifica automáticamente el archivo utilizando el método especificado cuando se envía el mensaje. La codificación de un archivo se produce en el momento en que se ejecuta el comando SMTP_Send. Si el archivo es grande la ejecución del comando SMTP_Send puede tardar unos momentos. Puede ahorrar tiempo cuando el mismo archivo se envía varias veces. En estos casos lo mejor es codificar el archivo una vez con el comando IT_Encode y luego adjuntar el archivo resultante a su mensaje utilizando el valor negativo de tipoCod. Un valor negativo en tipoCod no realizará ninguna codificación adicional, sino que el tipo de codificación se describe en el encabezado del archivo adjunto al mensaje. Esto informa al software de mensajería del destinatario la forma correcta de interpretar los datos adjuntos.

Nota: no puede pasar un elemento de array en el parámetro tipoCod.

eliminarOpcion es un parámetro entero opcional que especifica la forma de tratar los datos adjuntos.

Un valor de cero añade el archivo adjunto a la lista actual de los archivos adjuntos.
Un valor de 1 reemplaza todos los archivos adjuntos con el archivo nomArchivo. Si nomArchivo es una cadena vacía, todos los archivos adjuntos se eliminarán.
Un valor de 2 eliminará sólo el archivo adjunto listado en nomArchivo de la lista de archivos adjuntos.

El parámetro idAdjunto asocia el archivo adjunto con una referencia definida en el cuerpo del mensaje utilizando la etiqueta HTML t<img src=\"cid:ID\">. Esto significa que el contenido de los archivos, por ejemplo una imagen, se pueden mostrar en el mensaje en el cliente de correo electrónico.
Este funcionamiento sólo es compatible con los mensajes en HTML. También tenga en cuenta que el resultado final puede variar dependiendo del cliente de correo electrónico.

The optional contentType parameter explicitly sets the content type of the attachment file. By default, if this parameter is omitted or contains an empty string, 4DIC automatically sets the content type of the attachment file based on its extension. The following rules are applied:

El parámetro opcional contentType define explícitamente el tipo de contenido del archivo adjunto. De forma predeterminada, si este parámetro se omite o contiene una cadena vacía, 4DIC define automáticamente el tipo de contenido del archivo adjunto en función de su extensión. Se aplican las siguientes reglas:

Extensión	Tipo de contenido
jpg, jpeg	image/jpeg
png	image/png
gif	image/gif
pdf	application/pdf
doc	application/msword
xls	application/vnd.ms-excel
ppt	application/vnd.ms-powerpoint
zip	application/zip
gz	application/gzip
json	application/json
js	application/javascript
ps	application/postscript
xml	application/xml
htm, html	text/html
mp3	audio/mpeg
other	application/octet-stream

En contentType, puede pasar una cadena que defina el tipo de contenido para el archivo (tipo MIME), por ejemplo "video/mpeg". Este valor de tipo de contenido se establecerá para los datos adjuntos, independientemente de su extensión.

Nota: pase una cadena vacía ("") en el parámetro idAdjunto si no lo desea utilizar.

Ejemplo 1

Envío de un mensaje HTML con una imagen incluida:

 $error:=SMTP_New($smtp_id)

 $error:=SMTP_Host($smtp_id;"smtp.gmail.com")

 $error:=SMTP_From($smtp_id;"henry@gmail.com")

 $error:=SMTP_ReplyTo($smtp_id;"replies@gmail.com")

 $error:=SMTP_Subject($smtp_id;"HTML Test  &  picture included")

 $error:=SMTP_To($smtp_id;"john@4d.com";1)

 $error:=SMTP_Body($smtp_id;"<html><B><I>Hello world in bold!</I></B> <img src=\"cid:myID123\">(normal text)</HTML>";4)

 $error:=SMTP_Attachment($smtp_id;"c:\\temp\\tulips.jpg";2;0;"myID123")

 $error:=SMTP_Auth($smtp_id;"henry@gmail.com";"*******")

 $error:=SMTP_Send($smtp_id;1)

 $error:=SMTP_Clear($smtp_id)

Ejemplo 2

Queremos declarar sus archivos de configuración como archivos XML:

 $path:=Get 4D folder(Database folder)+"Settings.mySettings"

 $err:=SMTP_Attachment($smtp_id;$path;2;0;"myID123";"application/xml")

Ver también

IT_Encode
SMTP_New
SMTP_Send