EXPORT DATA

Home

4D v16.3

EXPORT DATA


EXPORT DATA ( DateiName {; Projekt {; *}} )

Parameter	Typ	Beschreibung
DateiName	String	Kompletter Pfadname der Exportdatei
Projekt	Textvariable, BLOB Variable	Inhalt des Exportprojekts
		Neuer Inhalt des Exportprojekts (wenn Parameter * übergeben wurde)
*	Operator	Zeigt Exportdialog und aktualisiert das Projekt

Beschreibung

Der Befehl EXPORT DATA exportiert Daten in die Datei DateiName. 4D kann Daten in folgenden Formaten exportieren: Text, Text mit fester Länge, XML, SYLK, DIF, DBF (dBase) und 4D.

Übergeben Sie in DateiName einen leeren String, zeigt EXPORT DATA den Standarddialog zum Sichern an. Hier kann der Benutzer Name, Typ und Ort der Exportdatei festlegen. Nach Bestätigen dieses Dialogs enthält die Systemvariable Document den Zugriffspfad und den Namen der Datei. Klickt der Benutzer auf die Schaltfläche Abbrechen, wird die Ausführung des Befehls gestoppt. Die Systemvariable OK hat dann den Wert 0 (Null).

Mit dem optionalen Parameter Projekt können Sie ein Projekt zum Exportieren der Daten verwenden. Damit wird der Export direkt ausgeführt, d.h. ohne Eingreifen des Benutzers (außer Sie verwenden die Option *, siehe unten). Übergeben Sie den optionalen Parameter Projekt nicht, wird das Dialogfenster für Export angezeigt. Der Benutzer kann die Exportparameter selbst festlegen oder ein bestehendes Exportprojekt laden.

Ein Exportprojekt enthält alle Exportparameter wie die Tabellen und Felder zum Exportieren, die Begrenzer, etc. Im Parameter Projekt können Sie entweder eine Textvariable mit XML oder mit einer Referenz auf ein zuvor vorhandenes DOM Element, bzw. ein BLOB übergeben. Projekte lassen sich per Programmierung (nur im XML Format) erstellen oder durch Laden der Parameter, die zuvor im Exportdialog definiert wurden. Im 2. Fall haben Sie dafür zwei Möglichkeiten:

Sie verwenden den Befehl EXPORT DATA mit einem leeren Parameter Projekt und dem optionalen Parameter *. Dann speichern Sie den Parameter Projekt in ein Feld vom Typ Text oder BLOB (siehe unten). Auf diese Weise können Sie das Projekt mit der Datendatei sichern.
Sie sichern das Projekt auf die Festplatte, laden es dann z.B. über die Funktion DOM Parse XML source und übergeben seine Referenz im Parameter Projekt.

Hinweis zur Kompatibilität: Ab 4D Version 12 werden Exportprojekte in XML codiert. 4D kann Exportprojekte, die mit einer früheren 4D Version im BLOB Format erstellt wurden, öffnen. Mit v12 erstellte Projekte lassen sich dagegen nicht mit Version 11 oder älter öffnen. Wir empfehlen deshalb zum Verwalten der Exportdateien Variablen vom Typ Text zu verwenden.

Ist der optionale Parameter * angegeben, wird das Dialogfenster für den Export mit den Parametern des Projekts angezeigt. So können Sie ein vordefiniertes Projekt einsetzen, und trotzdem einen bzw. mehrere Parameter ändern. Außerdem enthält der Parameter Projekt nach Schließen des Dialogfensters für den Export die Parameter des "neuen" Projekts. Sie können dann das neue Projekt in einem BLOB Feld, auf der Festplatte, etc. speichern.

War der Export erfolgreich, hat die Systemvariable OK den Wert 1.

Beispiel 1

Dieses Beispiel zeigt die Verwendung des Befehls EXPORT DATA, um Daten im binären Format zu exportieren.

Diese Methode macht eine Schleife in alle Tabellen der Datenbank und ruft die Methode ExportBinary auf:

 C_TEXT($ExportPath)

 C_LONGINT($i)

 $ExportPath:=Select folder("Wählen Sie den Export Ordner:")

 If(Ok=1)

    For($i;1;Get last table number

       If(Is table number valid($i))

          ExportBinary(Table($i);$ExportPath+Table name($i);True)

       End if

    End for

 End if

Hier ist der Code für die Methode ExportBinary:

 C_POINTER($1) //Tabelle

 C_TEXT($2) //Pfad der Zieldatei

 C_BOOLEAN($3) //exportiere alle Datensätze

 C_LONGINT($i)

 C_TEXT($ref)

 $ref:=DOM Create XML Ref("Einstellungen-Import-Export")

  // Exportiere die Tabelle "$1" in '4D' binäres Format, alle Datensätze oder nur die aktuelle Auswahl

 DOM SET XML ATTRIBUTE($ref;"table_no";Table($1);"format";"4D";"all_records";$3)

  // Definition der Felder zum Exportieren

 For($i;1;Get last field number($1))

    If(Is field number valid($1;$i))

       $elt:=DOM Create XML element($ref;"field";"table_no";Table($1);"field_no";$i)

    End if

 End for

 EXPORT DATA($2;$ref)

 If(Ok=0)

    ALERT("Fehler während Export der Tabelle"+Table name($1))

 End if

 DOM CLOSE XML($ref)

Beispiel 2

Dieses Beispiel erstellt ein leeres Projekt und speichert die vom Benutzer gesetzten Parameter im Dialogfenster für den Export:

 C_TEXT($exportParams)

 EXPORT DATA("DocExport.txt";$exportParams;*) //Anzeige des Dialogfensters für den Export

Systemvariablen und Mengen

Klickt der Benutzer im Standarddialog für Öffnen oder im Dialog für Export auf die Schaltfläche Abbrechen, hat die Systemvariable OK den Wert 0 (Null). War der Export erfolgreich, hat die Systemvariable OK den Wert 1.

Siehe auch

EXPORT DIF
EXPORT SYLK
EXPORT TEXT
IMPORT DATA