4D v14.3OB SET ARRAY |
||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
|
4D v14.3
OB SET ARRAY
|
OB SET ARRAY ( Objekt ; Eigenschaft ; Array ) | ||||||||
Parameter | Typ | Beschreibung | ||||||
Objekt | Objekt |
![]() |
Strukturiertes Objekt | |||||
Eigenschaft | Text |
![]() |
Name der zu setzenden Eigenschaft | |||||
Array | Array Text, Array Zahl, Array Boolean, Array Objekt, Array Zeiger, Array Lange Ganzzahl |
![]() |
Array zum Speichern in Eigenschaft | |||||
Der Befehl OB SET ARRAY definiert das Array, das der Eigenschaft im Objekt, definiert im Parameter Objekt, zugeordnet ist.
Objekt muss über den Befehl C_OBJECT definiert worden sein.
Im Parameter Eigenschaft übergeben Sie die Bezeichnung der Eigenschaft zum Erstellen oder Ändern. Ist die Eigenschaft bereits in Objekt vorhanden, wird ihr Wert aktualisiert. Ist sie noch nicht vorhanden, wird sie angelegt.
Wichtig: Beachten Sie, dass Eigenschaft Groß- und Kleinschreibung berücksichtigt.
Im Parameter Array übergeben Sie das Array, das als Wert der Eigenschaft übergeben werden muss. Es werden mehrere Array-Typen unterstützt.
Hinweis: Zweidimensionale Arrays lassen sich hier nicht verwenden.
Ein Array Text verwenden:
C_OBJECT($Children)
ARRAY TEXT($arrChildren;3)
$arrChildren{1}:="Richard"
$arrChildren{2}:="Susan"
$arrChildren{3}:="James"
OB SET ARRAY($Children;"Children";$arrChildren)
// Value of $Children = {"Children":["Richard","Susan","James"]}
In einem Array ein Element hinzufügen:
ARRAY TEXT($arrText;2)
$arrText{1}:="Smith"
$arrText{2}:="White"
C_OBJECT($Employees)
OB SET ARRAY($Employees;"Employees";$arrText)
APPEND TO ARRAY($arrText;"Brown") // Add to the 4D array
// $Employees = {"Employees":["Smith","White"]}
OB SET ARRAY($Employees;"Employees";$arrText)
// $Employees = {"Employees":["Smith","White","Brown"]}
Ein Array Text mit Auswahl eines Elements verwenden:
// $Employees = {"Employees":["Smith","White","Brown"]}
OB SET ARRAY($Employees ;"Manager";$arrText{1})
// $Employees = {"Employees":["Smith","White","Brown"],"Manager":["Smith"]}
Ein Array Objekt verwenden:
C_OBJECT($Children;$ref_richard;$ref_susan;$ref_james)
ARRAY OBJECT($arrChildren;0)
OB SET($ref_richard;"nom";"Richard";"age";7)
APPEND TO ARRAY($arrChildren;$ref_richard)
OB SET($ref_susan;"name";"Susan";"age";4)
APPEND TO ARRAY($arrChildren;$ref_susan)
OB SET($ref_james;"name";"James";"age";3)
APPEND TO ARRAY($arrChildren;$ref_james)
// $arrChildren {1} = {"name":"Richard","age":7}
// $arrChildren {2} = {"name":"Susan","age":4}
// $arrChildren {3} = {"name":"James","age":3}
OB SET ARRAY($Children;"Children";$arrChildren)
// $Children = {"Children":[{"name":"Richard","age":7},{"name":"Susan",
// "age":4},{"name":"James","age":3}]}
Hier sehen Sie, wie das Objekt im Debugger erscheint:
Produkt: 4D
Thema: Objekte (Sprache)
Nummer:
1227
Erstellt: 4D v14
4D Programmiersprache ( 4D v14 R2)
4D Programmiersprache ( 4D v14 R3)
4D Programmiersprache ( 4D v14.3)
4D Programmiersprache ( 4D v14 R4)