4D Doc Center : Aktuelle Auswahl

Home

4D v14

Aktuelle Auswahl

Zusätzlich zu den Erläuterungen im Video sollten Sie folgendes beachten:

Nachfolgendes Schema zeigt, wie 4D arbeitet, also den Ablauf von Auswahl - Aktion (SELECTION-ACTION):

Das Konzept aktuelle Auswahl ist ein Grundbaustein von 4D, der etwas anders ist als das anderer Systeme, insbesondere SQL.

Eine aktuelle Auswahl ist eine Liste von Datensätzen, die durch Suche in der Tabelle entsteht (entsprechend der WHERE Clausel in SQL)

In 4D haben wir kontinuierlich eine aktuelle Auswahl pro Tabelle. Diese Auswahl kann 0 bis X Datensätze enthalten.

Die aktuelle Auswahl ist die Liste der Datensätze, mit denen wir Aktionen ausführen. Sie können die aktuelle Auswahl zwischen zwei Aktionen ändern.

Nachfolgender Code entspricht der Übung, die in diesem Video ausgeführt wird (Zu Beginn wurden 2 Zeilen zum Deklarieren einfacher Variablen hinzugefügt):

 C_DATE($StartYear;$EndYear)

 C_LONGINT($Year)

 

 $Year:=2011

 $YearStart:=Date("01/01/"+String($Year))

 $YearEnd:=Add to date($YearStart;1;0;-1)

 

 ALL RECORDS([Technicians])

 $Num:=Records in selection([Technicians])

 

 ARRAY TEXT(ArrTechnicians;$Num)

 ARRAY LONGINT(Arr_NumInterventions;$Num)

 

 FIRST RECORD([Technicians])

 While(Not(End selection([Technicians])))

    QUERY([Interventions];[Interventions]Technician_Initials=[Technicians]ID) // Wir haben die Liste der Einsätze für den Techniker im Speicher.

    QUERY SELECTION([Interventions];[Interventions]Intervention_Date>=$YearStart;*)

    QUERY SELECTION([Interventions];&;[Interventions]Intervention_Date<=$YearEnd)

 

    $Index:=Selected record number([Technicians])

    ArrTechnicians{$Index}:=[Technicians]LastName

    Arr_NumInterventions{$Index}:=Records in selection([Interventions])

 

    NEXT RECORD([Technicians])

 End while

Über den Befehl APPEND TO ARRAY können Sie die Größe des Array vor Ausführen der Schleife setzen und während dem Prozess der Variablen $Index einen Wert zuweisen (und so die Funktion Selected record number kennenlernen).

Video Skript