SMTP_QuickSend

4D Internet Commands v16

SMTP_QuickSend


SMTP_QuickSend ( nomServidor ; msgDe ; msgA ; msgObjeto ; mensaje {; paramSesion}{; puerto}{; nomUsuario ; contrasena} ) -> resultado

Parámetro	Tipo	Descripción
nomServidor	Cadena	Nombre o dirección IP del servidor
msgDe	Texto	Dirección electrónica o Lista de direcciones
msgA	Texto	Dirección electrónica o Lista de direcciones
msgObjeto	Texto	Asunto del mensaje (UTF-8 por defecto)
mensaje	Texto	Mensaje (UTF-8 por defecto)
paramSesion	Entero largo	0 o se omite = No utilizar SSL sino switchover, 1 = Utilizar SSL, 2 = Nunca utilizar SSL (switchover no permitido), 4 = Enviar texto HTML sin SSL, 5 = Enviar texto HTML con SSL, 8 = Enviar Mime HTML sin SSL/TLS, 9 = Enviar Mime HTML con SSL/TLS
puerto	Entero largo	Número de puerto a utilizar
nomUsuario	Texto	Nombre de usuario para la autenticación
contrasena	Texto	Contraseña para la autenticación
resultado	Entero	Código de error

Descripción

El comando SMTP_QuickSend permite crear y enviar un mensaje con un solo comando. Si requiere un mayor control sobre el mensaje o si el mensaje es más complejo, utilice el comando SMTP_New.

Nota: este comando no se puede utilizar en las bases convertidas que funcionan en modo "no Unicode".

nomServidor contiene el nombre o la dirección IP del servidor SMTP que se encargará de la distribución del mensaje.

msgDe contiene una o más direcciones electrónicas completas indicando quien envió el mensaje originalmente. Todas las direcciones que figuran en el encabezado De son visibles para todos los destinatarios del mensaje.

msgA contiene una o más direcciones electrónicas completas. Las direcciones identificadas en el encabezado msgA reciben una copia original del mensaje. Cada destinatario del mensaje puede ver las otras direcciones electrónicas a las cuales fue enviado el mensaje.

asunto es un valor texto que describe de forma concisa el tema tratado en detalle por el cuerpo del mensaje.

Nota: por defecto, el asunto y el cuerpo del mensaje están codificados en UTF-8, lo que garantiza que los caracteres enviados serán interpretados correctamente por casi todos los clientes de correo electrónico. Si desea utilizar un conjunto de caracteres específicos, consulte los comandos SMTP_SetPrefs y SMTP_Charset.

mensaje es un valor texto que contiene el cuerpo del mensaje.

El parámetro opcional paramSesion establece el formato del mensaje (texto estándar, HTML o Mime HTML) y el modo de activación del protocolo SSL para la conexión:

Si pasa 0 u omite este parámetro, el mensaje será formateado en texto y enviado en modo estándar no seguro. Si el servidor propone una actualización a SSL/TLS después de la autenticación, la báscula se efectúa automáticamente (funcionamiento del SSL/TLS en modo explícito).
Si pasa 1, el mensaje será formateado en texto y enviado enn SSL (modo síncrono),
Si pasa 2, el mensaje será formateado en texto y enviado pero sin soporte de actualización en SSL/TLS.
Si pasa 4, el mensaje será formateado en HTML y enviado en modo estándar.
Si pasa 5, el mensaje será formateado en HTML y enviado en modo SSL/TLS,
Si pasa 8, el mensaje será formateado en Mime HTML y enviado en modo estándar,
Si pasa 9, el mensaje será formateado en Mime HTML y enviado en modo SSL/TLS,
Nota: Mime HTML (extensión de archivo .mht o .mhtml) es un formato de archivo de página Web que pueden fusionar el código HTML, así como también los recursos externos, como imágenes en un único documento. Se apoya en varios navegadores, así como MS Word, por ejemplo. Dado que este formato es soportado para áreas 4D Write Pro, puede fácilmente guardar y enviar áreas 4D Write Pro por correo electrónico incluyendo todos sus recursos.

