JSON Stringify array

Home

4D v16.3

JSON


JSON Stringify array ( Array {; *} ) -> Funktionsergebnis

Parameter	Typ	Beschreibung
Array	Array Text, Array Zahl, Array Boolean, Array Zeiger, Array Objekt	Array zum Serialisieren des Inhalts
*	Operator	Formatierung aktivieren
Funktionsergebnis	Text	String mit dem serialisierten JSON Array

Beschreibung

Die Funktion JSON Stringify array konvertiert das 4D Array Array in ein serialisiertes JSON Array. Diese Funktion führt die entgegengesetzte Aktion des Befehls JSON PARSE ARRAY aus.

In Array übergeben Sie ein 4D Array mit den Daten zum Serialisieren. Es kann vom Typ Text, Zahl, Boolean, Zeiger oder Objekt sein.

Hinweis: Übergeben Sie eine skalare Variable oder Feld in Array, gibt die Funktion einen String mit dem Parameterwert zwischen den Klammern "[ ]" zurück.

Sie können den optionalen Parameter * übergeben, um im resultierenden String Formatierungszeichen einzuschließen. Das verbessert die Darstellung von JSON Daten (pretty formatting) bei der Anzeige in einer Web Seite.

Beispiel 1

Ein Array Text konvertieren:

 C_TEXT($jsonString)

 ARRAY TEXT($ArrayFirstname;2)

 $ArrayFirstname{1}:="John"

 $ArrayFirstname{2}:="Jim"

 $jsonString :=JSON Stringify array($ArrayFirstname)

 

  // $jsonString = "["John","Jim"]"

Beispiel 2

Ein Array Text mit Zahlen konvertieren:

 ARRAY TEXT($phoneNumbers;0)

 APPEND TO ARRAY($phoneNumbers ;"555-0100")

 APPEND TO ARRAY($phoneNumbers ;"555-0120")

 $string :=JSON Stringify array($phoneNumbers)

  // $string = "["555-0100","555-0120"]"

Beispiel 3

Ein Array Objekt konvertieren:

 C_OBJECT($ref_john)

 C_OBJECT($ref_jim)

 ARRAY OBJECT($myArray;0)

 OB SET($ref_john;"name";"John";"age";35)

 OB SET($ref_jim;"name";"Jim";"age";40)

 APPEND TO ARRAY($myArray ;$ref_john)

 APPEND TO ARRAY($myArray ;$ref_jim)

 $JsonString :=JSON Stringify array($myArray)

  // $JsonString = "[{"name":"John","age":35},{"name":"Jim","age":40}]"

 

  // Wollen Sie das Ergebnis als Text anzeigen, übergeben Sie den optionalen Parameter *:

 $JsonStringPretty :=JSON Stringify array($myArray;*)

Beispiel 4

Eine 4D Auswahl in ein Array Objekt konvertieren:

 C_OBJECT($jsonObject)

 C_TEXT($jsonString)

 

 QUERY([Company];[Company]Company Name="a@")

 OB SET($jsonObject;"company name";->[Company]Company Name)

 OB SET($jsonObject;"city";->[Company]City)

 OB SET($jsonObject;"date";[Company]Date_input)

 OB SET($jsonObject;"time";[Company]Time_input)

 ARRAY OBJECT($arraySel;0)

 

 While(Not(End selection([Company])))

    $ref_value:=OB Copy($jsonObject;True)

  // Ohne Kopieren sind die Werte leere Strings

    APPEND TO ARRAY($arraySel;$ref_value)

  // Jedes Element enthält die gewählten Werte, zum Beispiel:

  // $arraySel{1} = // {"company name":"APPLE","time":43200000,"city":

  // "Paris","date":"2012-08-02T00:00:00Z"}

    NEXT RECORD([Company])

 End while

 

 $jsonString:=JSON Stringify array($arraySel)

  // $jsonString = "[{"company name":"APPLE","time":43200000,"city":

  //"Paris","date":"2012-08-02T00:00:00Z"},{"company name":

  //"ALMANZA",...}]"

Siehe auch

JSON PARSE ARRAY
JSON Stringify