Command name

Home

4D v15.4

Command name


Command name ( Befehl ) -> Funktionsergebnis

Parameter	Typ	Beschreibung
Befehl	Lange Ganzzahl	Befehlsnummer
Funktionsergebnis	String	Lokalisierter Befehlsname

Hinweis zur Kompatibilität

Diese Funktion hat im Zuge der Evolution von 4D heutzutage keine große Bedeutung mehr:

Für Anweisungen (Formeln) bietet 4D eine Syntax mit Tokens, die potentielle Probleme bei geänderten Befehlsnamen verhindert, aber trotzdem ermöglicht, Befehlsnamen in lesbarer Form einzugeben. Diese Syntax lässt sich auch für andere Elemente der Programmierung verwenden, wie Tabellen oder Felder. Weitere Informationen dazu finden Sie im Abschnitt Tokens in Formeln verwenden.

Beschreibung

Die Funktion Command name gibt den Namen des Befehls zu der in Befehl übergebenen Nummer zurück.

Dieser Name kann zwischen verschiedenen Versionen variieren (umbenannte Befehle) oder sich nach der Sprache des Programms richten. Ab 4D v15 wird standardmäßig in allen 4D Programmiersprachen die englische Version verwendet. Jedoch kann eine französische 4D Version über die Option "Verwende regionale Systemeinstellungen" auf der Seite Methoden der 4D Einstellungen weiterhin die französischen 4D Befehlsnamen verwenden.

Hinweis: Die entsprechende Nummer zum Befehlsnamen erscheint in jeder Datei in der rechten oberen Ecke unter Eigenschaften.

Command name setzt die Variable OK auf 1, wenn Befehl zu einer vorhandenen Befehlsnummer passt, andernfalls auf 0. Bei deaktivierten Befehlen gibt Command name einen leeren String zurück (siehe letztes Beispiel).

Beispiel 1

Sie wollen in einem Formular eine DropDown-Liste mit den Grundbefehlen für Summen füllen. Die Objektmethode dafür lautet:

 Case of

    :(Form event=On Before)

       ARRAY TEXT(asCommand;4)

       asCommand{1}:=Command name(1)

       asCommand{2}:=Command name(2)

       asCommand{3}:=Command name(4)

       asCommand{4}:=Command name(3)

  ` ...

 End case

In der englischen/deutschen Version von 4D lautet die DropDown-Liste: Sum, Average, Min und Max. In der französischen Version (wenn die Option "Verwende regionale Systemeinstellungen" markiert ist) lautet sie: Somme, Moyenne, Min und Max.

Beispiel 2

Mit folgendem Code können Sie alle gültigen 4D Befehle in ein Array laden:

 C_LONGINT($Lon_id)

 C_TEXT($Txt_command)

 ARRAY LONGINT($tLon_Command_IDs;0)

 ARRAY TEXT($tTxt_commands;0)

 

 Repeat

    $Lon_id:=$Lon_id+1

    $Txt_command:=Command name($Lon_id)

    If(OK=1) //Befehlsnummer existiert

       If(Length($Txt_command)>0) //Befehl ist nicht deaktiviert

          APPEND TO ARRAY($tTxt_commands;$Txt_command)

          APPEND TO ARRAY($tLon_Command_IDs;$Lon_id)

       End if

    End if

 Until(OK=0) //Ende der vorhandenen Befehle

Siehe auch

EXECUTE FORMULA