JSON TO SELECTION

Home

4D v16.3

JSON

JSON TO SELECTION


JSON TO SELECTION ( TabelleName ; jsonArray )

Parameter	Typ	Beschreibung
TabelleName	Tabelle	4D Tabelle, in die Elemente kopiert werden
jsonArray	Text	Array mit Objekten in JSON

Beschreibung

Der Befehl JSON TO SELECTION kopiert den Inhalt des Array mit JSON Objekten jsonArray in eine Datensatzauswahl von TabelleName.

Der Parameter jsonArray ist ein Text Array mit Objekten, formatiert in JSON und mit einem oder mehreren Elementen. Die Syntax lautet wie folgt:

"[{"attribute1":"value1","attribute2":"value2",...},...,{"attribute1":"valueN","attribute2":"valueN",...}]"

Gibt es für TabelleName zum Zeitpunkt des Aufrufs eine Auswahl, werden die Elemente des JSON Array in die Datensätze kopiert, und zwar in der Reihenfolge des Array und der Datensätze. Übersteigt die Anzahl der Elemente im JSON Array die Anzahl der Datensätze in der aktuellen Auswahl, werden neue Datensätze erstellt. Alle Datensätze, egal ob neu oder schon vorhanden, werden automatisch gesichert.

Hinweis: Dieser Befehl unterstützt Felder vom Typ Objekt: JSON Daten werden automatisch konvertiert.

Warnung: Verwenden Sie diesen Befehl mit Bedacht, denn JSON TO SELECTION ersetzt alle Informationen in den vorhandenen Datensätzen.

Ist ein Datensatz während der Ausführung des Befehls gesperrt, wird er nicht geändert. Alle gesperrten Datensätze werden in die Systemmenge LockedSet gelegt. Nach Ausführen von JSON TO SELECTION können Sie testen, ob die Menge LockedSet Datensätze enthält, die gesperrt waren.
Weitere Informationen zu dieser Menge finden Sie im Abschnitt Die Systemmenge LockedSet.

Beispiel

Mit dem Befehl JSON TO SELECTION Datensätze in der Tabelle [Company] hinzufügen:

 C_OBJECT($Object1;$Object2;$Object3;$Object4)

 C_TEXT($ObjectString)

 ARRAY OBJECT($arrayObject;0)

 

 OB SET($Object1;"ID";"200";"Company Name";"4D SAS";"City";"Clichy")

 APPEND TO ARRAY($arrayObject;$Object1)

 

 OB SET($Object2;"ID";"201";"Company Name";"APPLE";"City";"Paris")

 APPEND TO ARRAY($arrayObject;$Object2)

 

 OB SET($Object3;"ID";"202";"Company Name";"IBM";"City";"London")

 APPEND TO ARRAY($arrayObject;$Object3)

 

 OB SET($Object4;"ID";"203";"Company Name";"MICROSOFT";"City";"New York")

 APPEND TO ARRAY($arrayObject;$Object4)

 

 $ObjectString:=JSON Stringify array($arrayObject)

 

  // $ObjectString = "[{"ID":"200","City":"Clichy","Company Name":"4D SAS"},{"ID":"201","City":"Paris","Company Name":"APPLE"},{"ID":"202","City":"London","Company Name":"IBM"},{"ID":"203","City":"New York","Company Name":"MICROSOFT"}]"

 

 JSON TO SELECTION([Company];$ObjectString)

  // Sie erstellen 4 Datensätze in der Tabelle [Company], füllen die ID, die Felder Company Name und City

Siehe auch

Selection to JSON