PV SELECT RANGE

4D View v16

PV SELECT RANGE


PV SELECT RANGE ( area ; esquerda ; superior ; direita ; inferior ; açao )

Parâmetro	Tipo	Descrição
area	Inteiro longo	Área 4D View
esquerda	Inteiro longo	Número de coluna da célula esquerda
superior	Inteiro longo	Número de linha da célula superior
direita	Inteiro longo	Número da coluna da célula direita
inferior	Inteiro longo	Número de linha da célula inferior
açao	Inteiro	Ação de seleção

Descrição

O comando PV SELECT RANGE seleciona a faixa de células definidas pela esquerda, superior, direita e inferior.

O parâmetro açao permite definir a ação de seleção a executar quando uma seleção de células já existe: pode adicionar a faixa a seleção, reduzir a seleção a faixa ou eliminar a faixa da seleção. açao se define utilizando as constantes PV Ações de seleção:

Constante	Tipo	Valor
pv selection add	Inteiro longo	1
pv selection reduce	Inteiro longo	2
pv selection set	Inteiro longo	0

Exemplo 1

Queremos selecionar a faixa das células E2, E3, F2, F3. A ação de seleção depende do contexto (células já selecionadas):

  `Os arrays definem a seleção atual:

 ARRAY LONGINT($Left;0) `Números de coluna da célula a esquerda

 ARRAY LONGINT($Top;0) `Números de linha da célula superior

 ARRAY LONGINT($Right;0) `Números de coluna da célula a direita

 ARRAY LONGINT($Bottom;0) `Número de linha de célula inferior

 PV GET SELECTED RANGES LIST(Area;$Left;$Top;$Right;$Bottom) `Obter faixas selecionadas se existe

 If(Size of array($Left)=0) `Não há seleção atual

    PV SELECT RANGE(Area;5;2;6;3;pv selection set) `Definir a faixa como seleção atual

 Else

    PV SELECT RANGE(Area;5;2;6;3;pv selection add) `Adicionar a faixa a seleção atual

 End if

Exemplo 2

Este exemplo permite selecionar ou de-selecionar a célula na qual o usuário realiza Alt+clique (Windows) ou Opção+clique (Mac OS), dependendo de se pertence ou não a seleção.

  `Definição da faixa de seleção atual

 PV SELECT RANGE(area;1;5;2;9;pv selection set)

 

  `Chamada de um método quando se faz clique na área

 PV ON EVENT(area;pv on clicked;"ExampleView")

 

  `Método ExampleView

 C_LONGINT($1;$2;$3;$4;$5)

 If(($2=pv on clicked) & ($3=2048)) `Alt + clique ou Opção + clique

    If(PV Is cell selected(area;$4;$5)=1)

  `Se a célula é parte da seleção, se retira da seleção

       PV SELECT RANGE(area;$4;$5;$4;$5;pv selection reduce)

    Else

  `Se a célula não faz parte da seleção, é adicionada a seleção

       PV SELECT RANGE(area;$4;$5;$4;$5;pv selection add)

    End if

 End if

Ver também

PV GET CURRENT CELL
PV Is range selected