4D v16

Utilizar a cláusula WHERE

Página Inicial

 
Página Inicial
4D v16
Manual de SQL
Tutorial
Utilizar a cláusula WHERE

Utilizar a cláusula WHERE  


 

 

Se agora queremos saber quantos filmes realizados desde 1960 estão na videoteca.

O código 4D seria:

 C_LONGINT($NoMovies)
 
 $NoMovies:=0
 REDUCE SELECTION([MOVIES];0)
 QUERY([MOVIES];[MOVIES]Year_of_Movie>=1960)
 $NoMovies:=Records in selection([MOVIES])
 ALERT("A videoteca contém "+String($NoMovies)+"filmes realizados desde 1960")

  • Utilizando o código SQL:

     C_LONGINT($NoMovies)
     
     $NoMovies:=0
     REDUCE SELECTION([MOVIES];0)
     Begin SQL
        SELECT COUNT(*)
        FROM MOVIES
        WHERE Year_of_Movie >= 1960
        INTO :$NoMovies;
     End SQL
     ALERT("A videoteca contém "+String($NoMovies)+"filmes realizados desde 1960")
  • Utilizando os comandos SQL genéricos:

     C_LONGINT($NoMovies)
     $NoMovies:=0
     REDUCE SELECTION([MOVIES];0)
     
     SQL LOGIN(SQL_INTERNAL;"";"")
     SQL EXECUTE("SELECT COUNT(*) FROM MOVIES WHERE Year_of_Movie >= 1960";$NoMovies)
     SQL LOAD RECORD(SQL all records)
     SQL LOGOUT
     ALERT("A videoteca contém "+String($NoMovies)+"filmes realizados desde 1960")
  • Utilizando o comando QUERY BY SQL:

     C_LONGINT($NoMovies)
     
     $NoMovies:=0
     REDUCE SELECTION([MOVIES];0)
     QUERY BY SQL([MOVIES];"Year_of_Movie >= 1960")
     $NoMovies:=Records in selection([MOVIES])
     ALERT("A videoteca contém "+String($NoMovies)+"filmes realizados desde 1960")
  • Utilizando o comando SQL EXECUTE IMMEDIATE:

     C_LONGINT($NoMovies)
     C_TEXT($tQueryTxt)
     
     $NoMovies:=0
     REDUCE SELECTION([MOVIES];0)
     $tQueryTxt:="SELECT COUNT(*) FROM MOVIES WHERE Year_of_Movie >= 1960 INTO :$NoMovies;"
     Begin SQL
        EXECUTE IMMEDIATE :$tQueryTxt;
     End SQL
     ALERT("A videoteca contém "+String($NoMovies)+" filmes realizados desde 1960")

Como na seção anterior, para provar todos os exemplos, simplesmente lance a base "4D SQL Code Samples" e vá até a janela principal. Escolha o modo de interrogação do motor de 4D e faça clique no botão WHERE clause.

anterior
seguido

 
PROPRIEDADES 

Produto: 4D
Tema: Tutorial

 
HISTÓRIA 

 
ARTICLE USAGE

Manual de SQL ( 4D v16)