PV SELECTIONNER PLAGE

4D View v16


PV SELECTIONNER PLAGE ( zone ; gauche ; haut ; droit ; bas ; action )

Paramètre	Type	Description
zone	Entier long	Zone 4D View
gauche	Entier long	Numéro de colonne des cellules de gauche
haut	Entier long	Numéro de ligne des cellules du haut
droit	Entier long	Numéro de colonne des cellules de droite
bas	Entier long	Numéro de ligne des cellules du bas
action	Entier	Action de sélection

Description

La commande PV SELECTIONNER PLAGE sélectionne la plage de cellules définie par gauche, haut, droit et bas.

Le paramètre action permet de définir l’action de sélection que vous souhaitez effectuer lorsqu’une sélection de cellules existe déjà : vous pouvez créer une nouvelle plage, ajouter la plage à la sélection ou supprimer la plage de la sélection. Utilisez les constantes du thème PV Actions de sélection pour définir ce paramètre :

Constante	Type	Valeur	Comment
pv sélection définir	Entier long	0	La nouvelle sélection remplace la sélection existante.
pv sélection étendre	Entier long	1	La nouvelle sélection est ajoutée à la sélection existante.
pv sélection réduire	Entier long	2	La sélection est ôtée de la sélection existante. Si la cellule courante se trouve parmi les éléments désignés, elle est désélectionnée et la zone ne contient plus de cellule courante.

Exemple 1

Nous souhaitons sélectionner la plage de cellules E2, E3, F2, F3. L’action de sélection dépendra du contexte (plage entièrement sélectionnée) et, le cas échéant, du choix de l’utilisateur.

  `Tableaux définissant la sélection existante :

 TABLEAU ENTIER LONG($TabGauche;0) `Numéros de colonne des cellules de gauche

 TABLEAU ENTIER LONG($TabHaut;0) `Numéros de ligne des cellules du haut

 TABLEAU ENTIER LONG($TabDroit;0) `Numéros de colonnes des cellules de droite

 TABLEAU ENTIER LONG($TabBas;0) `Numéros de lignes des cellules du bas

 

  `Plages sélectionnées :

 PV LIRE LISTE PLAGES SELECT(Zone;$TabGauche;$TabHaut;$TabDroit;$TabBas)

 

 Si(Taille tableau($TabGauche)=0) `Rien de sélectionné

    PV SELECTIONNER PLAGE(Zone;5;2;6;3;pv sélection définir) `Fixons la sélection à la plage

 

 Sinon `D'autres plages sont déjà sélectionnées

    CONFIRMER("Étendre la sélection existante ?";"Oui";"Non")

    Si(OK=1) `Sélection multiple incluant la plage

       PV SELECTIONNER PLAGE(Zone;5;2;6;3;pv sélection étendre)

    Sinon

       PV SELECTIONNER PLAGE(Zone;5;2;6;3;pv sélection définir) `Sélection réduite à la plage

    Fin de si

 Fin de si

Exemple 2

Cet exemple permet de sélectionner ou de désélectionner la cellule dans laquelle l’utilisateur a effectué Alt+clic (Windows) ou Option+clic (Mac OS), suivant qu’elle appartient déjà ou non à la sélection.

  `Définition de la plage de sélection courante

 PV SELECTIONNER PLAGE(zone;1;5;2;9;pv sélection définir)

 

  `Appel d’une méthode en cas de clic dans la zone

 PV APPELER SUR EVENEMENT(zone;pv sur clic;"ExempleView")

 

  `Méthode ExempleView

 C_ENTIER LONG($1;$2;$3;$4;$5)

 Si(($2=pv sur clic)&($3=2048)) `Alt + clic ou Option + clic

    Si(PV Cellule selectionnee(zone;$4;$5)=1)

  `Si la cellule appartient à la sélection, on la retire de la sélection

       PV SELECTIONNER PLAGE(zone;$4;$5;$4;$5;pv sélection réduire)

    Sinon

  `Si la cellule n’appartient pas à la sélection, on l’y ajoute

       PV SELECTIONNER PLAGE(zone;$4;$5;$4;$5;pv sélection étendre)

    Fin de si

 Fin de si

Voir aussi

PV LIRE CELLULE COURANTE
PV Plage selectionnee