4D Doc Center : WEB LIRE PARTIE CORPS

4D v14.3

WEB LIRE PARTIE CORPS


WEB LIRE PARTIE CORPS ( partie ; contenuPartie ; nomPartie ; typeMime ; nomFichier )

Paramètre	Type	Description
partie	Entier long	Numéro de partie
contenuPartie	BLOB, Texte	Contenu de la partie
nomPartie	Texte	Nom de la variable "input"
typeMime	Texte	Type mime du fichier
nomFichier	Texte	Nom du fichier posté

Description

La commande WEB LIRE PARTIE CORPS, appelée dans le contexte d’un process Web, permet d’analyser la partie "corps" d’une requête multi-part.

Passez dans le paramètre partie le numéro de la partie à analyser. Vous pouvez obtenir le nombre total de parties à l’aide de la commande WEB Lire nombre parties corps.

Le paramètre contenuPartie récupère le contenu de la partie. Lorsque les parties à récupérer sont des fichiers, vous devez passer un paramètre de type BLOB. Dans le cas de variables TEXT postées dans un formulaire Web, vous pouvez passer un paramètre de type texte.

Le paramètre nomPartie récupère le nom de la variable du champ input HTTP.

Les paramètres typeMime et nomFichier permettent de récupérer le type Mime et le nom du fichier d’origine, le cas échéant. nomFichier n’est renseigné que dans le cas où le fichier a été posté dans <input type="file">.
typeMime et nomFichier sont optionnels mais ne peuvent pas être passés séparément.

Note : Dans le cadre d’une requête multi-part, le premier tableau de la commande WEB LIRE VARIABLES retourne toutes les parties du formulaire, dans le même ordre que la commande WEB LIRE PARTIE CORPS. Vous pouvez l’utiliser par exemple afin d’obtenir directement la position d'une partie du formulaire.

Exemple

Dans cet exemple, un formulaire Web permet de télécharger sur le serveur HTTP plusieurs images depuis un navigateur et de les afficher dans la page. Voici le formulaire Web :

Voici le code la partie <body> de la page :

<body>
        <form enctype="multipart/form-data" action="/4DACTION/GetFile/" method="post">
            Locate the picture files to upload: <br>
            Picture file 1: <input name="file1" type="file"><br>
            Picture file 2: <input name="file2" type="file"><br>
            <input type="submit">                    
        </form>     
        <hr/>
    <!--4DSCRIPT/galleryInit-->
    <!--4Dloop aFileNames-->
        <img src="/photos/<!--4Dvar aFileNames{aFileNames}-->"/>
    <!--4Dendloop-->
</body>

Deux méthodes 4D sont appelées par la page :

galleryInit au chargement (balise 4DSCRIPT), permettant d’afficher les images présentes dans le dossier de destination.
GetFile au moment de l’envoi des données (url 4DACTION du formulaire multi-part), permettant de traiter l’envoi.

Voici le code de la méthode galleryInit :

 C_TEXTE($vDestinationFolder)

 TABLEAU TEXTE(aFileNames;0)

 C_ENTIER LONG($i)

 $vDestinationFolder:=Dossier 4D(Dossier racine HTML)+"photos"+Séparateur dossier //"DossierWeb/photos" par exemple

 LISTE DES DOCUMENTS($vDestinationFolder;aFileNames)

Voici le code de la méthode GetFile :

 C_TEXTE($vPartName;$vPartMimeType;$vPartFileName;$vDestinationFolder)

 C_BLOB($vPartContentBlob)

 C_ENTIER LONG($i)

 $vDestinationFolder:=Dossier 4D(Dossier racine HTML)+"photos"+Séparateur dossier

 Boucle($i;1;WEB Lire nombre parties corps) //pour chaque partie

    WEB LIRE PARTIE CORPS($i;$vPartContentBlob;$vPartName;$vPartMimeType;$vPartFileName)

    Si($vPartFileName#"")

       BLOB VERS DOCUMENT($vDestinationFolder+$vPartFileName;$vPartContentBlob)

    Fin de si

 Fin de boucle

 WEB ENVOYER REDIRECTION HTTP("/") // retour à la page