FORM FIXER TAILLE

4D v16.3

FORM FIXER TAILLE


FORM FIXER TAILLE ( {objet ;} horizontal ; vertical {; *} )

Paramètre	Type	Description
objet	Chaîne	Nom d’objet indiquant les limites du formulaire
horizontal	Entier long	Si * passé : marge horizontale (pixels) Si * omis : largeur (pixels)
vertical	Entier long	Si * passé : marge verticale (pixels) Si * omis : hauteur (pixels)
*	Opérateur	• Si passé, utiliser horizontal et vertical comme marges du formulaire • Si omis, utiliser horizontal et vertical comme largeur et hauteur du formulaire Ce paramètre ne peut pas être passé si objet est passé

Description

La commande FORM FIXER TAILLE permet de modifier par programmation la taille du formulaire courant. La nouvelle taille est définie pour le process courant, elle n’est pas stockée avec le formulaire.

Comme en mode Développement, cette commande permet de définir la taille d’un formulaire de trois manières :

automatiquement — 4D détermine la taille du formulaire sur le principe que tous les objets doivent être visibles — en ajoutant éventuellement une marge horizontale et une marge verticale,
sur la base de l’emplacement d’un objet du formulaire auquel s’ajoutent éventuellement une marge horizontale et une marge verticale,
en saisissant des dimensions “absolues” (largeur et hauteur).
Pour plus d’informations sur les possibilités de dimensionnement des formulaires, reportez-vous au manuel Mode Développement de 4D.

Taille automatique
Pour que le formulaire ait une taille automatique, vous devez utiliser la syntaxe suivante :

FORM FIXER TAILLE(horizontal;vertical;*)

Dans ce cas, vous devez passer dans horizontal et vertical les marges (en pixels) que vous souhaitez ajouter à droite et en bas du formulaire.

Taille basée sur un objet
Pour que la taille du formulaire soit basée sur un objet, vous devez utiliser la syntaxe suivante :

FORM FIXER TAILLE(objet;horizontal;vertical)

Dans ce cas, vous devez passer dans horizontal et vertical les marges (en pixels) que vous souhaitez ajouter à droite et en bas de l’objet. Il n'est pas possible de passer le paramètre *.

Taille en valeur absolue
Pour passer une taille de formulaire absolue, vous devez utiliser la syntaxe suivante :

FORM FIXER TAILLE(horizontal;vertical)

Dans ce cas, vous devez passer dans horizontal et vertical la largeur et la hauteur (en pixels) du formulaire.

La commande FORM FIXER TAILLE modifie la taille du formulaire mais tient compte de ses propriétés de redimensionnement. Par exemple, si la largeur minimale du formulaire est de 500 pixels et si la commande définit une largeur de 400 pixels, la nouvelle largeur du formulaire sera de 500 pixels.

A noter également que cette commande ne modifie pas la taille de la fenêtre du formulaire (il est possible de redimensionner un formulaire sans que la taille de la fenêtre soit modifiée, et inversement). Pour modifier la taille de la fenêtre d’un formulaire, reportez-vous à la description de la commande REDIMENSIONNER FENETRE FORMULAIRE.

Exemple

Voici un exemple de mise en place d’une fenêtre de type Explorateur. Le formulaire suivant est défini en mode Développement :

La taille du formulaire est “automatique”.

La fenêtre est affichée via l’instruction suivante :

 $ref:=Creer fenetre formulaire([Table 1];"Form1";Form fenêtre standard;Centrée horizontalement;Centrée verticalement;*)

 DIALOGUE([Table 1];"Form1")

 FERMER FENETRE

La partie droite de la fenêtre peut être affichée ou masquée via un clic sur l’option d’agrandissement/réduction :

La méthode objet associée à ce bouton est la suivante :

 Au cas ou

    :(Evenement formulaire=Sur chargement)

       C_BOOLEEN(b1;<>contracté)

       C_ENTIER LONG(marge)

       marge:=15

       b1:=<>contracté

       Si(<>contracté)

          FORM FIXER REDIMENSIONNEMENT HORIZONTAL(Faux)

          FORM FIXER TAILLE("b1";marge;marge)

       Sinon

          FORM FIXER REDIMENSIONNEMENT HORIZONTAL(Vrai)

          FORM FIXER TAILLE("onglet";marge;marge)

       Fin de si

 

    :(Evenement formulaire=Sur clic)

       <>contracté:=b1

       Si(b1)

  `contracté

          OBJET LIRE COORDONNEES(*;"b1";$g;$h;$d;$b)

          COORDONNEES FENETRE($gf;$hf;$df;$bf;Fenetre formulaire courant)

          CHANGER COORDONNEES FENETRE($gf;$hf;$gf+$d+marge;$hf+$b+marge;Fenetre formulaire courant)

          FORM FIXER REDIMENSIONNEMENT HORIZONTAL(Faux)

          FORM FIXER TAILLE("b1";marge;marge)

 

       Sinon

  `déployé

          OBJET LIRE COORDONNEES(*;"onglet";$g;$h;$d;$b)

          COORDONNEES FENETRE($gf;$hf;$df;$bf;Fenetre formulaire courant)

          CHANGER COORDONNEES FENETRE($gf;$hf;$gf+$d+marge;$hf+$b+marge;Fenetre formulaire courant)

          FORM FIXER REDIMENSIONNEMENT HORIZONTAL(Vrai)

          FORM FIXER TAILLE("onglet";marge;marge)

       Fin de si

 

 Fin de cas

Voir aussi

FORM FIXER REDIMENSIONNEMENT HORIZONTAL
FORM FIXER REDIMENSIONNEMENT VERTICAL