Command name

4D v15.4

Command name


Command name ( comando ) -> Resultado

Parâmetro	Tipo	Descrição
comando	Inteiro longo	Número de comando
Resultado	String	Nome do comando localizado

Nota de Compatibilidade

A utilidade deste comando foi muito reduzida ao longo do tempo, com a evolução de 4D:

Para argumentos não tokenizados (fórmulas), 4D oferece uma sintaxe token que pode ser usada para evitar problemas potenciais com variações em nomes de comandos, e que permite digitar esses nomes de uma maneira legível. Essa sintaxe também pode ser usada para os nomes de elementos de outras linguagens, tais como tabelas ou campos. Para saber mais, veja Usar tokens em fórmulas .
A partir de 4D v15, a versão em Inglês da linguagem de programação é usada como padrão em todas as versões da linguagem 4D, reduzindo anecessidades relativas a localização de banco de dados.

Descrição

O comando Command name retorna o nome do comando cujno número foi passado em comando.

Este nome pode variar entre versões de 4D (comandos renomeados) ou de acordo com a linguagem do aplicativo(*).

(*) Como padrão, a versão da linguagem Inglesa é usada a partir de 4D v15; mesmo assim, a opção "Use regional system settings" em Página Métodos das Preferências permite que continue a usar a linguagem francesa na versão francesa de 4D.

Nota: O número de cada comando está disponível na área de Propriedades da página de documentação.

O comando Command name estabelece uma variável OK para 1 se comando corresponer a um número de comando existente, e para 0 se não. Note, entretanto, que alguns comandos existentes foram desativados, em cujo caso Command name retorna uma string vazia (ver último exemplo).

Exemplo 1

Em um formulário, você deseja mostrar uma lista suspensa que contenha os comandos padrão de geração de informes. No método de objeto desta lista suspensa, você escreve:

 Case of

    :(Form event=On Before)

       ARRAY TEXT(asCommand;4)

       asCommand{1}:=Command name(1)

       asCommand{2}:=Command name(2)

       asCommand{3}:=Command name(4)

       asCommand{4}:=Command name(3)

  ` ...

 End case

Na versão inglesa de 4D, a lista suspensa conterá: Sum, Average, Min, e Max. Na versão francesa(*), a lista suspensa conterá: Somme, Moyenne, Min, e Max.

*com um aplicativo 4D application configurado para a linguagem francesa (ver nota de compatibilidade).

Exemplo 2

O seguinte código lhe permite carregar todos os comandos 4D válidos em um array:

 C_LONGINT($Lon_id)

 C_TEXT($Txt_command)

 ARRAY LONGINT($tLon_Command_IDs;0)

 ARRAY TEXT($tTxt_commands;0)

 

 Repeat

    $Lon_id:=$Lon_id+1

    $Txt_command:=Command name($Lon_id)

    If(OK=1) //o número de comando existe

       If(Length($Txt_command)>0) //o comando não está desativado

          APPEND TO ARRAY($tTxt_commands;$Txt_command)

          APPEND TO ARRAY($tLon_Command_IDs;$Lon_id)

       End if

    End if

 Until(OK=0) //fim dos comandos existentes

Ver também

EXECUTE FORMULA