4D v16
Utiliser la clause WHERE
- 4D - Référence SQL
-
- Prise en main
-
- Introduction
- Recevoir le résultat d'une requête SQL dans une variable
- Utiliser la clause WHERE
- Recevoir le résultat d'une requête SQL dans un tableau
- Utiliser la fonction CAST
- Utiliser la clause ORDER BY
- Utiliser la clause GROUP BY
- Utiliser des fonctions statistiques
- Utiliser la clause HAVING
- Appeler des méthodes 4D depuis le code SQL
- Jointures
- Utiliser des alias
- Sous-requêtes
- Tracer et déboguer le code SQL
- Data Definition Language
- Connexions externes
- Connexion au moteur SQL 4D via le driver ODBC
4D v16
Utiliser la clause WHERE
Utiliser la clause WHERE
Nous souhaitons à présent savoir combien de films réalisés à partir de 1960 sont présents dans la base. Voici le code 4D correspondant à cette requête :
C_LONGINT($NoMovies)
$NoMovies:=0
REDUCE SELECTION([MOVIES];0)
QUERY([MOVIES];[MOVIES]Year_of_Movie>=1960)
$NoMovies:=Records in selection([MOVIES])
ALERT("La videothèque contient "+String($NoMovies)+" films réalisés depuis 1960")- En utilisant du code SQL :
C_LONGINT($NoMovies)
$NoMovies:=0
REDUCE SELECTION([MOVIES];0)
Begin SQL
SELECT COUNT(*)
FROM MOVIES
WHERE Year_of_Movie >= 1960
INTO :$NoMovies;
End SQL
ALERT("La videothèque contient "+String($NoMovies)+" films réalisés depuis 1960")
- En utilisant les commandes SQL génériques :
C_LONGINT($NoMovies)
$NoMovies:=0
REDUCE SELECTION([MOVIES];0)
SQL LOGIN(SQL_INTERNAL;"";"")
SQL EXECUTE("SELECT COUNT(*) FROM MOVIES WHERE Year_of_Movie >= 1960";$NoMovies)
SQL LOAD RECORD(SQL all records)
SQL LOGOUT
ALERT("La videothèque contient "+String($NoMovies)+" films réalisés depuis 1960")
- En utilisant la commande 4D CHERCHER PAR SQL :
C_LONGINT($NoMovies)
$NoMovies:=0
REDUCE SELECTION([MOVIES];0)
QUERY BY SQL([MOVIES];"Year_of_Movie >= 1960")
$NoMovies:=Records in selection([MOVIES])
ALERT("La videothèque contient "+String($NoMovies)+" films réalisés depuis 1960")
- En utilisant la commande SQL dynamique EXECUTE IMMEDIATE :
C_LONGINT($NoMovies)
C_TEXT($tQueryTxt)
$NoMovies:=0
REDUCE SELECTION([MOVIES];0)
$tQueryTxt:="SELECT COUNT(*) FROM MOVIES WHERE Year_of_Movie >= 1960 INTO :$NoMovies;"
Begin SQL
EXECUTE IMMEDIATE :$tQueryTxt;
End SQL
ALERT("La videothèque contient "+String($NoMovies)+" films réalisés depuis 1960")
Comme dans la section précédente, pour tester tous ces exemples, lancez la base "4D SQL Code Samples" et affichez la boîte de dialogue principale. Choisissez le mode d'interrogation du moteur de 4D et cliquez sur le bouton Clause WHERE.
PROPRIÉTÉS
Produit : 4D
Thème : Prise en main
HISTORIQUE
UTILISATION DE L'ARTICLE
4D - Référence SQL ( 4D v16)
© 1985-2018 4D SAS / 4D, Inc. Tous droits réservés.