PV REPORT ONE

Home

4D View v16

PV REPORT ONE


PV REPORT ONE ( Bereich ; Spalte ; Zeile ; Haupttabelle ; TabelleUmbruch ; FeldUmbruch ; Operator ; Tabellen ; Felder ; Einfügen ; Detail ; Titel )

Parameter	Typ	Beschreibung
Bereich	Lange Ganzzahl	4D View Bereich
Spalte	Lange Ganzzahl	Spaltennummer
Zeile	Lange Ganzzahl	Zeilennummer
Haupttabelle	Ganzzahl	Nummer Haupttabelle
TabelleUmbruch	Ganzzahl	Tabellennummer, wo Umbruch auftritt
FeldUmbruch	Ganzzahl	Feldnummer, wo Umbruch auftritt
Operator	Ganzzahl	Auszuführende Operationen
Tabellen	Ganzzahl	Tabellennummer des anzuzeigenden Feldes
Felder	Ganzzahl	Nummer des anzuzeigenden Feldes
Einfügen	Ganzzahl	0 = Ersetzen; 1 = Zeilen einfügen
Detail	Lange Ganzzahl	Einfügeoptionen Detail
Titel	String	Titel Umbruch

Beschreibung

Der Befehl PV REPORT ONE erstellt einen Bericht im 4D View Bereich mit den Werten aus 4D Feldern angegeben in Tabellen und Felder, beginnend mit der aktuellen Auswahl in der Tabelle Haupttabelle. Über Operator können Sie diesem Feld eine Operation zuweisen, z.B.: Zwischensumme, Anzahl, Maximum. Für Operator verwenden Sie eine Konstante unter dem Thema PV Bericht Funktionen :

Konstante	Typ	Wert
pv report function average	Lange Ganzzahl	1
pv report function count	Lange Ganzzahl	4
pv report function max	Lange Ganzzahl	3
pv report function min	Lange Ganzzahl	2
pv report function none	Lange Ganzzahl	-1
pv report function sum	Lange Ganzzahl	0

Das generierte Ergebnis fügen Sie aus der Zelle Spalte und Zeile in Bereich ein.

TabelleUmbruch und FeldUmbruch weist das Feld zu, wo der Umbruch ausgeführt wird. Über Umbrüche können Sie Datensätze in homogene Gruppen einteilen und Zwischenberechnungen ausführen.
Ein Umbruch ist eine Wertänderung in einer Sortierung nach Tabelle. Sie müssen diese Umbruchebene einer Sortierung nach Kriterium zuweisen. Die Datensatzauswahl definiert durch TabelleUmbruch und FeldUmbruch muss vor Einsatz des Befehls PV REPORT ONE sortiert werden. Sie kann auch weitere Sortierkriterien enthalten, die für den Umbruch keine Bedeutung haben. Weitere Informationen zum Erstellen von Schnellberichten mit Umbrüchen finden Sie im Handbuch 4D Designmodus.

Der Parameter Einfügen gibt an, ob die im 4D View Bereich gesetzten Werte bereits vorhandene Zellen ersetzen oder in neue Zeilen eingegeben werden. Übergeben Sie den Wert 0 (Null), werden die Daten gelöscht und ersetzt; übergeben Sie 1, werden zusätzliche Zeilen eingefügt.

Mit dem Parameter Detail können Sie festlegen, wie 4D View Daten und Umbruchzeilen im Bericht einfügt:

Übergeben Sie 0 in Detail, werden nur Umbruchzeilen eingefügt und keine Zeilen mit Daten.
Übergeben Sie 1 in Detail, werden Zeilen mit Daten eingefügt und der Umbruchwert in jeder Zeile wiederholt.
Übergeben Sie 2 in Detail, werden Zeilen mit Daten eingefügt und der Umbruchwert nur einmal angezeigt.

Mit dem Parameter Titel können Sie den Titel der Ergebniszeile setzen, z.B. "Gesamt", "Durchschnitt". Sie können wie im 4D Schnellberichteditor das Zeichen # als Platzhalter für den Wert des aktuellen Umbruchs verwenden. Ist zum Beispiel “Land” das Umbruchfeld, übergeben Sie in Titel "Gesamt für #:". Der Bericht zeigt dann an: "Gesamt für USA: "Gesamt für Japan:", etc.
Übergeben Sie einen leeren String, wenn Sie keinen Titel einfügen wollen.

Hinweis: Hat Detail den Wert 0 und ist der Titel ein leerer String, wird die erste Spalte nicht eingefügt, da sie leer wäre.

Beispiel

In einem 4D View Bereich eine Kundenliste zeigen, getrennt nach männlich und weiblich und die Anzahl der Datensätze für jede Gruppe angeben:

 C_LONGINT($Column) //Spaltennummer

 C_LONGINT($Row) //Zeilennummer

 C_LONGINT($Master) //Nummer Haupttabelle

 C_LONGINT($TableBreak) //Nummer der Tabelle mit Umbruch

 C_LONGINT($FieldBreak) //Nummer des Feldes mit Umbruch

 C_LONGINT($Operator) //Auszuführende Operation

 C_LONGINT($Table) //Tabellennummer der anzuzeigenden Felder

 C_LONGINT($Field) //Anzahl der anzuzeigenden Felder

 C_LONGINT($Insert) //0=Ersetzen;1=Zeilen einfügen

 C_LONGINT($Detail) //Anzeigeoptionen Detail

 C_TEXT($Title) //Titel der Ergebniszeile

 

  //Initialisieren

 $Column:=4 //Starte Anzeige mit Spalte C

 $Row:=3 //Starte Anzeige mit der 3.Zeile (Titel + leere Zeile)

 $Master:=Table(->[Clients]) //Tabelle Clients ist entfernt

 $TableBreak:=Table(->[Clients])

 $FieldBreak:=Field(->[Clients]Type) //Umbruch bei Kundentyp

 $Operator:=pv report function count //Berechne Anzahl Männer und Frauen

 $Table:=Table(->[Clients]) //Felder der Tabelle Clients

 $Field:=Field(->[Clients]Name) //Zum Drucken von Namen

 $Insert:=1 //Anfrage einfügen

 $Detail:=2 //Detail Zeilen werden eingefügt, Werte erscheinen einmal

 $Title:="Total"

 

 ALL RECORDS([Clients])

 ORDER BY([Clients];[Clients]Type;[Clients]Name) //Sortierung erforderlich bei Umbruch + alphabetische Anzeige

 

 PV REPORT ONE(Bereich;$Column;$Row;$Master;$TableBreak;$FieldBreak;$Operator;$Table;$Field;$Insert;$Detail;$Title)

Siehe auch

PV ARRAY TO CELLS
PV REPORT MANY