Tenga en cuenta que estos valores corresponden a las combinaciones habituales, sin embargo el parámetro paramSesion es un realidad un campo de bits y permite cualquier combinación personalizada si utiliza Operadores de bits:

Número de bit	Formato utilizado si el bit es 1
0	Usar SSL o el comportamiento predeterminado, conexión en claro y actualizar a SSL si es posible.
1	Nunca actualizar, permanecer en modo no cifrado, incluso si la actualización es posible. Bit se ignora si se ha seleccionado SSL (bit-0).
2	Cuerpo del mensaje en HTML, definir el encabezado apropiado.
3	Mensaje MHTML, el bit 2 (HTML) se ignora. El usuario es responsable de configurar todo, excepto "A", "De", "Fecha" y "Asunto

El parámetro opcional puerto especifica el número de puerto SMTP a utilizar para la conexión con el servidor. Los valores utilizados con más frecuencia son:

25 = puerto STMP estándar no seguro (puerto por defecto si el parámetro se omite)
465 = puerto SMTPS (SSL/TLS)
587 = puerto STMP estándar (seguro); pase este puerto para conexiones con un servidor MS Exchange (modo explícito).

Los parámetros opcionales nomUsuario y contrasena se utilizan para autenticar el remitente con el servidor de correo. Estos parámetros deben pasarse en conjunto. Note que el modo de autenticación más seguro soportado pro el servidor será el utilizado (como el modo por defecto del comando SMTP_Auth).

Ejemplo 1

Ejemplo de uso de este comando:

 $Host:="www.4d.com"

 $ToAddress:="adupont@4d.fr"

 $FromAddress:="jsmith@4d.com"

 $Subject:="Informes de ventas"

 $Message:="¿Podría enviarme el informe de ventas de enero de 2009? Gracias."

 $Error:=SMTP_QuickSend($Host;$FromAddress;$ToAddress;$Subject;$Message;1)

 If($Error#0)

    ALERT("Error: SMTP_QuickSend"+Char(13)+IT_ErrorText($Error))

 End If

Ejemplo 2

Ejemplo de utilización del comando para un envío de mensaje seguro vía un servidor MS Exchange:

 $ServerName:="exchange.4d.com"

 $MsgTo:="adupont@gmail.com"

 $MsgFrom:="a.user@4d.com"

 $Subject:="Test message"

 $Message:="This is a test for sending a message in secure mode. Please do not reply."

 $Error:=SMTP_QuickSend($ServerName;$MsgFrom;$MsgTo;$Subject;$Message;0;587;"a.user";"@!password@!")

Ejemplo 3

Envío de un mensaje en HTML con SSL/TLS:

 $Host:="smtp.gmail.com"

 $ToAddress:="john@4d.com"

 $FromAddress:="harry@gmail.com"

 $Subject:="Message HTML"

 $Message:="Let’s meet at <b>Joe’s Coffee Shop</b>!"

 $Param:=5 //HTML with SSL

 $Port:=465 //SSL port of gmail

 $User:="harry@gmail.com"

 $Password:="xyz&@!&@"

 $Error:=SMTP_QuickSend($Host;$FromAddress;$ToAddress;$Subject;$Message;$Param;$Port;$User;$Password)

Ejemplo 4

Usted guardó un documento .mht de su disco y desea enviarlo por correo electrónico. Para ello, puede escribir:

 $Message:=Document to text("c:\\documents\\invitation.mht")

 $Host:="smtp.gmail.com"

 $ToAddress:="john@4d.com"

 $FromAddress:="harry@gmail.com"

 $Subject:="Let's party"

 $Param:=9 //MHTML with SSL

 $Port:=465 //SSL port of gmail

 $User:="harry@gmail.com"

 $Password:="xyz&@!&@"

 $Error:=SMTP_QuickSend($Host;$FromAddress;$ToAddress;$Subject;$Message;$Param;$Port;$User;$Password)

Ver también

SMTP_Charset
SMTP_New
SMTP_SetPrefs