PV SELECT RANGE

4D View v16

PV SELECT RANGE


PV SELECT RANGE ( area ; left ; top ; right ; bottom ; action )

引数	型	説明
area	倍長整数	4D View エリア
left	倍長整数	左側のセルの列番号
top	倍長整数	上側のセルの行番号
right	倍長整数	右側のセルの列番号
bottom	倍長整数	下側のセルの行番号
action	整数	選択動作

説明

PV SELECT RANGEコマンドは、left、top、right 、bottom で定義された範囲のセルを選択します。

引数action により、選択セルが既に存在する場合に行う選択動作を定義することができます。このセルを既存の選択範囲に加えるか、または選択範囲をこのセルだけに縮小することができます。action の定義はPV Selection action定数を使用して行います:

定数	型	値	コメント
pv selection add	倍長整数	1	新しいセレクションは既存のセレクションに追加される
pv selection reduce	倍長整数	2	既存のセレクションから選択したセレクションが取り除かれる
pv selection set	倍長整数	0	新しいセレクションが既存のセレクションを置き換える

例題 1

セル範囲、E2、E3、F2、F3 を選択したい場合について考えてみます。選択動作は状況に応じて変わります（既存の選択セルがあるかどうか）:

  `既存の選択範囲を定義する配列

 ARRAY LONGINT($Left;0) ` 左側のセルの列番号

 ARRAY LONGINT($Top;0) ` 上側のセルの行番号

 ARRAY LONGINT($Right;0) ` 右側のセルの列番号

 ARRAY LONGINT($Bottom;0) ` 下側のセルの行番号

 

 PV GET SELECTED RANGES LIST(Area;$Left;$Top;$Right;$Bottom) `選択された範囲が存在する場合には、その座標を取得する

 

 If(Size of array($Left)=0) `現在の選択範囲はない

    PV SELECT RANGE(Area;5;2;6;3;pv selection set) `この範囲を現在の選択範囲に設定

 Else

    PV SELECT RANGE(Area;5;2;6;3;pv selection add) `この範囲を現在の選択範囲に追加

 End if

例題 2

この例題はAlt+clicked (Windows) や Option+clicked (Mac OS)時に、そのセルが選択範囲中にあるかどうかによって動作を切り替えます:

  `カレントの選択範囲を指定

 PV SELECT RANGE(area;1;5;2;9;pv selection set)

 

  `エリアがクリックされたらメソッドを呼び出す

 PV ON EVENT(area;pv on clicked;"ExampleView")

 

  `ExampleView メソッド

 C_LONGINT($1;$2;$3;$4;$5)

 If(($2=pv on clicked) & ($3=2048)) `Alt + click または Option + click

    If(PV Is cell selected(area;$4;$5)=1)

  `セルが選択範囲内なら、選択から取り除く

       PV SELECT RANGE(area;$4;$5;$4;$5;pv selection reduce)

    Else

  `セルが選択範囲外なら、そこに加える

       PV SELECT RANGE(area;$4;$5;$4;$5;pv selection add)

    End if

 End if

参照

PV GET CURRENT CELL
PV Is range selected