SMTP_QuickSend

4D Internet Commands v16

SMTP_QuickSend


SMTP_QuickSend ( nomeServidor ; msgDe ; msgA ; assunto ; mensagem {; paramSessao}{; port}{; nomUsuario ; senha} ) -> Resultado

Parâmetro	Tipo	Descrição
nomeServidor	String	Nome ou endereço IP do servidor
msgDe	Texto	Endereço de email ou lista de endereços
msgA	Texto	Endereço de email ou lista de endereços
assunto	Texto	Assunto da mensagem
mensagem	Texto	Mensagem
paramSessao	Inteiro longo	1 = Utilizar SSL, 0 se omite = Não utilizar SSL
port	Inteiro longo	Número de porta a utilizar
nomUsuario	Texto	Nome de usuário para a autenticação
senha	Texto	senha para a autenticação
Resultado	Inteiro	Código de erro

Descrição

O comando SMTP_QuickSend permite criar e enviar uma mensagem com um só comando. É requerido um maior controle sobre a mensagem ou se a mensagem é mais complexa, utilize o comando SMTP_New.

Nota: este comando não pode ser utilizado nas bases convertidas que funcionam em modo "no Unicode".

nomeServidor contém o nome ou o endereço IP do servidor SMTP que será encarregado da distribuição da mensagem.

msgDe contém um ou mais emails completos indicando quem enviou a mensagem originalmente. Todas os endereços que figuram no cabeçalho De são visíveis para todos os destinatários da mensagem.

msgA contém um ou mais emails completos. Os endereços identificados no cabeçalho msgA recebem uma copia original da mensagem. Cada destinatário da mensagem pode ver os outros emails os quais foram enviados a mensagem.

assunto é um valor texto que descrevem de forma concisa o tema tratado em detalhe pelo corpo da mensagem.

Nota: por padrão, o assunto e o corpo da mensagem estão codificados em UTF-8, o que garante que os caracteres enviados serão interpretados corretamente por quase todos os clientes de correio eletrônico. Se deseja utilizar um conjunto de caracteres específicos, consulte os comandos SMTP_SetPrefs e SMTP_Charset.

mensagem é um valor texto que contém o corpo da mensagem. Por razões históricas, o tamanho da mensagem está limitado a 32 KB.

O parâmetro opcional paramSessao estabelece o formato da mensagem (texto estandarte ou HTML) e o modo de ativação do protocolo SSL para a conexão:

Se passar 0 ou omite este parâmetro, a mensagem será enviada em modo padrão não seguro. Se o servidor propõe uma atualização a SSL/TLS depois da autenticação, a báscula se realiza automaticamente (funcionamento do SSL/TLS em modo explícito)
Se passar 1, a mensagem será formatado em texto e enviado em SSL (modo síncrono),
Se passar 2, a mensagem será formatado em texto e enviado mas sem suporte de atualização em SSL/TLS.
Se passar 4, a mensagem será formatado em HTML e enviado em modo estandarte.
Se passar 5, a mensagem será formatado em HTML e enviado em modo SSL/TLS.
Se passar 8, a mensagem será formatado em Mime HTML e enviado em modo estandarte,
Se passar 9, a mensagem será formatado em Mime HTML e enviado em modo SSL/TLS,
Nota: Mime HTML (extensão de arquivo .mht ou .mhtml) é um formato de arquivo de página Web que podem fusionar o código HTML, assim como os recursos externos, como imagenes em um único documento. Se apoia em vários navegadores, assim como MS Word, por exemplo. Dado que este formato é suportado para áreas 4D Write Pro, pode facilmente guardar e enviar áreas 4D Write Pro por email incluindo todos seus recursos.

Tenha em conta que estes valores correspondem as combinações habituais, no entanto o parâmetro paramSesion é uma realidade um campo de bits e permite qualquer combinação personalizada se utiliza Operadores de bit:

Número de bit	Formato utilizado se o bit é 1
0	Usar SSL ou o comportamento pré determinado, conexão em claro e atualizar a SSL se é possível.
1	Nunca atualizar, permanecer em modo não cifrado, inclusive se a atualização é possível. Bit é ignorado se foi selecionado SSL (bit-0).
2	Corpo da mensagem em HTML, definir o cabeçalho apropriado.
3	Mensagem MHTML, ou bit 2 (HTML) é ignorado. O usuário é responsável de configurar tudo, exceto "A", "De", "Data" e "Assunto

O parâmetro opcional porta especifica o número de porta SMTP a utilizar para a conexão com o servidor. Os valores utilizados com mais frequência são:

25 = porta STMP padrão não seguro (porta por padrão se o parâmetro se omite)
465 = porta SMTPS (SSL/TLS)
587 = porta STMP padrão (seguro); passe esta porta para conexões com um servidor MS Exchange (modo explícito).

Os parâmetros opcionais nomUsuario e senha se utilizam para autenticar o remitente com o servidor de correio. Estes parâmetros devem passar em conjunto. Note que o modo de autenticação mais seguro suportado pelo servidor será o utilizado (como o modo por padrão do comando SMTP_Auth).

Exemplo 1

Exemplo de uso deste comando:

 $Host:="www.4d.com"

 $ToAddress:="adupont@4d.fr"

 $FromAddress:="jsmith@4d.com"

 $Subject:="Relatórios de vendas"

 $Message:="Poderia me enviar o relatório de vendas de janeoio de 2009? Obrigado."

 $Error:=SMTP_QuickSend($Host;$FromAddress;$ToAddress;$Subject;$Message;1)

 If($Error#0)

    ALERT("Error: SMTP_QuickSend"+Char(13)+IT_ErrorText($Error))

 End If

Exemplo 2

Exemplo de utilização do comando para um envio de mensagem seguro via um servidor MS Exchange:

 $ServerName:="exchange.4d.com"

 $MsgTo:="adupont@gmail.com"

 $MsgFrom:="a.user@4d.com"

 $Subject:="Test message"

 $Message:="This is a test for sending a message in secure mode. Please do not reply."

 $Error:=SMTP_QuickSend($ServerName;$MsgFrom;$MsgTo;$Subject;$Message;0;587;"a.user";"@!password@!")

Exemplo 3

Envio de uma mensagem em HTML com SSL/TLS:

 $Host:="smtp.gmail.com"

 $ToAddress:="john@4d.com"

 $FromAddress:="harry@gmail.com"

 $Subject:="Message HTML"

 $Message:="Let’s meet at <b>Joe’s Coffee Shop</b>!"

 $Param:=5 //HTML with SSL

 $Port:=465 //SSL port of gmail

 $User:="harry@gmail.com"

 $Password:="xyz&@!&@"

 $Error:=SMTP_QuickSend($Host;$FromAddress;$ToAddress;$Subject;$Message;$Param;$Port;$User;$Password)

Exemplo 4

Você guardou um documento .mht de seu disco e deseja enviar ele por email. Para isso, pode escrever:

 $Message:=Document to text("c:\\documents\\invitation.mht")

 $Host:="smtp.gmail.com"

 $ToAddress:="john@4d.com"

 $FromAddress:="harry@gmail.com"

 $Subject:="Let's party"

 $Param:=9 //MHTML with SSL

 $Port:=465 //SSL port of gmail

 $User:="harry@gmail.com"

 $Password:="xyz&@!&@"

 $Error:=SMTP_QuickSend($Host;$FromAddress;$ToAddress;$Subject;$Message;$Param;$Port;$User;$Password)

Ver também

SMTP_Charset
SMTP_New
SMTP_SetPrefs