DIALOG

4D v16.3

DIALOG


DIALOG ( {aTable ;} form {; *} )

引数	型	説明
aTable	テーブル	フォームの属するテーブルまたは省略した場合デフォルトテーブルまたはプロジェクトフォームを使用
form	文字	ダイアログとして表示するテーブルフォームまたはプロジェクトフォーム
*	演算子	同じプロセスを使用

説明

DIALOGコマンドはユーザーに対してフォームformを表示します。このコマンドは、変数を用いてユーザーから情報を取得したり、処理を実行する際のオプションなど情報をユーザーに表示するために、使用されます。

Open windowコマンドで作成したモーダルウィンドウにフォームを表示するのは一般的な使用方法です。

典型的なダイアログの例を次に示します:

表示したり取得しなければならない情報がより複雑で、ALERT, CONFIRM, または Requestで処理できない場合、これらのコマンドの代わりにDIALOGを使用してください。

注: 4D環境設定の互換性ページにあるオプションを使用して、ダイアログボックスのフィールドへのデータ入力を禁止し、変数にのみ入力可とすることができます。この制約は、以前のバージョンの4Dでの動作に相当します。

ADD RECORDやMODIFY RECORDと異なり、DIALOGはカレント入力フォームを使用しません。form引数で使用するフォーム (プロジェクトフォームまたはテーブルフォーム) を指定しなければなりません。また、ボタンを省略した場合でもデフォルトボタンパネルは表示されません。この場合Escキーを使用してのみフォームを終了できます。

ユーザーが保存ボタンをクリック、またはテンキー上の “enter” キーを押す、または ACCEPT コマンドが実行された場合、ダイアログが受け入れられます。
ダイアログの受け入れが保存を行わないことに留意ください。ダイアログにフィールドが含まれる場合、更新されたデータを保存するには明示的に SAVE RECORD コマンドを呼ばなければなりません。

ユーザーがキャンセルボタンをクリック、またはEscキーを押す、または CANCEL コマンドが実行された場合には、ダイアログはキャンセルされます。

オプションの * 引数を渡すと、フォームはカレントプロセスで最後に開かれたウィンドウにロードされ、フォームをスクリーン上でアクティブにしたままこのコマンドは実行を終了します。
このフォームはユーザーアクションに対し通常通り反応し、標準アクションまたはフォームに関連する4Dコード (オブジェクトメソッドやフォームメソッド) が CANCEL や ACCEPT コマンドを呼び出すと閉じられます。カレントプロセスが終了すると、この方法で作成されたフォームは、CANCEL コマンドが呼ばれたかのように自動で閉じられます。
この開き方では別にプロセスを開始する必要がないため、ドキュメントと一緒にフローティングパレットを表示するのに特に便利です。

DIALOGの呼び出し後、システム変数OKにはダイアログが受け入れられると1が、キャンセルされると0が設定されます。

注:

DIALOG(form;*) をコールする前に、あらかじめウィンドウが作成されている必要があります (プロセスのカレントダイアログウィンドウや、各プロセスにデフォルトで作成されるウィンドウは使用できません)。でなければ、エラー -9909 が生成されます。
オプションの * 引数を使用する場合、標準アクションまたは CANCEL や ACCEPT コマンドを呼び出すと、ウィンドウは自動的に閉じられます。ウィンドウ自身の終了を別途操作する必要はありません。

例題 1

以下の例題は、検索条件を指定するためにDIALOGを使用します。変数vName と vState が置かれたフォームが表示され、ユーザは検索条件を入力できます:

 Open window(10;40;370;220) ` モーダルウィンドウを表示

 DIALOG("Search Dialog") ` カスタム検索ダイアログを表示

 CLOSE WINDOW ` モーダルウィンドウは必要ない

 If(OK=1) ` ダイアログが受け入れられれば

    QUERY([Company];[Company]Name=vName;*)

    QUERY([Company];&;[Company]State=vState)

 End if

例題 2

以下の例題はツールパレットを作成するために使用できます:

  `ツールパレットの表示

 $palette_window:=Open form window("tools";Palette form window)

 DIALOG("tools";*) `即座にコントロールを返す

  `メインのドキュメントウィンドウを表示

 $document_window:=Open form window("doc";Plain form window)

 DIALOG("doc")

システム変数およびセット

DIALOGの呼び出し後ダイアログが受け入れられればOKに1が、キャンセルされれば0が設定されます。

参照

ACCEPT
ADD RECORD
CANCEL
Open window